Re: [PATCH pve-cluster 8/9] fix #7294: cluster: helpers: add cluster-wide version assertion

[David Riley <d.riley@proxmox.com>]

On 6/22/26 11:42 AM, Daniel Kral wrote:
> On Thu Jun 11, 2026 at 4:59 PM CEST, David Riley wrote:
>> Add function to assert a minimum version requirement for the whole
>> cluster.
>>
>> Evaluates against the cluster configuration. Dies if any node is
>> offline, or running an older version, ensuring cluster-wide feature
>> compatibility before allowing an operation to proceed.
>>
>> Prevents older nodes from truncating newly structured user.cfg
>> entries.
>>
>> Link: https://bugzilla.proxmox.com/show_bug.cgi?id=7294
>> Signed-off-by: David Riley <d.riley@proxmox.com>
>> ---
>>   src/PVE/Cluster/Helpers.pm | 35 +++++++++++++++++++++++++++++++++++
>>   1 file changed, 35 insertions(+)
> As for the previous patch, this could go in PVE::Cluster as code that
> already depends on some cluster-related functionality has it imported,
> but no hard feelings about this.
I agree. I also decided to move the helpers from patch 7 into pve-common, so
it definitely makes sense to move this into PVE::Cluster instead of having a new
module.
>> diff --git a/src/PVE/Cluster/Helpers.pm b/src/PVE/Cluster/Helpers.pm
>> index a4b41c9..3937e6d 100644
>> --- a/src/PVE/Cluster/Helpers.pm
>> +++ b/src/PVE/Cluster/Helpers.pm
>> @@ -47,5 +47,40 @@ sub version_cmp {
>>       return 0;
>>   }
>>   
>> +# Asserts that all configured nodes in the cluster meet a minimum version requirement.
>> +# Evaluates against the full, static cluster node list rather than only live nodes.
>> +# Aborts if any node is offline, unreadable, or running an
>> +# outdated version, preventing partial feature rollouts from corrupting cluster state.
>> +sub assert_min_cluster_version {
>> +    my ($major, $minor, $release) = @_;
>> +
>> +    my $nodestat = PVE::Cluster::get_node_kv('version-info') || {};
>> +
>> +    my $clinfo = PVE::Cluster::get_clinfo() || {};
>> +    my $nodelist = $clinfo->{nodelist} || {};
> This might be unnecessary for single-node setups as there we can enforce
> versioned dependencies much more easily through package version
> constraints, but it should be noted that the $nodelist hash will be
> empty if no cluster has been created.
>
> If we want to make this assertion also work on single-node setups, this
> could use PVE::Cluster::get_nodelist(), which fakes the nodelist for a
> single node.
It should work for single-node setup as well otherwise it will crash and make the
feature it is gatekeeping unusable, so you definitely found a bug in my patch here.
I will adapt this in v2 to account for single-node setups as well.
Thanks.
>
> Either way, that should probably go in the subroutine's description.
>
>> +
>> +    foreach my $node (sort keys %$nodelist) {
> nit: for new code we use 'for' in favor of 'foreach' [0]
You are right. Thanks for pointing it out.
> [0] https://pve.proxmox.com/wiki/Perl_Style_Guide#Perl_syntax_choices
>
>> +        my $raw_json = $nodestat->{$node};
>> +
>> +        if (!defined($raw_json)) {
>> +            die "cannot execute operation: cluster node '$node' is offline or not reporting its"
>> +                . " version. All nodes must be online to verify cluster-wide feature support.\n";
>> +        }
>> +
>> +        my $vinfo = eval { decode_json($raw_json) };
>> +        if ($@ || !$vinfo || !$vinfo->{version}) {
>> +            die "cannot execute operation: failed to parse cluster version string for node"
>> +                . " '$node'.\n";
>> +        }
>> +
>> +        if (!pvecfg_min_version($vinfo->{version}, $major, $minor, $release)) {
>> +            die "cannot execute operation: cluster node '$node' runs an older version of Proxmox"
>> +                . " VE ($vinfo->{version}) than the required $major.$minor.$release. Please"
>> +                . " upgrade all nodes first.\n";
>> +        }
>> +    }
>> +    return 1;
>> +}
>> +
>>   1;
>>