public inbox for pve-devel@lists.proxmox.com
 help / color / mirror / Atom feed
From: Thomas Lamprecht <t.lamprecht@proxmox.com>
To: pve-devel@lists.proxmox.com
Subject: [PATCH qemu-server v3 15/38] api: migrate, clone: refuse targets that would drop the guest identity
Date: Wed, 18 Nov 2026 05:37:27 +0100	[thread overview]
Message-ID: <20261118043817.1659212-16-t.lamprecht@proxmox.com> (raw)
In-Reply-To: <20261118043817.1659212-1-t.lamprecht@proxmox.com>

Older qemu-server versions reject the identity members of 'meta' and
drop the whole property when they write the config. A guest that moves
to such a node loses its identity, and gets a new one with a later
write by an upgraded node.

Refuse online and offline migrations and clones to another node unless
the target reports a Proxmox VE version that keeps the identity. Use the
shared version threshold and treat missing version information as too
old. Report the reason and the versions involved in the migration
preconditions, so that clients can explain the refusal. Leave such nodes
out of the nodes reported for the clone and copy features, which the web
interface uses to validate the target of a clone. The snapshot feature,
which the web interface polls, keeps reporting all nodes without
looking up their versions.

Check before starting the task or handing an API migration request to
HA. This does not keep an HA resource plugin from shutting down a VM
for a relocation before it calls the migration API.

Signed-off-by: Thomas Lamprecht <t.lamprecht@proxmox.com>
---

changes v2 -> v3:
* describe the refusal reason per node, on top of the independent schema
  fix, and validate complete responses in the test
* feature API: no version lookups for 'snapshot' requests

changes v1 -> v2:
* leave such nodes out of the nodes of the clone feature, which the
  clone dialog uses
* use the shared schema for the precondition result

 src/PVE/API2/Qemu.pm      |  27 +++++-
 src/test/run_api_tests.pl | 168 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 194 insertions(+), 1 deletion(-)

diff --git a/src/PVE/API2/Qemu.pm b/src/PVE/API2/Qemu.pm
index 1a3f2ce9..5954dd8e 100644
--- a/src/PVE/API2/Qemu.pm
+++ b/src/PVE/API2/Qemu.pm
@@ -29,6 +29,7 @@ use PVE::RESTHandler;
 use PVE::ReplicationConfig;
 use PVE::GuestHelpers qw(assert_tag_permissions);
 use PVE::GuestID;
+use PVE::GuestIdentity;
 use PVE::GuestImport;
 use PVE::QemuConfig;
 use PVE::QemuServer;
@@ -4394,6 +4395,8 @@ __PACKAGE__->register_method({
         properties => {
             hasFeature => { type => 'boolean' },
             nodes => {
+                description => "Nodes on which the storages of the VM are available, for"
+                    . " 'clone' and 'copy' only those that keep the guest identity.",
                 type => 'array',
                 items => { type => 'string' },
             },
@@ -4422,6 +4425,15 @@ __PACKAGE__->register_method({
         my $storecfg = PVE::Storage::config();
 
         my $nodelist = PVE::QemuServer::shared_nodes($conf, $storecfg);
+        # a clone to another node is refused if that node would drop the guest identity
+        if ($feature ne 'snapshot') {
+            my $nodename = PVE::INotify::nodename();
+            for my $other (keys $nodelist->%*) {
+                next if $other eq $nodename;
+                delete $nodelist->{$other}
+                    if PVE::GuestIdentity::node_identity_unsupported($other);
+            }
+        }
         my $hasFeature =
             PVE::QemuConfig->has_feature($feature, $conf, $storecfg, $snapname, $running);
 
@@ -4554,7 +4566,10 @@ __PACKAGE__->register_method({
 
         my $load_and_check = sub {
             $rpcenv->check_pool_exist($pool) if defined($pool);
-            PVE::Cluster::check_node_exists($target) if $target;
+            if ($target) {
+                PVE::Cluster::check_node_exists($target);
+                PVE::GuestIdentity::assert_node_supports_identity($target);
+            }
 
             my $storecfg = PVE::Storage::config();
 
@@ -5443,6 +5458,8 @@ __PACKAGE__->register_method({
                                 },
                             },
                         },
+                        'guest-identity-unsupported' =>
+                            PVE::GuestIdentity::node_identity_unsupported_schema(),
                     },
                 },
                 description => "Not allowed nodes, keyed by node name, with the reasons.",
@@ -5585,6 +5602,12 @@ __PACKAGE__->register_method({
                     $blocking_ha_resources;
             }
 
+            # the migration refuses nodes that would drop the guest identity
+            if (my $unsupported = PVE::GuestIdentity::node_identity_unsupported($node)) {
+                $res->{not_allowed_nodes}->{$node}->{'guest-identity-unsupported'} =
+                    $unsupported;
+            }
+
             # if nothing came up, add it to the allowed nodes
             if (scalar($res->{not_allowed_nodes}->{$node}->%*) == 0) {
                 push $res->{allowed_nodes}->@*, $node;
@@ -5697,6 +5720,8 @@ __PACKAGE__->register_method({
 
         PVE::Cluster::check_node_exists($target);
 
+        PVE::GuestIdentity::assert_node_supports_identity($target);
+
         my $targetip = PVE::Cluster::remote_node_ip($target);
 
         my $vmid = extract_param($param, 'vmid');
diff --git a/src/test/run_api_tests.pl b/src/test/run_api_tests.pl
index 4d5e1cdf..cc9cbadf 100755
--- a/src/test/run_api_tests.pl
+++ b/src/test/run_api_tests.pl
@@ -13,6 +13,7 @@ use Test::MockModule;
 use Test::More;
 
 use PVE::API2::Qemu;
+use PVE::GuestIdentity;
 use PVE::RPCEnvironment;
 
 my $rpcenv = PVE::RPCEnvironment->init('cli');
@@ -38,6 +39,31 @@ sub mock_unreachable_config {
 }
 mock_unreachable_config();
 
+my $qemu_server_module = Test::MockModule->new('PVE::QemuServer');
+$qemu_server_module->mock(check_running => sub { return 0; });
+
+# Proxmox VE versions the cluster nodes report, undef for none
+my $node_versions = {};
+
+my $cluster_module = Test::MockModule->new('PVE::Cluster');
+$cluster_module->mock(
+    check_cfs_quorum => sub { return 1; },
+    check_node_exists => sub { return 1; },
+    remote_node_ip => sub { return '192.0.2.2'; },
+    get_node_pvecfg_version => sub {
+        my ($node) = @_;
+        return $node_versions->{$node};
+    },
+    node_pvecfg_version_at_least => sub {
+        my ($node, @required) = @_;
+        my @version = split(/\./, $node_versions->{$node} // return 0);
+        for my $i (0 .. 2) {
+            return $version[$i] > $required[$i] if $version[$i] != $required[$i];
+        }
+        return 1;
+    },
+);
+
 # Returns the error of calling the API method $method with $param, either the parameter errors as
 # hash or the error message.
 sub api_error {
@@ -145,4 +171,146 @@ subtest 'pending changes of meta are dropped' => sub {
     mock_unreachable_config();
 };
 
+my $min_version = PVE::GuestIdentity::MIN_PVE_MANAGER_VERSION;
+my $node_cases = [
+    [$min_version, "reached load_config\n"],
+    ['10.0.0', "reached load_config\n"],
+    [
+        '9.2.0',
+        "node 'pve2' runs Proxmox VE 9.2.0, keeping the guest identity requires $min_version or"
+            . " newer - upgrade the node first\n",
+    ],
+    [
+        undef,
+        "node 'pve2' does not report its Proxmox VE version, so it is unknown whether the node"
+            . " keeps the guest identity\n",
+    ],
+];
+
+for my $case ($node_cases->@*) {
+    my ($version, $expected) = $case->@*;
+    $node_versions->{pve2} = $version;
+    my $what = 'target node with ' . ($version // 'no') . ' version';
+
+    is(
+        api_error('migrate_vm', { target => 'pve2' }), $expected, "migrate_vm: offline, $what",
+    );
+    is(
+        api_error('migrate_vm', { target => 'pve2', online => 1 }),
+        $expected,
+        "migrate_vm: online, $what",
+    );
+    is(
+        api_error('clone_vm', { newid => 101, target => 'pve2' }), $expected, "clone_vm: $what",
+    );
+}
+
+$node_versions->{pve2} = undef;
+is(
+    api_error('clone_vm', { newid => 101 }),
+    "reached load_config\n",
+    'clone_vm: no check without target node',
+);
+
+subtest 'migration preconditions' => sub {
+    my $nodes = ['localhost', 'pve2', 'pve3', 'pve4'];
+    $cluster_module->mock(get_nodelist => sub { return $nodes; });
+    my $inotify_module = Test::MockModule->new('PVE::INotify');
+    $inotify_module->mock(nodename => sub { return 'localhost'; });
+
+    $qemu_config_module->mock(load_config => sub { return { memory => 512 }; });
+    my $migrate_helpers_module = Test::MockModule->new('PVE::QemuMigrate::Helpers');
+    $migrate_helpers_module->mock(
+        check_local_resources => sub {
+            return ([], {}, { map { $_ => [] } $nodes->@* });
+        },
+    );
+    my $ha_config_module = Test::MockModule->new('PVE::HA::Config');
+    $ha_config_module->mock(vm_is_ha_managed => sub { return 0; });
+
+    $node_versions->@{ 'pve2', 'pve3', 'pve4' } = ($min_version, '9.2.0', undef);
+
+    my $res = PVE::API2::Qemu->migrate_vm_precondition({ node => 'localhost', vmid => 100 });
+
+    is_deeply($res->{allowed_nodes}, ['pve2'], 'only the node keeping the identity is allowed');
+    is_deeply(
+        $res->{not_allowed_nodes}->{pve3},
+        {
+            'guest-identity-unsupported' => {
+                version => '9.2.0',
+                'required-version' => $min_version,
+            },
+        },
+        'node with an older version is not allowed',
+    );
+    is_deeply(
+        $res->{not_allowed_nodes}->{pve4},
+        { 'guest-identity-unsupported' => { 'required-version' => $min_version } },
+        'node without version is not allowed',
+    );
+
+    my $returns = PVE::API2::Qemu->map_method_by_name('migrate_vm_precondition')->{returns};
+    # every reason of a node must be documented
+    my $strict = dclone($returns);
+    my $node_schema = $strict->{properties}->{not_allowed_nodes}->{additionalProperties};
+    $node_schema->{additionalProperties} = 0;
+    eval { PVE::JSONSchema::validate($res, $strict) };
+    is($@, '', 'result matches the schema, including the reasons of each node');
+    my $undocumented = { $res->%*, not_allowed_nodes => { pve3 => { 'other-reason' => 1 } } };
+    eval { PVE::JSONSchema::validate($undocumented, $strict) };
+    like($@, qr/other-reason/, 'an undocumented reason does not');
+
+    $cluster_module->unmock('get_nodelist');
+    mock_unreachable_config();
+};
+
+subtest 'clone target nodes' => sub {
+    my $inotify_module = Test::MockModule->new('PVE::INotify');
+    $inotify_module->mock(nodename => sub { return 'pve1'; });
+
+    $qemu_config_module->mock(
+        load_config => sub { return { memory => 512 }; },
+        has_feature => sub { return 1; },
+    );
+    $qemu_server_module->mock(
+        shared_nodes => sub {
+            return { map { $_ => 1 } 'pve1', 'pve2', 'pve3', 'pve4' };
+        },
+    );
+
+    # the version of the local node does not matter, a clone on the same node needs no check
+    $node_versions->@{ 'pve1', 'pve2', 'pve3', 'pve4' } = (undef, $min_version, '9.2.0', undef);
+
+    # the local node is the one the handler runs on, whatever name the API path used for it
+    for my $node ('pve1', 'localhost') {
+        my $res =
+            PVE::API2::Qemu->vm_feature({ node => $node, vmid => 100, feature => 'clone' });
+        is_deeply(
+            [sort $res->{nodes}->@*],
+            ['pve1', 'pve2'],
+            "node '$node': only nodes that keep the identity are offered as clone target",
+        );
+    }
+
+    # the web interface polls the snapshot feature, which needs no version lookups
+    my $lookups = 0;
+    my $node_identity_unsupported = \&PVE::GuestIdentity::node_identity_unsupported;
+    my $guest_identity_module = Test::MockModule->new('PVE::GuestIdentity');
+    $guest_identity_module->mock(
+        node_identity_unsupported => sub {
+            $lookups++;
+            return $node_identity_unsupported->(@_);
+        },
+    );
+    my $res =
+        PVE::API2::Qemu->vm_feature({ node => 'pve1', vmid => 100, feature => 'snapshot' });
+    is_deeply([sort $res->{nodes}->@*], ['pve1', 'pve2', 'pve3', 'pve4'], 'snapshot: nodes');
+    is($lookups, 0, 'snapshot: no version lookup');
+    $guest_identity_module->unmock('node_identity_unsupported');
+
+    $qemu_server_module->unmock('shared_nodes');
+    $qemu_config_module->unmock('has_feature');
+    mock_unreachable_config();
+};
+
 done_testing();
-- 
2.47.3





  parent reply	other threads:[~2026-11-18  4:40 UTC|newest]

Thread overview: 42+ messages / expand[flat|nested]  mbox.gz  Atom feed  top
2026-11-18  4:37 [PATCH cluster/guest-common/qemu-server/container/manager/docs v3 00/38] fix #7846: guest identity (uid) and cluster ID Thomas Lamprecht
2026-11-18  4:37 ` [PATCH cluster v3 01/38] pmxcfs: reject changes to the cluster ID file from user space Thomas Lamprecht
2026-11-18  4:37 ` [PATCH cluster v3 02/38] pmxcfs: generate a cluster ID on standalone nodes Thomas Lamprecht
2026-11-18  4:37 ` [PATCH cluster v3 03/38] pmxcfs: dfsm: add a callback that runs once all members are in sync Thomas Lamprecht
2026-11-18  4:37 ` [PATCH cluster v3 04/38] pmxcfs: quorum: pass the corosync membership to an optional listener Thomas Lamprecht
2026-11-18  4:37 ` [PATCH cluster v3 05/38] pmxcfs: confdb: call an optional listener when the nodes get published Thomas Lamprecht
2026-11-18  4:37 ` [PATCH cluster v3 06/38] pmxcfs: dcdb: generate the cluster ID once the cluster is in sync Thomas Lamprecht
2026-11-18  4:37 ` [PATCH cluster v3 07/38] cluster: add helper to read the cluster ID Thomas Lamprecht
2026-11-18  4:37 ` [PATCH cluster v3 08/38] pmxcfs: allow removing the cluster ID file in forced local mode Thomas Lamprecht
2026-11-18  4:37 ` [PATCH guest-common v3 09/38] guest identity: add helpers for the guest uid and registration time Thomas Lamprecht
2026-11-18  4:37 ` [PATCH guest-common v3 10/38] abstract config: assign a guest identity and keep it on config writes Thomas Lamprecht
2026-11-18  4:37 ` [PATCH guest-common v3 11/38] abstract config: let the VMID reservation return the previous state Thomas Lamprecht
2026-11-18  4:37 ` [PATCH guest-common v3 12/38] guest identity: allow taking over a uid that is unused in the cluster Thomas Lamprecht
2026-11-18  4:37 ` [PATCH guest-common v3 13/38] migrate: add shared helpers for the identity command of the migration tunnel Thomas Lamprecht
2026-11-18  4:37 ` [PATCH qemu-server v3 14/38] api: restore: release the VMID if a restore to an unused VMID fails Thomas Lamprecht
2026-11-18  4:37 ` Thomas Lamprecht [this message]
2026-11-18  4:37 ` [PATCH qemu-server v3 16/38] fix #7846: config: add a guest identity to the 'meta' property Thomas Lamprecht
2026-11-18  4:37 ` [PATCH qemu-server v3 17/38] restore: take over the guest uid from the backup where possible Thomas Lamprecht
2026-11-18  4:37 ` [PATCH qemu-server v3 18/38] api: remote migration: take over the guest uid from the source Thomas Lamprecht
2026-11-18  4:37 ` [PATCH qemu-server v3 19/38] api: status: return the guest uid Thomas Lamprecht
2026-11-18  4:37 ` [PATCH qemu-server v3 20/38] tests: remote migration: check a failed command and an early tunnel end Thomas Lamprecht
2026-11-18  4:37 ` [PATCH container v3 21/38] config: add read-only meta property with the creation time Thomas Lamprecht
2026-11-18  4:37 ` [PATCH container v3 22/38] fix #7846: config: add a guest identity to the 'meta' property Thomas Lamprecht
2026-11-18  4:37 ` [PATCH container v3 23/38] api: migrate, clone: refuse targets that would drop the guest identity Thomas Lamprecht
2026-11-18  4:37 ` [PATCH container v3 24/38] restore: take over the guest uid from the backup where possible Thomas Lamprecht
2026-11-18  4:37 ` [PATCH container v3 25/38] restore: refuse overwriting a container with another guest's backup Thomas Lamprecht
2026-11-18  4:37 ` [PATCH container v3 26/38] test: remote migration: check the cleanup of the target after failures Thomas Lamprecht
2026-11-18  4:37 ` [PATCH container v3 27/38] api: remote migration: take over the guest uid from the source Thomas Lamprecht
2026-11-18  4:37 ` [PATCH container v3 28/38] api: status: return the guest uid Thomas Lamprecht
2026-11-18  4:37 ` [PATCH manager v3 29/38] api: cluster resources: add guest uid and registration time Thomas Lamprecht
2026-11-18  4:37 ` [PATCH manager v3 30/38] api: cluster status: add cluster ID Thomas Lamprecht
2026-11-18  4:37 ` [PATCH manager v3 31/38] ui: restore: allow overwriting a guest with a backup of another guest Thomas Lamprecht
2026-11-18  4:37 ` [PATCH manager v3 32/38] ui: migrate: refuse target nodes that would drop the guest identity Thomas Lamprecht
2026-11-18  4:37 ` [PATCH manager v3 33/38] ui: guest summary: show " Thomas Lamprecht
2026-11-18  4:37 ` [PATCH manager v3 34/38] api: bulk migrate: refuse targets that would drop " Thomas Lamprecht
2026-11-18  4:37 ` [PATCH docs v3 35/38] vzdump: describe the guest identity of VMs and containers Thomas Lamprecht
2026-11-18  4:37 ` [PATCH docs v3 36/38] pvecm: document the cluster ID and how to get a new one Thomas Lamprecht
2026-11-18  4:37 ` [PATCH docs v3 37/38] qm: configuration: describe the read-only meta property Thomas Lamprecht
2026-11-18  4:37 ` [PATCH docs v3 38/38] pct: " Thomas Lamprecht
2026-11-18 13:49 ` [PATCH cluster/guest-common/qemu-server/container/manager/docs v3 00/38] fix #7846: guest identity (uid) and cluster ID Dominik Csapak
2026-11-18 14:13   ` Thomas Lamprecht
2026-11-19 10:38 ` superseded: " Thomas Lamprecht

Reply instructions:

You may reply publicly to this message via plain-text email
using any one of the following methods:

* Save the following mbox file, import it into your mail client,
  and reply-to-all from there: mbox

  Avoid top-posting and favor interleaved quoting:
  https://en.wikipedia.org/wiki/Posting_style#Interleaved_style

* Reply using the --to, --cc, and --in-reply-to
  switches of git-send-email(1):

  git send-email \
    --in-reply-to=20261118043817.1659212-16-t.lamprecht@proxmox.com \
    --to=t.lamprecht@proxmox.com \
    --cc=pve-devel@lists.proxmox.com \
    /path/to/YOUR_REPLY

  https://kernel.org/pub/software/scm/git/docs/git-send-email.html

* If your mail client supports setting the In-Reply-To header
  via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox
Service provided by Proxmox Server Solutions GmbH | Privacy | Legal