[PATCH e2e-tests 07/38] lib: pveinstance: add helper to find a task started by another task

["Michael Köppl" <m.koeppl@proxmox.com>]

Some tasks start another task for the same guest and finish before
it does (e.g. a container rollback with 'start' set runs the start in a
separate 'vzstart' task). A test that only waits for the first task then
races against the second one.

Add a helper that finds such a task through the node's task list, so
tests can wait for it and check its result.

Signed-off-by: Michael Köppl <m.koeppl@proxmox.com>
---
 Proxmox/Test/PVEInstance.pm | 30 ++++++++++++++++++++++++++++++
 1 file changed, 30 insertions(+)

diff --git a/Proxmox/Test/PVEInstance.pm b/Proxmox/Test/PVEInstance.pm
index dc40489..646ff48 100644
--- a/Proxmox/Test/PVEInstance.pm
+++ b/Proxmox/Test/PVEInstance.pm
@@ -109,6 +109,36 @@ sub destroy_volume {
     return $ok;
 }
 
+# Return the UPID of the task of $type that the task $upid started for the same guest, such as the
+# 'vzstart' task of a rollback with 'start' set. Such a task runs separately and can still be
+# running, or not have started yet, when $upid has finished. Dies if no such task shows up within
+# $timeout seconds (default 60).
+sub find_spawned_task {
+    my ($self, $upid, $type, $timeout) = @_;
+
+    my (undef, $node, undef, undef, $starttime, undef, $vmid) = split(/:/, $upid);
+    die "cannot parse UPID '$upid'\n" if !defined($vmid) || $vmid eq '';
+
+    return poll_until(
+        sub {
+            my $tasks = $self->client()->get(
+                "/nodes/$node/tasks",
+                {
+                    vmid => $vmid,
+                    typefilter => $type,
+                    since => hex($starttime),
+                    source => 'all',
+                },
+            );
+            my ($task) = grep { $_->{upid} ne $upid } $tasks->@*;
+            return $task ? $task->{upid} : undef;
+        },
+        timeout => $timeout // 60,
+        interval => 2,
+        description => "a '$type' task for guest $vmid started by $upid",
+    );
+}
+
 sub wait_for_qga {
     my ($self, $vmid, $timeout) = @_;
     return $self->wait_for_qga_on($self->get_nodename(), $vmid, $timeout);
-- 
2.47.3