[PATCH qemu-server 0/3] fix #7801: warn about problematic VirtIO ISOs

[PATCH qemu-server 0/3] fix #7801: warn about problematic VirtIO ISOs

[Nicolas Frey]

This series fixes #7801 by implementing backend-only checks for VirtIO
ISOs with known issues. When a user starts, creates, or updates a VM,
the system scans for problematic VirtIO filenames and logs a warning in
the task log if a known issue is detected.

This approach supersedes the earlier UI patches [0], following feedback
to implement the check in the backend. Since the backend check already
alerts users via task log warnings (an equally effective and less intrusive
solution) the separate API call and UI patches became unnecessary.

Thanks Dominik and Maximilano for the feedback on the last revision

[0] https://lore.proxmox.com/all/20260826074935.78437-1-n.frey@proxmox.com/

qemu-server:

Nicolas Frey (3):
  drive: add helper to detect VirtIO driver ISOs with known issues
  partially fix #7801: api: warn about problematic VirtIO driver ISOs
  partially fix #7801: vm start: warn about problematic VirtIO ISOs

 src/PVE/API2/Qemu.pm        | 11 +++++++
 src/PVE/QemuServer.pm       |  2 ++
 src/PVE/QemuServer/Drive.pm | 61 +++++++++++++++++++++++++++++++++++++
 3 files changed, 74 insertions(+)


Summary over all repositories:
  3 files changed, 74 insertions(+), 0 deletions(-)

--
Generated by murpp 0.12.1

[PATCH qemu-server 1/3] drive: add helper to detect VirtIO driver ISOs with known issues

[Nicolas Frey]

the wiki lists version ranges of the VirtIO driver ISO for Windows that
are known to cause issues. these helpers should be the single source of
truth in code for checking these known issues.

Signed-off-by: Nicolas Frey <n.frey@proxmox.com>
---
 src/PVE/QemuServer/Drive.pm | 61 +++++++++++++++++++++++++++++++++++++
 1 file changed, 61 insertions(+)

diff --git a/src/PVE/QemuServer/Drive.pm b/src/PVE/QemuServer/Drive.pm
index 17c46f36..9839bb48 100644
--- a/src/PVE/QemuServer/Drive.pm
+++ b/src/PVE/QemuServer/Drive.pm
@@ -13,6 +13,7 @@ use PVE::Storage;
 use PVE::Storage::Common;
 use PVE::JSONSchema qw(get_standard_option);
 
+use PVE::QemuServer::Helpers;
 use PVE::QemuServer::Monitor qw(qsd_qmp_peer vm_qmp_peer);
 
 use base qw(Exporter);
@@ -766,6 +767,66 @@ sub drive_is_cdrom {
     return $drive && $drive->{media} && ($drive->{media} eq 'cdrom');
 }
 
+# version ranges of the VirtIO driver ISO for Windows that are known to cause issues, see
+# https://pve.proxmox.com/wiki/Windows_VirtIO_Drivers#Known_Issues
+my $virtio_win_issues = [
+    { from => [0, 1, 215], to => [0, 1, 262] }, { from => [0, 1, 285], to => [0, 1, 285] },
+];
+
+# returns the version of the VirtIO driver ISO referenced by $volid if it is known to cause
+# issues, undef otherwise
+sub virtio_win_iso_issue {
+    my ($volid) = @_;
+
+    my @version = ($volid // '') =~ m/virtio-win[_-](\d+)\.(\d+)\.(\d+)/i;
+    return if !@version;
+
+    my $cmp_with = sub {
+        my ($other) = @_;
+
+        return PVE::QemuServer::Helpers::version_cmp(map { ($version[$_], $other->[$_]) }
+            0 .. 2);
+    };
+
+    for my $issue ($virtio_win_issues->@*) {
+        return join('.', @version)
+            if $cmp_with->($issue->{from}) >= 0 && $cmp_with->($issue->{to}) <= 0;
+    }
+
+    return;
+}
+
+# warn if the CD-ROM drive $opt contains a VirtIO driver ISO that is known to cause issues
+sub warn_about_virtio_win_issues {
+    my ($opt, $volid) = @_;
+
+    my $version = virtio_win_iso_issue($volid);
+    return if !defined($version);
+
+    log_warn("$opt: version $version of the VirtIO drivers for Windows is known to cause issues,"
+        . " see https://pve.proxmox.com/wiki/Windows_VirtIO_Drivers#Known_Issues");
+
+    return;
+}
+
+# warn about every CD-ROM drive in $conf that contains a problematic VirtIO driver ISO
+sub warn_about_virtio_win_issues_in_config {
+    my ($conf) = @_;
+
+    return if !PVE::QemuServer::Helpers::windows_version($conf->{ostype});
+
+    for my $opt (valid_drive_names()) {
+        next if !defined($conf->{$opt});
+
+        my $drive = eval { parse_drive($opt, $conf->{$opt}) };
+        next if !$drive || !drive_is_cdrom($drive, 1);
+
+        warn_about_virtio_win_issues($opt, $drive->{file});
+    }
+
+    return;
+}
+
 sub parse_drive_interface {
     my ($key) = @_;
 
-- 
2.47.3

[PATCH qemu-server 2/3] partially fix #7801: api: warn about problematic VirtIO driver ISOs

[Nicolas Frey]

Warn when a CD-ROM drive of a Windows guest gets a VirtIO driver ISO
with known issues assigned on update and create.

The OS type can be set in the same request as the drive, so prefer a
newly requested one over the one from the configuration.

Signed-off-by: Nicolas Frey <n.frey@proxmox.com>
---
 src/PVE/API2/Qemu.pm | 11 +++++++++++
 1 file changed, 11 insertions(+)

diff --git a/src/PVE/API2/Qemu.pm b/src/PVE/API2/Qemu.pm
index 71247eec..b2860a49 100644
--- a/src/PVE/API2/Qemu.pm
+++ b/src/PVE/API2/Qemu.pm
@@ -1511,6 +1511,8 @@ __PACKAGE__->register_method({
                     my $vga = PVE::QemuServer::parse_vga($conf->{vga});
                     PVE::QemuServer::assert_clipboard_config($vga);
 
+                    PVE::QemuServer::Drive::warn_about_virtio_win_issues_in_config($conf);
+
                     # auto generate uuid if user did not specify smbios1 option
                     if (!$conf->{smbios1}) {
                         $conf->{smbios1} = PVE::QemuServer::generate_smbios1_uuid();
@@ -2411,6 +2413,15 @@ my $update_vm_api = sub {
 
                 # new drive
                 $check_drive_perms->($opt, $param->{$opt});
+
+                # warn about virtio win known issues only on windows
+                my $ostype = $param->{ostype} // $conf->{pending}->{ostype} // $conf->{ostype};
+                if (PVE::QemuServer::Helpers::windows_version($ostype)) {
+                    my $drive = PVE::QemuServer::parse_drive($opt, $param->{$opt}, 1);
+                    PVE::QemuServer::Drive::warn_about_virtio_win_issues($opt, $drive->{file})
+                        if $drive && PVE::QemuServer::drive_is_cdrom($drive, 1);
+                }
+
                 PVE::QemuServer::vmconfig_register_unused_drive(
                     $storecfg,
                     $vmid,
-- 
2.47.3

[PATCH qemu-server 3/3] partially fix #7801: vm start: warn about problematic VirtIO ISOs

[Nicolas Frey]

An ISO can end up in a CD-ROM drive without passing through the
configuration API, e.g. by restoring a backup or by editing the
configuration file directly.

checking on start covers these cases too and puts the warning in the
task log right next to the boot that might be affected by the known
issue.

Signed-off-by: Nicolas Frey <n.frey@proxmox.com>
---
 src/PVE/QemuServer.pm | 2 ++
 1 file changed, 2 insertions(+)

diff --git a/src/PVE/QemuServer.pm b/src/PVE/QemuServer.pm
index 759f7db2..0ed75cd7 100644
--- a/src/PVE/QemuServer.pm
+++ b/src/PVE/QemuServer.pm
@@ -5627,6 +5627,8 @@ sub vm_start_nolock {
 
         check_efi_vars($storecfg, $vmid, $conf) if $conf->{bios} && $conf->{bios} eq 'ovmf';
 
+        PVE::QemuServer::Drive::warn_about_virtio_win_issues_in_config($conf);
+
         # Note that for certain cases like templates, the configuration is minimized, so need to ensure
         # the rest of the function here uses the same configuration that was used to build the command
         ($cmd, $spice_port, my $pci_devices, $conf) = config_to_command(
-- 
2.47.3

Re: [PATCH qemu-server 1/3] drive: add helper to detect VirtIO driver ISOs with known issues

[Maximiliano Sandoval]

Nicolas Frey <n.frey@proxmox.com> writes:

> the wiki lists version ranges of the VirtIO driver ISO for Windows that
> are known to cause issues. these helpers should be the single source of
> truth in code for checking these known issues.
>
> Signed-off-by: Nicolas Frey <n.frey@proxmox.com>
> ---
>  src/PVE/QemuServer/Drive.pm | 61 +++++++++++++++++++++++++++++++++++++
>  1 file changed, 61 insertions(+)
>
> diff --git a/src/PVE/QemuServer/Drive.pm b/src/PVE/QemuServer/Drive.pm
> index 17c46f36..9839bb48 100644
> --- a/src/PVE/QemuServer/Drive.pm
> +++ b/src/PVE/QemuServer/Drive.pm
> @@ -13,6 +13,7 @@ use PVE::Storage;
>  use PVE::Storage::Common;
>  use PVE::JSONSchema qw(get_standard_option);
>  
> +use PVE::QemuServer::Helpers;
>  use PVE::QemuServer::Monitor qw(qsd_qmp_peer vm_qmp_peer);
>  
>  use base qw(Exporter);
> @@ -766,6 +767,66 @@ sub drive_is_cdrom {
>      return $drive && $drive->{media} && ($drive->{media} eq 'cdrom');
>  }
>  
> +# version ranges of the VirtIO driver ISO for Windows that are known to cause issues, see
> +# https://pve.proxmox.com/wiki/Windows_VirtIO_Drivers#Known_Issues
> +my $virtio_win_issues = [
> +    { from => [0, 1, 215], to => [0, 1, 262] }, { from => [0, 1, 285], to => [0, 1, 285] },
> +];

Since the warning is always the same now, it might make sense (or be
cleaner) to have an explicit list of all affected versions, e.g.
0.1.{215, 217, 221, 225, 229, 240, 248, 262, 285},

No strong opinion on this, definitively not a blocker.

> +
> +# returns the version of the VirtIO driver ISO referenced by $volid if it is known to cause
> +# issues, undef otherwise
> +sub virtio_win_iso_issue {
> +    my ($volid) = @_;
> +
> +    my @version = ($volid // '') =~ m/virtio-win[_-](\d+)\.(\d+)\.(\d+)/i;
> +    return if !@version;
> +
> +    my $cmp_with = sub {
> +        my ($other) = @_;
> +
> +        return PVE::QemuServer::Helpers::version_cmp(map { ($version[$_], $other->[$_]) }
> +            0 .. 2);
> +    };
> +
> +    for my $issue ($virtio_win_issues->@*) {
> +        return join('.', @version)
> +            if $cmp_with->($issue->{from}) >= 0 && $cmp_with->($issue->{to}) <= 0;
> +    }
> +
> +    return;
> +}
> +
> +# warn if the CD-ROM drive $opt contains a VirtIO driver ISO that is known to cause issues
> +sub warn_about_virtio_win_issues {
> +    my ($opt, $volid) = @_;
> +
> +    my $version = virtio_win_iso_issue($volid);
> +    return if !defined($version);
> +
> +    log_warn("$opt: version $version of the VirtIO drivers for Windows is known to cause issues,"
> +        . " see https://pve.proxmox.com/wiki/Windows_VirtIO_Drivers#Known_Issues");
> +
> +    return;
> +}
> +
> +# warn about every CD-ROM drive in $conf that contains a problematic VirtIO driver ISO
> +sub warn_about_virtio_win_issues_in_config {
> +    my ($conf) = @_;
> +
> +    return if !PVE::QemuServer::Helpers::windows_version($conf->{ostype});
> +
> +    for my $opt (valid_drive_names()) {
> +        next if !defined($conf->{$opt});
> +
> +        my $drive = eval { parse_drive($opt, $conf->{$opt}) };
> +        next if !$drive || !drive_is_cdrom($drive, 1);
> +
> +        warn_about_virtio_win_issues($opt, $drive->{file});
> +    }
> +
> +    return;
> +}
> +
>  sub parse_drive_interface {
>      my ($key) = @_;

-- 
Maximiliano

Re: [PATCH qemu-server 0/3] fix #7801: warn about problematic VirtIO ISOs

[Maximiliano Sandoval]

Nicolas Frey <n.frey@proxmox.com> writes:


> This series fixes #7801 by implementing backend-only checks for VirtIO
> ISOs with known issues. When a user starts, creates, or updates a VM,
> the system scans for problematic VirtIO filenames and logs a warning in
> the task log if a known issue is detected.
>
> This approach supersedes the earlier UI patches [0], following feedback
> to implement the check in the backend. Since the backend check already
> alerts users via task log warnings (an equally effective and less intrusive
> solution) the separate API call and UI patches became unnecessary.
>
> Thanks Dominik and Maximilano for the feedback on the last revision
>
> [0] https://lore.proxmox.com/all/20260826074935.78437-1-n.frey@proxmox.com/

Tested:

- qm set 104 --ide0 local:iso/virtio-win-0.1.285.iso,media=cdrom
- qm set 104 --ide1 local:iso/virtio-win-0.1.262.iso,media=cdrom
- qm start 104

the CLI produces 2 warnings as described in the commits.

Note that the setting the ISOs in the UI won't produce a warnings and
since there is no task, there will not be any visible issue. However,
having warnings on qmstart is good enough in my opinion.

Tested-by: Maximiliano Sandoval <m.sandoval@proxmox.com>

-- 
Maximiliano

Re: [PATCH qemu-server 1/3] drive: add helper to detect VirtIO driver ISOs with known issues

[Maximiliano Sandoval]

Nicolas Frey <n.frey@proxmox.com> writes:

> the wiki lists version ranges of the VirtIO driver ISO for Windows that
> are known to cause issues. these helpers should be the single source of
> truth in code for checking these known issues.
>
> Signed-off-by: Nicolas Frey <n.frey@proxmox.com>
> ---
>  src/PVE/QemuServer/Drive.pm | 61 +++++++++++++++++++++++++++++++++++++
>  1 file changed, 61 insertions(+)
>
> diff --git a/src/PVE/QemuServer/Drive.pm b/src/PVE/QemuServer/Drive.pm
> index 17c46f36..9839bb48 100644
> --- a/src/PVE/QemuServer/Drive.pm
> +++ b/src/PVE/QemuServer/Drive.pm
> @@ -13,6 +13,7 @@ use PVE::Storage;
>  use PVE::Storage::Common;
>  use PVE::JSONSchema qw(get_standard_option);
>  
> +use PVE::QemuServer::Helpers;
>  use PVE::QemuServer::Monitor qw(qsd_qmp_peer vm_qmp_peer);
>  
>  use base qw(Exporter);
> @@ -766,6 +767,66 @@ sub drive_is_cdrom {
>      return $drive && $drive->{media} && ($drive->{media} eq 'cdrom');
>  }
>  
> +# version ranges of the VirtIO driver ISO for Windows that are known to cause issues, see
> +# https://pve.proxmox.com/wiki/Windows_VirtIO_Drivers#Known_Issues
> +my $virtio_win_issues = [
> +    { from => [0, 1, 215], to => [0, 1, 262] }, { from => [0, 1, 285], to => [0, 1, 285] },
> +];
> +
> +# returns the version of the VirtIO driver ISO referenced by $volid if it is known to cause
> +# issues, undef otherwise
> +sub virtio_win_iso_issue {
> +    my ($volid) = @_;
> +
> +    my @version = ($volid // '') =~ m/virtio-win[_-](\d+)\.(\d+)\.(\d+)/i;
> +    return if !@version;
> +
> +    my $cmp_with = sub {
> +        my ($other) = @_;
> +
> +        return PVE::QemuServer::Helpers::version_cmp(map { ($version[$_], $other->[$_]) }
> +            0 .. 2);
> +    };
> +
> +    for my $issue ($virtio_win_issues->@*) {
> +        return join('.', @version)
> +            if $cmp_with->($issue->{from}) >= 0 && $cmp_with->($issue->{to}) <= 0;
> +    }
> +
> +    return;
> +}
> +
> +# warn if the CD-ROM drive $opt contains a VirtIO driver ISO that is known to cause issues
> +sub warn_about_virtio_win_issues {
> +    my ($opt, $volid) = @_;
> +
> +    my $version = virtio_win_iso_issue($volid);
> +    return if !defined($version);
> +
> +    log_warn("$opt: version $version of the VirtIO drivers for Windows is known to cause issues,"
> +        . " see https://pve.proxmox.com/wiki/Windows_VirtIO_Drivers#Known_Issues");
> +
> +    return;

cosmetic nit: This return might be redundant.

> +}
> +
> +# warn about every CD-ROM drive in $conf that contains a problematic VirtIO driver ISO
> +sub warn_about_virtio_win_issues_in_config {
> +    my ($conf) = @_;
> +
> +    return if !PVE::QemuServer::Helpers::windows_version($conf->{ostype});
> +
> +    for my $opt (valid_drive_names()) {
> +        next if !defined($conf->{$opt});
> +
> +        my $drive = eval { parse_drive($opt, $conf->{$opt}) };
> +        next if !$drive || !drive_is_cdrom($drive, 1);
> +
> +        warn_about_virtio_win_issues($opt, $drive->{file});
> +    }
> +
> +    return;

cosmetic nit: This return might be redundant.

> +}
> +
>  sub parse_drive_interface {
>      my ($key) = @_;

-- 
Maximiliano

Re: [PATCH qemu-server 0/3] fix #7801: warn about problematic VirtIO ISOs

[Maximiliano Sandoval]

Maximiliano Sandoval <m.sandoval@proxmox.com> writes:

> Nicolas Frey <n.frey@proxmox.com> writes:
>
>
>> This series fixes #7801 by implementing backend-only checks for VirtIO
>> ISOs with known issues. When a user starts, creates, or updates a VM,
>> the system scans for problematic VirtIO filenames and logs a warning in
>> the task log if a known issue is detected.
>>
>> This approach supersedes the earlier UI patches [0], following feedback
>> to implement the check in the backend. Since the backend check already
>> alerts users via task log warnings (an equally effective and less intrusive
>> solution) the separate API call and UI patches became unnecessary.
>>
>> Thanks Dominik and Maximilano for the feedback on the last revision
>>
>> [0] https://lore.proxmox.com/all/20260826074935.78437-1-n.frey@proxmox.com/
>
> Tested:
>
> - qm set 104 --ide0 local:iso/virtio-win-0.1.285.iso,media=cdrom
> - qm set 104 --ide1 local:iso/virtio-win-0.1.262.iso,media=cdrom
> - qm start 104
>
> the CLI produces 2 warnings as described in the commits.
>
> Note that the setting the ISOs in the UI won't produce a warnings and
> since there is no task, there will not be any visible issue. However,
> having warnings on qmstart is good enough in my opinion.
>
> Tested-by: Maximiliano Sandoval <m.sandoval@proxmox.com>

Modulo cosmetic things, the series looks good to me.

Reviewed-by: Maximiliano Sandoval <m.sandoval@proxmox.com>

-- 
Maximiliano

Re: [PATCH qemu-server 0/3] fix #7801: warn about problematic VirtIO ISOs

[Jonas Theisen]

On 9/15/26 16:32, Nicolas Frey wrote:
> This series fixes #7801 by implementing backend-only checks for VirtIO
> ISOs with known issues. When a user starts, creates, or updates a VM,
> the system scans for problematic VirtIO filenames and logs a warning in
> the task log if a known issue is detected.
>
> This approach supersedes the earlier UI patches [0], following feedback
> to implement the check in the backend. Since the backend check already
> alerts users via task log warnings (an equally effective and less intrusive
> solution) the separate API call and UI patches became unnecessary.
>
> Thanks Dominik and Maximilano for the feedback on the last revision
>
> [0] https://lore.proxmox.com/all/20260826074935.78437-1-n.frey@proxmox.com/
>
> <snip>

Tested the patches on current qemu-server v9.2.9.

Works as intended.
Only workflow that feels a little bit weird to me is when creating
a Windows VM with an affected ISO version and using "Start after Create"
This causes two directly consecutive tasks with warnings but i also
do not have a better idea on how to avoid this.

Tested (Web UI):
  * Existing Windows VM with affected ISO => Warning
  * Existing Windows VM with unaffected ISO => No Warning
  * New VM with affected ISO => Warning on create and start

Tested-by: Jonas Theisen <j.theisen@proxmox.com>