public inbox for pve-devel@lists.proxmox.com
 help / color / mirror / Atom feed
From: Thomas Lamprecht <t.lamprecht@proxmox.com>
To: pve-devel@lists.proxmox.com
Subject: [PATCH manager 26/34] api: cluster resources: add guest uid and registration time
Date: Mon, 16 Nov 2026 01:46:38 +0100	[thread overview]
Message-ID: <20261116004703.2908294-27-t.lamprecht@proxmox.com> (raw)
In-Reply-To: <20261116004703.2908294-1-t.lamprecht@proxmox.com>

Tools that follow guests across restores and migrations, for example
backup products, need the guest identity. Report the 'uid' and 'rtime'
of guests that have them on their rows, so such tools get both for all
guests with one call instead of reading each guest config. Like lock
and tags, they are only reported to users with VM.Audit on the guest.

Both come from the 'meta' line, which the existing request for lock and
tags now also returns, so there is no extra round trip to pmxcfs. The
line is parsed per guest, and a guest with a missing or malformed
identity only lacks the fields. Neither the raw line nor its other
members are exposed.

Signed-off-by: Thomas Lamprecht <t.lamprecht@proxmox.com>
---
 PVE/API2/Cluster.pm           |  25 +++-
 test/ClusterResources_test.pl | 249 ++++++++++++++++++++++++++++++++++
 test/Makefile                 |   6 +-
 3 files changed, 278 insertions(+), 2 deletions(-)
 create mode 100755 test/ClusterResources_test.pl

diff --git a/PVE/API2/Cluster.pm b/PVE/API2/Cluster.pm
index 4e5efbfd..346ecdb2 100644
--- a/PVE/API2/Cluster.pm
+++ b/PVE/API2/Cluster.pm
@@ -11,6 +11,7 @@ use PVE::DataCenterConfig;
 use PVE::Exception qw(raise_param_exc);
 use PVE::Firewall;
 use PVE::GuestHelpers;
+use PVE::GuestIdentity;
 use PVE::HA::Config;
 use PVE::HA::Env::PVE2;
 use PVE::INotify;
@@ -474,6 +475,22 @@ __PACKAGE__->register_method({
                     optional => 1,
                     default => 0,
                 },
+                uid => {
+                    description =>
+                        "Guest lineage identifier, normally kept across restores and migrations"
+                        . " from other clusters (for types 'qemu' and 'lxc').",
+                    type => 'string',
+                    optional => 1,
+                },
+                rtime => {
+                    description =>
+                        "Time the guest was registered in this cluster, for example by"
+                        . " creation, restore, or migration from another cluster, in milliseconds"
+                        . " since the UNIX epoch (for types 'qemu' and 'lxc').",
+                    type => 'integer',
+                    minimum => 0,
+                    optional => 1,
+                },
                 network => {
                     description => "The name of a Network entity (for type 'network').",
                     type => "string",
@@ -552,7 +569,7 @@ __PACKAGE__->register_method({
         # we try to generate 'numbers' by using "$X + 0"
         if (!$param->{type} || $param->{type} eq 'vm') {
             my $prop_list = [qw(lock tags)];
-            my $props = PVE::Cluster::get_guest_config_properties($prop_list);
+            my $props = PVE::Cluster::get_guest_config_properties([@$prop_list, 'meta']);
 
             for my $vmid (sort keys %$idlist) {
 
@@ -593,6 +610,12 @@ __PACKAGE__->register_method({
                     }
                 }
 
+                my $identity = PVE::GuestIdentity::parse_identity($props->{$vmid}->{meta});
+                if ($identity) {
+                    $entry->{uid} = $identity->{uid};
+                    $entry->{rtime} = int($identity->{rtime}) if defined($identity->{rtime});
+                }
+
                 if (
                     defined($entry->{pool})
                     && !$rpcenv->check($authuser, "/pool/$entry->{pool}", ['Pool.Audit'], 1)
diff --git a/test/ClusterResources_test.pl b/test/ClusterResources_test.pl
new file mode 100755
index 00000000..4b981dc7
--- /dev/null
+++ b/test/ClusterResources_test.pl
@@ -0,0 +1,249 @@
+#!/usr/bin/perl
+
+use v5.36;
+
+use lib ('.', '..');
+
+use JSON;
+use Test::MockModule;
+use Test::More;
+
+use PVE::JSONSchema;
+
+use PVE::API2::Cluster;
+
+my $uid_100 = 'k3d7q2mxa5vb4n6pw2fz';
+my $uid_101 = 'r6t2w4y7z3c5e2g4h7jm';
+my $uid_104 = 'q2w3e4r5t6y7u2i3o4pa';
+
+# top-level config values per guest as decoded from the pmxcfs reply, plus whether the user has
+# VM.Audit on it; node2 is offline
+my $guests;
+my $default_guests = {
+    100 => {
+        type => 'qemu',
+        node => 'node1',
+        audit => 1,
+        lock => 'backup',
+        tags => 'prod;web',
+        meta => "creation-qemu=9.2.0,ctime=1700000000,rtime=1731600000123,uid=$uid_100",
+    },
+    101 => { type => 'lxc', node => 'node2', audit => 1, meta => "uid=$uid_101" },
+    102 => {
+        type => 'qemu',
+        node => 'node1',
+        audit => 1,
+        meta => 'rtime=1731600000123,uid=NOT-A-UID',
+    },
+    103 => { type => 'qemu', node => 'node1', audit => 1, lock => 'migrate' },
+    104 => { type => 'qemu', node => 'node2', audit => 1, meta => "rtime=12x,uid=$uid_104" },
+    105 => {
+        type => 'lxc',
+        node => 'node1',
+        audit => 0,
+        meta => "rtime=1731600000123,uid=$uid_100",
+    },
+};
+
+my $default_identities = {
+    100 => { uid => $uid_100, rtime => 1731600000123 },
+    101 => { uid => $uid_101 },
+    102 => {},
+    103 => {},
+    104 => { uid => $uid_104 },
+};
+
+my $property_requests;
+my $ipc_failures = 0;
+
+my $cluster_mock = Test::MockModule->new('PVE::Cluster');
+$cluster_mock->redefine(
+    get_nodelist => sub { return ['node1', 'node2'] },
+    get_members => sub {
+        return { node1 => { id => 1, online => 1 }, node2 => { id => 2, online => 0 } };
+    },
+    rrd_dump => sub { return {} },
+    get_node_kv => sub { return {} },
+    get_vmlist => sub {
+        my $ids = {};
+        for my $vmid (keys %$guests) {
+            my $guest = $guests->{$vmid};
+            $ids->{$vmid} = { node => $guest->{node}, type => $guest->{type}, version => 1 };
+        }
+        return { ids => $ids };
+    },
+    get_guest_config_properties => sub($properties, $vmid = undef) {
+        die "only the request for all guests is expected\n" if defined($vmid);
+        push @$property_requests, [@$properties];
+        die "ipcc_send_rec[11] failed: Connection refused\n" if $ipc_failures-- > 0;
+
+        my $res = {};
+        for my $id (keys %$guests) {
+            for my $prop (@$properties) {
+                my $value = $guests->{$id}->{$prop} // next;
+                $res->{$id}->{$prop} = $value;
+            }
+        }
+        return $res;
+    },
+);
+
+my $ha_config_mock = Test::MockModule->new('PVE::HA::Config');
+$ha_config_mock->redefine(
+    read_manager_status => sub { return {} },
+    read_resources_config => sub { return { ids => {} } },
+);
+
+my $storage_mock = Test::MockModule->new('PVE::Storage');
+$storage_mock->redefine(
+    config => sub { return { ids => {} } },
+    storage_ids => sub { return () },
+);
+
+my $rpcenv = bless { user_cfg => { pools => { p1 => {} }, vms => { 100 => 'p1' } } },
+    'PVE::RPCEnvironment::Test';
+sub PVE::RPCEnvironment::Test::get_user { return 'auditor@pve'; }
+
+sub PVE::RPCEnvironment::Test::check($self, $user, $path, $privs, $noerr) {
+    return 1 if $path eq '/pool/p1' && grep { $_ eq 'Pool.Audit' } @$privs;
+    my ($vmid) = $path =~ m!^/vms/(\d+)$! or return 0;
+    return $guests->{$vmid}->{audit} && grep { $_ eq 'VM.Audit' } @$privs;
+}
+my $rpc_mock = Test::MockModule->new('PVE::RPCEnvironment');
+$rpc_mock->redefine(get => sub { return $rpcenv });
+
+my $method = PVE::API2::Cluster->map_method_by_name('resources');
+
+# returns the rows and their JSON encoding, which is what API clients see
+sub get_rows($param) {
+    $property_requests = [];
+
+    my $res = PVE::API2::Cluster->handle($method, $param);
+    my $json = JSON->new->utf8->canonical->encode($res);
+
+    PVE::JSONSchema::validate($res, $method->{returns}, "return schema violated\n");
+
+    return ($res, $json);
+}
+
+sub guest_rows($res) {
+    return { map { $_->{vmid} => $_ } grep { $_->{type} =~ m/^(?:qemu|lxc)$/ } @$res };
+}
+
+sub identity_view($res) {
+    my $rows = guest_rows($res);
+
+    my $view = {};
+    for my $vmid (keys %$rows) {
+        my $row = $rows->{$vmid};
+        $view->{$vmid} = { map { $_ => $row->{$_} } grep { exists($row->{$_}) } qw(uid rtime) };
+    }
+    return $view;
+}
+
+subtest 'identity of guests with valid, partial, invalid and missing meta' => sub {
+    $guests = {%$default_guests};
+
+    my ($res, $json) = get_rows({ type => 'vm' });
+    my $rows = guest_rows($res);
+
+    is_deeply(
+        $property_requests,
+        [[qw(lock tags meta)]],
+        'meta is fetched together with lock and tags in a single request',
+    );
+
+    is_deeply(
+        identity_view($res),
+        $default_identities,
+        'uid and rtime only where valid, guests without VM.Audit are not listed',
+    );
+
+    like($json, qr/"rtime":1731600000123[,}]/, 'rtime is encoded as JSON number');
+    like($json, qr/"uid":"$uid_100"/, 'uid is encoded as JSON string');
+
+    is($rows->{100}->{lock}, 'backup', 'lock is still reported');
+    is($rows->{100}->{tags}, 'prod;web', 'tags are still reported');
+    is($rows->{103}->{lock}, 'migrate', 'lock of a guest without meta is still reported');
+
+    for my $key (qw(meta ctime creation-qemu)) {
+        ok(!grep({ exists($_->{$key}) } @$res), "no '$key' in any row");
+    }
+};
+
+subtest 'listing of all resource types' => sub {
+    $guests = {%$default_guests};
+
+    my ($res) = get_rows({});
+
+    is(scalar(@$property_requests), 1, 'guest config properties are requested once');
+    is_deeply(identity_view($res), $default_identities, 'same identities as for type vm');
+    is(guest_rows($res)->{101}->{status}, 'unknown', 'guest on offline node is listed');
+
+    my @others = grep { $_->{type} !~ m/^(?:qemu|lxc)$/ } @$res;
+    is_deeply(
+        [sort map { $_->{id} } @others],
+        ['/pool/p1', 'node/node1', 'node/node2'],
+        'pool and node rows are listed',
+    );
+    ok(!grep({ exists($_->{uid}) || exists($_->{rtime}) } @others),
+        'no identity on other rows');
+};
+
+subtest 'control character or replacement character in meta' => sub {
+    # pmxcfs escapes control characters and replaces bytes that are not valid UTF-8 with U+FFFD
+    $guests = {
+        %$default_guests,
+        106 => {
+            type => 'qemu',
+            node => 'node1',
+            audit => 1,
+            lock => 'backup',
+            meta => "rtime=1731600000123,uid=k3d7q2mx\ta5vb4n6p",
+        },
+        107 => {
+            type => 'qemu',
+            node => 'node1',
+            audit => 1,
+            meta => "rtime=1731600000123,uid=k3d7q2mx\x{FFFD}5vb4n6p",
+        },
+        108 => {
+            type => 'lxc',
+            node => 'node1',
+            audit => 1,
+            meta => "ctime=17000\x{1}00000,rtime=1731600000456,uid=z2y3x4w5v6u7t2s3r4qn",
+        },
+    };
+
+    my ($res) = eval { get_rows({ type => 'vm' }) };
+    is($@, '', 'listing does not fail');
+
+    is_deeply(
+        identity_view($res),
+        {
+            %$default_identities,
+            106 => {},
+            107 => {},
+            108 => { uid => 'z2y3x4w5v6u7t2s3r4qn', rtime => 1731600000456 },
+        },
+        'only the guests with a malformed uid lack the identity',
+    );
+    is(guest_rows($res)->{106}->{lock}, 'backup', 'lock of such a guest is still reported');
+};
+
+subtest 'transient IPC failure fails the listing' => sub {
+    $guests = {%$default_guests};
+    $ipc_failures = 1;
+
+    eval { get_rows({ type => 'vm' }) };
+    like(
+        $@,
+        qr/Connection refused/,
+        'error is raised instead of listing guests without identity',
+    );
+    is(scalar(@$property_requests), 1, 'request is not repeated');
+
+    $ipc_failures = 0;
+};
+
+done_testing();
diff --git a/test/Makefile b/test/Makefile
index 2dfd20a4..7eaa46a2 100644
--- a/test/Makefile
+++ b/test/Makefile
@@ -5,7 +5,7 @@ all:
 export PERLLIB=..
 
 .PHONY: check
-check: test-replication test-balloon test-vzdump test-osd test-ceph-health test-ceph-services test-ceph-auth test-ceph-key-migration test-ceph-lockbox-migration test-custom-cpu-models test-pvesh
+check: test-replication test-balloon test-vzdump test-osd test-ceph-health test-ceph-services test-ceph-auth test-ceph-key-migration test-ceph-lockbox-migration test-custom-cpu-models test-pvesh test-cluster-resources
 
 .PHONY: test-balloon
 test-balloon:
@@ -61,6 +61,10 @@ test-custom-cpu-models:
 test-pvesh:
 	./pvesh_test.pl
 
+.PHONY: test-cluster-resources
+test-cluster-resources:
+	./ClusterResources_test.pl
+
 .PHONY: install
 install:
 
-- 
2.47.3





  parent reply	other threads:[~2026-11-16  0:51 UTC|newest]

Thread overview: 49+ messages / expand[flat|nested]  mbox.gz  Atom feed  top
2026-11-16  0:46 [PATCH cluster/guest-common/qemu-server/container/manager/docs 00/34] fix #7846: guest identity (uid) and cluster ID Thomas Lamprecht
2026-11-16  0:46 ` [PATCH cluster 01/34] pmxcfs: reject changes to the cluster ID file from user space Thomas Lamprecht
2026-11-16  0:46 ` [PATCH cluster 02/34] pmxcfs: generate a cluster ID on standalone nodes Thomas Lamprecht
2026-11-16  0:46 ` [PATCH cluster 03/34] pmxcfs: dfsm: add a callback that runs once all members are in sync Thomas Lamprecht
2026-11-16  0:46 ` [PATCH cluster 04/34] pmxcfs: quorum: pass the corosync membership to an optional listener Thomas Lamprecht
2026-11-16  0:46 ` [PATCH cluster 05/34] pmxcfs: dcdb: generate the cluster ID once the cluster is in sync Thomas Lamprecht
2026-11-16  0:46 ` [PATCH cluster 06/34] cluster: add helper to read the cluster ID Thomas Lamprecht
2026-11-16  0:46 ` [PATCH cluster 07/34] pmxcfs: allow removing the cluster ID file in forced local mode Thomas Lamprecht
2026-11-16  0:46 ` [PATCH guest-common 08/34] guest identity: add helpers for the guest uid and registration time Thomas Lamprecht
2026-11-17 10:47   ` Dominik Csapak
2026-11-16  0:46 ` [PATCH guest-common 09/34] abstract config: assign a guest identity and keep it on config writes Thomas Lamprecht
2026-11-17 10:47   ` Dominik Csapak
2026-11-17 12:47     ` Dominik Csapak
2026-11-16  0:46 ` [PATCH guest-common 10/34] abstract config: let the VMID reservation return the previous state Thomas Lamprecht
2026-11-16  0:46 ` [PATCH guest-common 11/34] guest identity: allow taking over a uid that is unused in the cluster Thomas Lamprecht
2026-11-17 13:14   ` Dominik Csapak
2026-11-16  0:46 ` [PATCH qemu-server 12/34] api: restore: release the VMID if a restore to an unused VMID fails Thomas Lamprecht
2026-11-16  0:46 ` [PATCH qemu-server 13/34] api: migrate, clone: refuse targets that would drop the guest identity Thomas Lamprecht
2026-11-16  0:46 ` [PATCH qemu-server 14/34] fix #7846: config: add a guest identity to the 'meta' property Thomas Lamprecht
2026-11-16  0:46 ` [PATCH qemu-server 15/34] restore: take over the guest uid from the backup where possible Thomas Lamprecht
2026-11-17 15:17   ` Dominik Csapak
2026-11-16  0:46 ` [PATCH qemu-server 16/34] api: remote migration: take over the guest uid from the source Thomas Lamprecht
2026-11-17 15:26   ` Dominik Csapak
2026-11-16  0:46 ` [PATCH qemu-server 17/34] api: status: return the guest uid Thomas Lamprecht
2026-11-16  0:46 ` [PATCH container 18/34] config: add read-only meta property with the creation time Thomas Lamprecht
2026-11-16  0:46 ` [PATCH container 19/34] fix #7846: config: add a guest identity to the 'meta' property Thomas Lamprecht
2026-11-16  0:46 ` [PATCH container 20/34] api: migrate, clone: refuse targets that would drop the guest identity Thomas Lamprecht
2026-11-16  0:46 ` [PATCH container 21/34] restore: take over the guest uid from the backup where possible Thomas Lamprecht
2026-11-16  0:46 ` [PATCH container 22/34] restore: refuse overwriting a container with another guest's backup Thomas Lamprecht
2026-11-16  0:46 ` [PATCH container 23/34] migrate: remote: clean up the target on a tunnel version mismatch Thomas Lamprecht
2026-11-16  0:46 ` [PATCH container 24/34] api: remote migration: take over the guest uid from the source Thomas Lamprecht
2026-11-16  0:46 ` [PATCH container 25/34] api: status: return the guest uid Thomas Lamprecht
2026-11-16  0:46 ` Thomas Lamprecht [this message]
2026-11-17 15:30   ` [PATCH manager 26/34] api: cluster resources: add guest uid and registration time Dominik Csapak
2026-11-16  0:46 ` [PATCH manager 27/34] api: cluster status: add cluster ID Thomas Lamprecht
2026-11-16  0:46 ` [PATCH manager 28/34] ui: restore: allow overwriting a guest with a backup of another guest Thomas Lamprecht
2026-11-16  0:46 ` [PATCH manager 29/34] ui: migrate: refuse target nodes that would drop the guest identity Thomas Lamprecht
2026-11-16  0:46 ` [PATCH manager 30/34] ui: guest summary: show " Thomas Lamprecht
2026-11-17 15:44   ` Dominik Csapak
2026-11-16  0:46 ` [PATCH docs 31/34] vzdump: describe the guest identity of VMs and containers Thomas Lamprecht
2026-11-16  0:46 ` [PATCH docs 32/34] pvecm: document the cluster ID and how to get a new one Thomas Lamprecht
2026-11-16  0:46 ` [PATCH docs 33/34] qm: configuration: describe the read-only meta property Thomas Lamprecht
2026-11-16  0:46 ` [PATCH docs 34/34] pct: " Thomas Lamprecht
2026-11-17 10:47 ` [PATCH cluster/guest-common/qemu-server/container/manager/docs 00/34] fix #7846: guest identity (uid) and cluster ID Dominik Csapak
2026-11-17 11:29   ` Thomas Lamprecht
2026-11-17 11:55     ` Dominik Csapak
2026-11-17 12:47       ` Thomas Lamprecht
2026-11-17 13:54         ` Dominik Csapak
2026-11-17 15:55 ` Dominik Csapak

Reply instructions:

You may reply publicly to this message via plain-text email
using any one of the following methods:

* Save the following mbox file, import it into your mail client,
  and reply-to-all from there: mbox

  Avoid top-posting and favor interleaved quoting:
  https://en.wikipedia.org/wiki/Posting_style#Interleaved_style

* Reply using the --to, --cc, and --in-reply-to
  switches of git-send-email(1):

  git send-email \
    --in-reply-to=20261116004703.2908294-27-t.lamprecht@proxmox.com \
    --to=t.lamprecht@proxmox.com \
    --cc=pve-devel@lists.proxmox.com \
    /path/to/YOUR_REPLY

  https://kernel.org/pub/software/scm/git/docs/git-send-email.html

* If your mail client supports setting the In-Reply-To header
  via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox
Service provided by Proxmox Server Solutions GmbH | Privacy | Legal