[PATCH pve-cluster 8/9] fix #7294: cluster: helpers: add cluster-wide version assertion

[David Riley <d.riley@proxmox.com>]

Add function to assert a minimum version requirement for the whole
cluster.

Evaluates against the cluster configuration. Dies if any node is
offline, or running an older version, ensuring cluster-wide feature
compatibility before allowing an operation to proceed.

Prevents older nodes from truncating newly structured user.cfg
entries.

Link: https://bugzilla.proxmox.com/show_bug.cgi?id=7294
Signed-off-by: David Riley <d.riley@proxmox.com>
---
 src/PVE/Cluster/Helpers.pm | 35 +++++++++++++++++++++++++++++++++++
 1 file changed, 35 insertions(+)

diff --git a/src/PVE/Cluster/Helpers.pm b/src/PVE/Cluster/Helpers.pm
index a4b41c9..3937e6d 100644
--- a/src/PVE/Cluster/Helpers.pm
+++ b/src/PVE/Cluster/Helpers.pm
@@ -47,5 +47,40 @@ sub version_cmp {
     return 0;
 }
 
+# Asserts that all configured nodes in the cluster meet a minimum version requirement.
+# Evaluates against the full, static cluster node list rather than only live nodes.
+# Aborts if any node is offline, unreadable, or running an
+# outdated version, preventing partial feature rollouts from corrupting cluster state.
+sub assert_min_cluster_version {
+    my ($major, $minor, $release) = @_;
+
+    my $nodestat = PVE::Cluster::get_node_kv('version-info') || {};
+
+    my $clinfo = PVE::Cluster::get_clinfo() || {};
+    my $nodelist = $clinfo->{nodelist} || {};
+
+    foreach my $node (sort keys %$nodelist) {
+        my $raw_json = $nodestat->{$node};
+
+        if (!defined($raw_json)) {
+            die "cannot execute operation: cluster node '$node' is offline or not reporting its"
+                . " version. All nodes must be online to verify cluster-wide feature support.\n";
+        }
+
+        my $vinfo = eval { decode_json($raw_json) };
+        if ($@ || !$vinfo || !$vinfo->{version}) {
+            die "cannot execute operation: failed to parse cluster version string for node"
+                . " '$node'.\n";
+        }
+
+        if (!pvecfg_min_version($vinfo->{version}, $major, $minor, $release)) {
+            die "cannot execute operation: cluster node '$node' runs an older version of Proxmox"
+                . " VE ($vinfo->{version}) than the required $major.$minor.$release. Please"
+                . " upgrade all nodes first.\n";
+        }
+    }
+    return 1;
+}
+
 1;
 
-- 
2.47.3