[PATCH installer v4 13/30] install: config: add option for setting up bond on management interface

[Christoph Heiss <c.heiss@proxmox.com>]

Prerequisite for the rest of the installer to support setting up a bond
as management interface during installations.

Signed-off-by: Christoph Heiss <c.heiss@proxmox.com>
---
Changes v3 -> v4:
  * no changes

Changes v2 -> v3:
  * add comments to new Proxmox::Sys::Net subroutines
  * fix up line length on comments
  * compare MAC addresses case-insensitively (@thanks Thomas)
  * allow clearing the primary bond interface (@thanks Thomas)

Changes v1 -> v2:
  * no changes

 Proxmox/Install/Config.pm | 47 +++++++++++++++++++++++++++++++++++++++
 Proxmox/Sys/Net.pm        | 34 ++++++++++++++++++++++++++++
 2 files changed, 81 insertions(+)

diff --git a/Proxmox/Install/Config.pm b/Proxmox/Install/Config.pm
index dba3692..967712a 100644
--- a/Proxmox/Install/Config.pm
+++ b/Proxmox/Install/Config.pm
@@ -103,6 +103,21 @@ my sub init_cfg {
         # network related
         mngmt_nic => undef,
 
+        # Options for creating a bond for the management interface with the given physical
+        # interfaces and mode.
+        mngmt_bond => {
+            # MAC addresses of member interfaces. If empty, bonding is disabled.
+            members => [],
+            # must be one of: 'balance-rr', 'active-backup', 'balance-xor', 'broadcast',
+            # '802.3ad', 'balance-tlb', 'balance-alb'
+            mode => 'active-backup', # recommended by our docs
+            # hash policy, only used with '802.3ad' and 'balance-xor' mode
+            # must be one of 'layer2', 'layer2+3', 'layer3+4'
+            hash_policy => 'layer2',
+            # MAC address of primary bond interface, only used with 'active-backup' mode, optional
+            primary_interface => undef,
+        },
+
         # maps mac address -> custom name
         # if set to a hash, enables interface name pinning for all interfaces
         network_interface_pin_map => undef,
@@ -257,6 +272,38 @@ sub get_subscription_key { return get('subscription_key'); }
 sub set_mngmt_nic { set_key('mngmt_nic', $_[0]); }
 sub get_mngmt_nic { return get('mngmt_nic'); }
 
+sub set_mngmt_bond_opt {
+    my ($k, $v) = @_;
+    my $opts = get('mngmt_bond');
+
+    croak "unknown management bond option key '$k'" if !exists($opts->{$k});
+
+    die "unknown bond mode '$v'\n"
+        if $k eq 'mode' && !Proxmox::Sys::Net::is_valid_bond_mode($v);
+    die "unknown bond hash policy '$v'\n"
+        if $k eq 'hash_policy' && !Proxmox::Sys::Net::is_valid_bond_hash_policy($v);
+
+    # allow setting no interfaces (disabling bonding), or 2+ for enabling it
+    die "at least 2 member interfaces are required for bond\n"
+        if $k eq 'members' && scalar($v->@*) == 1;
+    die "primary interface '$v' is not a member of the bond\n"
+        if $k eq 'primary_interface'
+        && defined($v)
+        && !grep { lc($_) eq lc($v) } $opts->{members}->@*;
+
+    $opts->{$k} = $v;
+}
+
+sub get_mngmt_bond_opt {
+    my ($k) = @_;
+    my $opts = get('mngmt_bond');
+    return defined($k) ? $opts->{$k} : $opts;
+}
+
+sub get_mngmt_bond_enabled { # virtual config
+    return scalar(get_mngmt_bond_opt('members')->@*) >= 2;
+}
+
 sub set_network_interface_pin_map { set_key('network_interface_pin_map', $_[0]); }
 sub get_network_interface_pin_map { return get('network_interface_pin_map'); }
 
diff --git a/Proxmox/Sys/Net.pm b/Proxmox/Sys/Net.pm
index c43311d..630d96a 100644
--- a/Proxmox/Sys/Net.pm
+++ b/Proxmox/Sys/Net.pm
@@ -15,6 +15,8 @@ our @EXPORT_OK = qw(
     parse_ip_mask
     parse_fqdn
     validate_link_pin_map
+    is_valid_bond_mode
+    is_valid_bond_hash_policy
     MIN_IFNAME_LEN
     MAX_IFNAME_LEN
     DEFAULT_PIN_PREFIX
@@ -450,4 +452,36 @@ sub validate_link_pin_map : prototype($) {
     }
 }
 
+# Checks whether the given string is a valid network bond mode, as accepted by
+# ifupdown2.
+sub is_valid_bond_mode {
+    my ($mode) = @_;
+
+    my $valid = {
+        'active-backup' => 1,
+        'balance-alb' => 1,
+        'balance-rr' => 1,
+        'balance-tlb' => 1,
+        'balance-xor' => 1,
+        'broadcast' => 1,
+        '802.3ad' => 1,
+    };
+
+    return exists($valid->{$mode});
+}
+
+# Checks whether the given string is a valid network bond hash policy, as
+# accepted by ifupdown2.
+sub is_valid_bond_hash_policy {
+    my ($policy) = @_;
+
+    my $valid = {
+        layer2 => 1,
+        'layer2+3' => 1,
+        'layer3+4' => 1,
+    };
+
+    return exists($valid->{$policy});
+}
+
 1;
-- 
2.55.0