public inbox for pve-devel@lists.proxmox.com
 help / color / mirror / Atom feed
From: Thomas Lamprecht <t.lamprecht@proxmox.com>
To: pve-devel@lists.proxmox.com
Subject: [PATCH container v5 23/41] api: migrate, clone: refuse targets that would drop the guest identity
Date: Thu, 19 Nov 2026 20:18:55 +0100	[thread overview]
Message-ID: <20261119191914.2336934-24-t.lamprecht@proxmox.com> (raw)
In-Reply-To: <20261119191914.2336934-1-t.lamprecht@proxmox.com>

Older pve-container versions drop the 'meta' property when they write a
config, and with it the guest identity. A later write by an upgraded
node then assigns a new identity.

Refuse restart and offline migrations and clones to another node unless
the target reports a version that keeps the identity. Check before the
operation starts, and report such nodes with the versions involved in
the migration preconditions, so that clients can explain the refusal.
Also return the nodes that keep the identity for the clone feature, so
that the web interface can validate the target of a clone. That list
does not consider the storages of the container.

The migration API also checks requests that come through HA, but an HA
relocation stops the container before it calls that API. The recovery
of guests from a fenced node moves configs without this check.

Signed-off-by: Thomas Lamprecht <t.lamprecht@proxmox.com>
Reviewed-by: Dominik Csapak <d.csapak@proxmox.com>
Tested-by: Dominik Csapak <d.csapak@proxmox.com>
---

no changes since v4

changes v3 -> v4:
* tests only: the mock of the feature check no longer stays for later
  subtests, and rebase

changes v2 -> v3:
* describe the refusal reason per node, on top of the independent schema
  fix, and validate complete responses in the test
* feature API: no version lookups and no 'nodes' for 'snapshot' requests
* description of 'nodes'

changes v1 -> v2:
* return the nodes that keep the identity for the clone feature, which
  the clone dialog uses
* use the shared schema for the precondition result

 src/PVE/API2/LXC.pm         |  40 ++++++--
 src/test/lifecycle_tests.pl | 190 ++++++++++++++++++++++++++++++++++++
 2 files changed, 223 insertions(+), 7 deletions(-)

diff --git a/src/PVE/API2/LXC.pm b/src/PVE/API2/LXC.pm
index a14a8be..91e6678 100644
--- a/src/PVE/API2/LXC.pm
+++ b/src/PVE/API2/LXC.pm
@@ -15,6 +15,7 @@ use PVE::Exception qw(raise raise_param_exc raise_perm_exc);
 use PVE::Firewall;
 use PVE::GuestHelpers;
 use PVE::GuestID;
+use PVE::GuestIdentity;
 use PVE::INotify;
 use PVE::JSONSchema qw(get_standard_option);
 use PVE::RESTEnvironment;
@@ -1672,6 +1673,8 @@ __PACKAGE__->register_method({
                                 },
                             },
                         },
+                        'guest-identity-unsupported' =>
+                            PVE::GuestIdentity::node_identity_unsupported_schema(),
                     },
                 },
                 description => "Not allowed nodes, keyed by node name, with the reasons.",
@@ -1735,6 +1738,12 @@ __PACKAGE__->register_method({
                     $blocking_ha_resources;
             }
 
+            # the migration refuses nodes that would drop the guest identity
+            if (my $unsupported = PVE::GuestIdentity::node_identity_unsupported($node)) {
+                $res->{'not-allowed-nodes'}->{$node}->{'guest-identity-unsupported'} =
+                    $unsupported;
+            }
+
             # if nothing came up, add it to the allowed nodes
             if (!defined($res->{'not-allowed-nodes'}->{$node})) {
                 push $res->{'allowed-nodes'}->@*, $node;
@@ -1778,6 +1787,8 @@ __PACKAGE__->register_method({
         PVE::Cluster::check_cfs_quorum();
 
         PVE::Cluster::check_node_exists($target);
+        # an older node drops the guest identity on its next write of the config
+        PVE::GuestIdentity::assert_node_supports_identity($target);
 
         my $targetip = PVE::Cluster::remote_node_ip($target);
 
@@ -1891,10 +1902,13 @@ __PACKAGE__->register_method({
         type => "object",
         properties => {
             hasFeature => { type => 'boolean' },
-            #nodes => {
-            #type => 'array',
-            #items => { type => 'string' },
-            #}
+            nodes => {
+                description => "Nodes that pass the guest identity check for a clone. The"
+                    . " storages of the container are not checked. Not set for 'snapshot'.",
+                type => 'array',
+                items => { type => 'string' },
+                optional => 1,
+            },
         },
     },
     code => sub {
@@ -1916,14 +1930,24 @@ __PACKAGE__->register_method({
             $conf = $snap;
         }
         my $storage_cfg = PVE::Storage::config();
-        #Maybe include later
-        #my $nodelist = PVE::LXC::shared_nodes($conf, $storage_cfg);
         my $hasFeature =
             PVE::LXC::Config->has_feature($feature, $conf, $storage_cfg, $snapname);
+        # the web interface polls the snapshot feature, which needs no target nodes
+        return { hasFeature => $hasFeature } if $feature eq 'snapshot';
+
+        # A clone to another node is refused if that node would drop the guest identity. Whether
+        # the storages of the container are available on a node is not checked.
+        my $nodename = PVE::INotify::nodename();
+        my $nodes = [];
+        for my $other (PVE::Cluster::get_nodelist()->@*) {
+            my $unsupported =
+                $other ne $nodename && PVE::GuestIdentity::node_identity_unsupported($other);
+            push $nodes->@*, $other if !$unsupported;
+        }
 
         return {
             hasFeature => $hasFeature,
-            #nodes => [ keys %$nodelist ],
+            nodes => $nodes,
         };
     },
 });
@@ -2104,6 +2128,8 @@ __PACKAGE__->register_method({
         undef $target if $target && ($target eq $localnode || $target eq 'localhost');
 
         PVE::Cluster::check_node_exists($target) if $target;
+        # an older node drops the guest identity on its next write of the config
+        PVE::GuestIdentity::assert_node_supports_identity($target) if $target;
 
         my $storecfg = PVE::Storage::config();
 
diff --git a/src/test/lifecycle_tests.pl b/src/test/lifecycle_tests.pl
index a9c857d..94c6d3a 100755
--- a/src/test/lifecycle_tests.pl
+++ b/src/test/lifecycle_tests.pl
@@ -25,6 +25,7 @@ use PVE::Cluster;
 use PVE::GuestHelpers;
 use PVE::GuestIdentity;
 use PVE::INotify;
+use PVE::JSONSchema;
 use PVE::Tools qw(file_get_contents file_set_contents);
 
 use PVE::LXC;
@@ -103,6 +104,12 @@ my $storage_cfg = {
     },
 };
 
+# reported Proxmox VE versions of the other cluster nodes
+my $node_versions = {
+    'new-node' => PVE::GuestIdentity::MIN_PVE_MANAGER_VERSION,
+    'old-node' => '9.2.0',
+};
+
 # recording used guest IDs needs the cluster filesystem and is not what gets tested here
 my $guest_id_module = Test::MockModule->new('PVE::GuestID');
 $guest_id_module->mock(register_used_id => sub { return; });
@@ -139,6 +146,19 @@ $cluster_module->mock(
         return undef if $noerr;
         die "CT $vmid already exists on node '$NODENAME'\n";
     },
+    remote_node_ip => sub { return '192.0.2.1' },
+    get_node_pvecfg_version => sub {
+        my ($node) = @_;
+        return $node_versions->{$node};
+    },
+    node_pvecfg_version_at_least => sub {
+        my ($node, @required) = @_;
+        my @version = split(/\./, $node_versions->{$node} // return 0);
+        for my $i (0 .. 2) {
+            return $version[$i] > $required[$i] if $version[$i] != $required[$i];
+        }
+        return 1;
+    },
 );
 
 # runs once between the checks of the create API call and its reservation, if set
@@ -1607,6 +1627,176 @@ subtest 'backup assigns the guest identity and includes it' => sub {
     is_deeply(identity_of(987), $identity, 'removing the backup lock keeps the identity');
 };
 
+subtest 'migration is refused to nodes that drop the guest identity' => sub {
+    reset_configs();
+    my $raw = existing_config('ctime=1500000000,rtime=1500000000000,uid=existingexistingexis');
+    write_raw_config(200, $raw);
+
+    my $migrated_to;
+    my $migrate_module = Test::MockModule->new('PVE::LXC::Migrate');
+    $migrate_module->mock(migrate => sub { $migrated_to = $_[1] });
+    my $ha_config_module = Test::MockModule->new('PVE::HA::Config');
+    $ha_config_module->mock(vm_is_ha_managed => sub { return 0 });
+
+    my $migrate = sub {
+        my ($target, $param) = @_;
+        return run_task(sub {
+            PVE::API2::LXC->migrate_vm({
+                node => $NODENAME,
+                vmid => 200,
+                target => $target,
+                ($param // {})->%*,
+            });
+        });
+    };
+
+    my $err = $migrate->('old-node');
+    like($err, qr/node 'old-node' runs Proxmox VE 9\.2\.0/, 'node too old is refused');
+    $err = $migrate->('unknown-node');
+    like($err, qr/does not report its Proxmox VE version/, 'node without version is refused');
+
+    my $stopped = 0;
+    $lxc_module->mock(
+        check_running => sub { return 1 },
+        vm_stop => sub { $stopped = 1 },
+    );
+    $err = $migrate->('old-node', { restart => 1 });
+    $lxc_module->mock(check_running => sub { return 0 });
+    $lxc_module->unmock('vm_stop');
+    like($err, qr/node 'old-node' runs Proxmox VE 9\.2\.0/, 'restart migration is refused');
+    ok(!$stopped, 'running container is not stopped');
+
+    ok(!defined($migrated_to), 'migration does not start');
+    is(read_raw_config(200), $raw, 'config is unchanged');
+
+    $err = $migrate->('new-node');
+    is($err, '', 'migration to an upgraded node starts');
+    is($migrated_to, 'new-node', 'migration goes to the target');
+};
+
+subtest 'migration preconditions list nodes that drop the guest identity' => sub {
+    reset_configs();
+    my $raw = existing_config('ctime=1500000000,rtime=1500000000000,uid=existingexistingexis');
+    write_raw_config(200, $raw);
+
+    my $ha_config_module = Test::MockModule->new('PVE::HA::Config');
+    $ha_config_module->mock(vm_is_ha_managed => sub { return 0 });
+    $cluster_module->mock(
+        get_nodelist => sub { return [$NODENAME, 'new-node', 'old-node', 'unknown-node'] },
+    );
+
+    my $res = PVE::API2::LXC->migrate_vm_precondition({ node => $NODENAME, vmid => 200 });
+    $cluster_module->unmock('get_nodelist');
+
+    my $required = PVE::GuestIdentity::MIN_PVE_MANAGER_VERSION;
+    is_deeply($res->{'allowed-nodes'}, ['new-node'], 'only the upgraded node is allowed');
+    is_deeply(
+        $res->{'not-allowed-nodes'},
+        {
+            'old-node' => {
+                'guest-identity-unsupported' => {
+                    version => '9.2.0',
+                    'required-version' => $required,
+                },
+            },
+            'unknown-node' => {
+                'guest-identity-unsupported' => { 'required-version' => $required },
+            },
+        },
+        'nodes that drop the identity are not allowed',
+    );
+
+    my $returns = PVE::API2::LXC->map_method_by_name('migrate_vm_precondition')->{returns};
+    eval { PVE::JSONSchema::validate($res, $returns) };
+    is($@, '', 'result matches the schema');
+    my $reasons_schema = {
+        $returns->{properties}->{'not-allowed-nodes'}->{additionalProperties}->%*,
+        additionalProperties => 0,
+    };
+    for my $node ('old-node', 'unknown-node') {
+        my $reasons = $res->{'not-allowed-nodes'}->{$node};
+        eval { PVE::JSONSchema::validate($reasons, $reasons_schema) };
+        is($@, '', "reason for $node is documented in the schema");
+    }
+};
+
+subtest 'clone feature only lists nodes that keep the guest identity' => sub {
+    reset_configs();
+    my $raw = existing_config('ctime=1500000000,rtime=1500000000000,uid=existingexistingexis');
+    write_raw_config(200, $raw);
+
+    $config_module->mock(has_feature => sub { return 1 });
+    $cluster_module->mock(
+        get_nodelist => sub { return [$NODENAME, 'new-node', 'old-node', 'unknown-node'] },
+    );
+
+    my $res =
+        PVE::API2::LXC->vm_feature({ node => $NODENAME, vmid => 200, feature => 'clone' });
+    $cluster_module->unmock('get_nodelist');
+
+    # the local node reports no version here, a clone on the same node needs no check
+    is_deeply(
+        $res->{nodes},
+        [$NODENAME, 'new-node'],
+        'nodes that drop the identity are left out',
+    );
+
+    my $returns = PVE::API2::LXC->map_method_by_name('vm_feature')->{returns};
+    eval { PVE::JSONSchema::validate($res, $returns) };
+    is($@, '', 'result matches the schema');
+
+    my $lookups = 0;
+    my $mocked_at_least = \&PVE::Cluster::node_pvecfg_version_at_least;
+    my $mocked_version = \&PVE::Cluster::get_node_pvecfg_version;
+    $cluster_module->mock(
+        get_nodelist => sub { return [$NODENAME, 'new-node', 'old-node', 'unknown-node'] },
+        node_pvecfg_version_at_least => sub { $lookups++; return $mocked_at_least->(@_) },
+        get_node_pvecfg_version => sub { $lookups++; return $mocked_version->(@_) },
+    );
+    $res =
+        PVE::API2::LXC->vm_feature({ node => $NODENAME, vmid => 200, feature => 'snapshot' });
+    $cluster_module->mock(
+        node_pvecfg_version_at_least => $mocked_at_least,
+        get_node_pvecfg_version => $mocked_version,
+    );
+    $cluster_module->unmock('get_nodelist');
+    is($lookups, 0, 'snapshot feature: no node versions are looked up');
+    ok(!exists($res->{nodes}), 'snapshot feature: no nodes are returned');
+    eval { PVE::JSONSchema::validate($res, $returns) };
+    is($@, '', 'snapshot feature: result matches the schema');
+
+    $config_module->unmock('has_feature');
+};
+
+subtest 'clone to another node is refused if the node drops the guest identity' => sub {
+    reset_configs();
+    my $raw = <<~'EOF';
+        arch: amd64
+        hostname: existing
+        memory: 512
+        meta: ctime=1500000000,rtime=1500000000000,uid=existingexistingexis
+        ostype: debian
+        rootfs: shared:200/vm-200-disk-0.raw,size=4G
+        unprivileged: 1
+        EOF
+    write_raw_config(200, $raw);
+    make_path(cfs_file("nodes/new-node/lxc"));
+
+    my $err = clone_ct(200, 201, { target => 'old-node' });
+    like($err, qr/node 'old-node' runs Proxmox VE 9\.2\.0/, 'clone is refused');
+    is(read_raw_config(200), $raw, 'source is unchanged');
+    ok(!defined(read_raw_config(201)), 'no clone is created');
+
+    $err = clone_ct(200, 201, { target => 'new-node' });
+    is($err, '', 'clone to an upgraded node succeeds') or diag($task_log);
+    my $clone_raw = read_raw_config(201, 'new-node');
+    ok(defined($clone_raw), 'clone is moved to the target node');
+    my $identity =
+        PVE::GuestIdentity::parse_identity($clone_raw =~ m/^meta: (.*)$/m ? $1 : undef);
+    like($identity->{uid}, qr/^[a-z2-7]{20}$/, 'clone has a uid');
+    isnt($identity->{uid}, 'existingexistingexis', 'clone has a new uid');
+};
+
 remove_tree($WORKDIR);
 
 done_testing();
-- 
2.47.3





  parent reply	other threads:[~2026-11-19 19:24 UTC|newest]

Thread overview: 43+ messages / expand[flat|nested]  mbox.gz  Atom feed  top
2026-11-19 19:18 [PATCH cluster/guest-common/qemu-server/container/manager/docs v5 00/41] fix #7846: guest identity (uid) and cluster ID Thomas Lamprecht
2026-11-19 19:18 ` [PATCH cluster v5 01/41] pmxcfs: reject changes to the cluster ID file from user space Thomas Lamprecht
2026-11-19 19:18 ` [PATCH cluster v5 02/41] pmxcfs: generate a cluster ID on standalone nodes Thomas Lamprecht
2026-11-19 19:18 ` [PATCH cluster v5 03/41] pmxcfs: dfsm: add a callback that runs once all members are in sync Thomas Lamprecht
2026-11-19 19:18 ` [PATCH cluster v5 04/41] pmxcfs: quorum: record the corosync membership Thomas Lamprecht
2026-11-19 19:18 ` [PATCH cluster v5 05/41] pmxcfs: dcdb: generate the cluster ID once the cluster is in sync Thomas Lamprecht
2026-11-19 19:18 ` [PATCH cluster v5 06/41] cluster: add helper to read the cluster ID Thomas Lamprecht
2026-11-19 19:18 ` [PATCH cluster v5 07/41] pmxcfs: allow removing the cluster ID file in forced local mode Thomas Lamprecht
2026-11-19 19:18 ` [PATCH guest-common v5 08/41] guest identity: add helpers for the guest uid and registration time Thomas Lamprecht
2026-11-19 19:18 ` [PATCH guest-common v5 09/41] abstract config: assign a guest identity and keep it on config writes Thomas Lamprecht
2026-11-19 19:18 ` [PATCH guest-common v5 10/41] abstract config: let the VMID reservation return the previous state Thomas Lamprecht
2026-11-19 19:18 ` [PATCH guest-common v5 11/41] guest identity: allow adopting a uid that is unused in the cluster Thomas Lamprecht
2026-11-19 19:18 ` [PATCH guest-common v5 12/41] migrate: add shared helpers for the identity command of the migration tunnel Thomas Lamprecht
2026-11-19 19:18 ` [PATCH guest-common v5 13/41] vzdump: notes template: list the uid variable Thomas Lamprecht
2026-11-19 19:18 ` [PATCH qemu-server v5 14/41] api: restore: release the VMID if a restore to an unused VMID fails Thomas Lamprecht
2026-11-19 19:18 ` [PATCH qemu-server v5 15/41] api: migrate, clone: refuse targets that would drop the guest identity Thomas Lamprecht
2026-11-19 19:18 ` [PATCH qemu-server v5 16/41] fix #7846: config: add a guest identity to the 'meta' property Thomas Lamprecht
2026-11-19 19:18 ` [PATCH qemu-server v5 17/41] restore: adopt the guest uid from the backup where possible Thomas Lamprecht
2026-11-19 19:18 ` [PATCH qemu-server v5 18/41] api: remote migration: adopt the guest uid from the source Thomas Lamprecht
2026-11-19 19:18 ` [PATCH qemu-server v5 19/41] api: status: return the guest uid Thomas Lamprecht
2026-11-19 19:18 ` [PATCH container v5 20/41] restore: decide by the reservation whether the container is new Thomas Lamprecht
2026-11-19 19:18 ` [PATCH container v5 21/41] config: add read-only meta property with the creation time Thomas Lamprecht
2026-11-19 19:18 ` [PATCH container v5 22/41] fix #7846: config: add a guest identity to the 'meta' property Thomas Lamprecht
2026-11-19 19:18 ` Thomas Lamprecht [this message]
2026-11-19 19:18 ` [PATCH container v5 24/41] restore: adopt the guest uid from the backup where possible Thomas Lamprecht
2026-11-19 19:18 ` [PATCH container v5 25/41] restore: refuse overwriting a container with another guest's backup Thomas Lamprecht
2026-11-19 19:18 ` [PATCH container v5 26/41] api: remote migration: adopt the guest uid from the source Thomas Lamprecht
2026-11-19 19:18 ` [PATCH container v5 27/41] api: status: return the guest uid Thomas Lamprecht
2026-11-19 19:19 ` [PATCH manager v5 28/41] api: cluster resources: add guest uid and registration time Thomas Lamprecht
2026-11-19 19:19 ` [PATCH manager v5 29/41] api: cluster status: add cluster ID Thomas Lamprecht
2026-11-19 19:19 ` [PATCH manager v5 30/41] ui: datacenter summary: show the " Thomas Lamprecht
2026-11-19 19:19 ` [PATCH manager v5 31/41] ui: restore: allow overwriting a guest with a backup of another guest Thomas Lamprecht
2026-11-19 19:19 ` [PATCH manager v5 32/41] ui: migrate: refuse target nodes that would drop the guest identity Thomas Lamprecht
2026-11-19 19:19 ` [PATCH manager v5 33/41] ui: guest summary: show " Thomas Lamprecht
2026-11-19 19:19 ` [PATCH manager v5 34/41] api: bulk migrate: refuse targets that would drop " Thomas Lamprecht
2026-11-19 19:19 ` [PATCH manager v5 35/41] vzdump: notes template: add the guest uid as variable Thomas Lamprecht
2026-11-19 19:19 ` [PATCH docs v5 36/41] vzdump: restore: describe what a failed restore can leave behind Thomas Lamprecht
2026-11-19 19:19 ` [PATCH docs v5 37/41] vzdump: describe the guest identity of VMs and containers Thomas Lamprecht
2026-11-19 19:19 ` [PATCH docs v5 38/41] pvecm: document the cluster ID and how to get a new one Thomas Lamprecht
2026-11-19 19:19 ` [PATCH docs v5 39/41] qm: configuration: describe the read-only meta property Thomas Lamprecht
2026-11-19 19:19 ` [PATCH docs v5 40/41] pct: " Thomas Lamprecht
2026-11-19 19:19 ` [PATCH docs v5 41/41] vzdump: notes: document the uid template variable Thomas Lamprecht
2026-11-20  3:07 ` [PATCH cluster/guest-common/qemu-server/container/manager/docs v5 00/41] fix #7846: guest identity (uid) and cluster ID Thomas Lamprecht

Reply instructions:

You may reply publicly to this message via plain-text email
using any one of the following methods:

* Save the following mbox file, import it into your mail client,
  and reply-to-all from there: mbox

  Avoid top-posting and favor interleaved quoting:
  https://en.wikipedia.org/wiki/Posting_style#Interleaved_style

* Reply using the --to, --cc, and --in-reply-to
  switches of git-send-email(1):

  git send-email \
    --in-reply-to=20261119191914.2336934-24-t.lamprecht@proxmox.com \
    --to=t.lamprecht@proxmox.com \
    --cc=pve-devel@lists.proxmox.com \
    /path/to/YOUR_REPLY

  https://kernel.org/pub/software/scm/git/docs/git-send-email.html

* If your mail client supports setting the In-Reply-To header
  via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox
Service provided by Proxmox Server Solutions GmbH | Privacy | Legal