[PATCH qemu-server 5/9] blockdev: implement reopen function

[Fiona Ebner <f.ebner@proxmox.com>]

Similar to the attach() function, but for re-opening an already
attached block node. Currently limited to non-throttle nodes.

Signed-off-by: Fiona Ebner <f.ebner@proxmox.com>
---
 src/PVE/QemuServer/Blockdev.pm | 68 ++++++++++++++++++++++++++++------
 1 file changed, 57 insertions(+), 11 deletions(-)

diff --git a/src/PVE/QemuServer/Blockdev.pm b/src/PVE/QemuServer/Blockdev.pm
index 879e1aab..dea46ca0 100644
--- a/src/PVE/QemuServer/Blockdev.pm
+++ b/src/PVE/QemuServer/Blockdev.pm
@@ -548,6 +548,33 @@ my sub blockdev_add {
 
 =pod
 
+=head3 generate_drive_blockdev_for_peer
+
+Helper for the C<attach> and C<reopen> functions, see C<attach> for the parameter descriptions.
+Returns the generated blockdev and the QMP peer information.
+
+=cut
+
+my sub generate_drive_blockdev_for_peer {
+    my ($storecfg, $id, $drive, $options) = @_;
+
+    my $qmp_peer = $options->{qsd} ? qsd_qmp_peer($id) : vm_qmp_peer($id);
+
+    my $machine_version;
+    if ($options->{qsd}) { # qemu-storage-daemon runs with the installed binary version
+        $machine_version =
+            'pc-i440fx-' . PVE::QemuServer::Machine::latest_installed_machine_version();
+    } else {
+        $machine_version = PVE::QemuServer::Machine::get_current_qemu_machine($id);
+    }
+
+    my $blockdev = generate_drive_blockdev($storecfg, $drive, $machine_version, $options);
+
+    return ($blockdev, $qmp_peer);
+}
+
+=pod
+
 =head3 attach
 
     my ($node_name, $read_only) = attach($storecfg, $id, $drive, $options);
@@ -596,17 +623,7 @@ state image.
 sub attach {
     my ($storecfg, $id, $drive, $options) = @_;
 
-    my $qmp_peer = $options->{qsd} ? qsd_qmp_peer($id) : vm_qmp_peer($id);
-
-    my $machine_version;
-    if ($options->{qsd}) { # qemu-storage-daemon runs with the installed binary version
-        $machine_version =
-            'pc-i440fx-' . PVE::QemuServer::Machine::latest_installed_machine_version();
-    } else {
-        $machine_version = PVE::QemuServer::Machine::get_current_qemu_machine($id);
-    }
-
-    my $blockdev = generate_drive_blockdev($storecfg, $drive, $machine_version, $options);
+    my ($blockdev, $qmp_peer) = generate_drive_blockdev_for_peer($storecfg, $id, $drive, $options);
 
     my $throttle_group_id;
     if (parse_top_node_name($blockdev->{'node-name'})) { # device top nodes need a throttle group
@@ -713,6 +730,35 @@ sub detach_fleecing_block_nodes {
     }
 }
 
+=pod
+
+=head3 reopen
+
+    reopen($storecfg, $id, $drive, $options);
+
+Re-open the already attached drive C<$drive> of the VM C<$id> while considering the additional
+options C<$options>. See C<attach> for the description of parameters and options. The C<no-throttle>
+option is currently required to be set.
+
+=cut
+
+sub reopen {
+    my ($storecfg, $id, $drive, $options) = @_;
+
+    # Will need additional consideration regarding the throttle group objects.
+    die "reopen for a throttle node is not implemented yet\n" if !$options->{'no-throttle'};
+
+    my ($blockdev, $qmp_peer) = generate_drive_blockdev_for_peer($storecfg, $id, $drive, $options);
+
+    if ($blockdev->{driver} eq 'zeroinit') { # zero-init does not support re-open, defer to child
+        $blockdev = $blockdev->{file};
+    }
+
+    qmp_cmd($qmp_peer, 'blockdev-reopen', options => [$blockdev]);
+
+    return;
+}
+
 sub resize {
     my ($vmid, $deviceid, $storecfg, $volid, $size) = @_;
 
-- 
2.47.3