[PATCH qemu-server v7 1/2] hotplug: factor out cleanup of disk devices

[Dominik Csapak <d.csapak@proxmox.com>]

Unplugging a disk or SCSI controller removes the same parts that need to
be removed when hotplugging one of them failed. Factor this out into a
helper, so it can be reused for cleaning up after a failed hotplug in a
following commit.

Pass the parsed drive to qemu_deletescsihw instead of parsing it from
the config again, since a disk that failed to hotplug is still pending
and not in the config yet.

No functional change intended.

Signed-off-by: Dominik Csapak <d.csapak@proxmox.com>
---
 src/PVE/QemuServer.pm | 34 +++++++++++++++++++---------------
 1 file changed, 19 insertions(+), 15 deletions(-)

diff --git a/src/PVE/QemuServer.pm b/src/PVE/QemuServer.pm
index 69a2bd64..5bed6afa 100644
--- a/src/PVE/QemuServer.pm
+++ b/src/PVE/QemuServer.pm
@@ -3854,6 +3854,20 @@ sub vm_devices_list {
     return $devices;
 }
 
+# clean up disks and their controllers (if unused afterwards)
+sub delete_disk_hardware {
+    my ($conf, $vmid, $deviceid, $device, $timeout) = @_;
+
+    qemu_devicedel($vmid, $deviceid);
+    qemu_devicedelverify($vmid, $deviceid, $timeout);
+    qemu_drivedel($vmid, $deviceid) if $deviceid =~ m/^(virtio|scsi)\d+$/;
+    # the iothread of a virtio-scsi-single disk belongs to its controller and is removed there
+    qemu_deletescsihw($conf, $vmid, $device) if $deviceid =~ m/^scsi\d+$/;
+    qemu_iothread_del($vmid, $deviceid) if $deviceid =~ m/^virtio(scsi)?\d+$/;
+
+    return;
+}
+
 sub vm_deviceplug {
     my ($storecfg, $conf, $vmid, $deviceid, $device, $arch, $machine_type) = @_;
 
@@ -3972,20 +3986,12 @@ sub vm_deviceunplug {
         qemu_devicedel($vmid, $deviceid);
         qemu_devicedelverify($vmid, $deviceid);
     } elsif ($deviceid =~ m/^(virtio)(\d+)$/) {
-        qemu_devicedel($vmid, $deviceid);
-        qemu_devicedelverify($vmid, $deviceid);
-        qemu_drivedel($vmid, $deviceid);
-        qemu_iothread_del($vmid, $deviceid);
+        delete_disk_hardware($conf, $vmid, $deviceid);
     } elsif ($deviceid =~ m/^(virtioscsi|scsihw)(\d+)$/) {
-        qemu_devicedel($vmid, $deviceid);
-        qemu_devicedelverify($vmid, $deviceid, 15);
-        qemu_iothread_del($vmid, $deviceid) if $deviceid =~ m/^virtioscsi\d+$/;
+        delete_disk_hardware($conf, $vmid, $deviceid, undef, 15);
     } elsif ($deviceid =~ m/^(scsi)(\d+)$/) {
-        qemu_devicedel($vmid, $deviceid);
-        qemu_devicedelverify($vmid, $deviceid);
-        qemu_drivedel($vmid, $deviceid);
-        # the iothread of a virtio-scsi-single disk belongs to its controller and is removed there
-        qemu_deletescsihw($conf, $vmid, $deviceid);
+        my $device = parse_drive($deviceid, $conf->{$deviceid});
+        delete_disk_hardware($conf, $vmid, $deviceid, $device);
     } elsif ($deviceid =~ m/^(net)(\d+)$/) {
         qemu_devicedel($vmid, $deviceid);
         qemu_devicedelverify($vmid, $deviceid);
@@ -4124,9 +4130,7 @@ sub qemu_findorcreatescsihw {
 }
 
 sub qemu_deletescsihw {
-    my ($conf, $vmid, $opt) = @_;
-
-    my $device = parse_drive($opt, $conf->{$opt});
+    my ($conf, $vmid, $device) = @_;
 
     if ($conf->{scsihw} && ($conf->{scsihw} eq 'virtio-scsi-single')) {
         vm_deviceunplug($vmid, $conf, "virtioscsi$device->{index}");
-- 
2.47.3