SPAM: [RFC PATCH network 02/16] sdn: controllers: add ovn plugin

["Rémi PAETA" <remi.paeta@comaite.com>]

An OVN controller describes an existing OVN deployment: the connection
strings of its northbound and southbound databases and the tunnel
encapsulation used between the chassis. The OVN central components are
deployed and operated by the administrator, PVE only connects to them,
similar to how the external IPAM plugins use an existing service.

Only plain TCP connections are supported for now.

OVN does not use FRR, so OVN controllers are not taken into account
when deciding whether an FRR configuration needs to be generated.

Signed-off-by: Rémi PAETA <remi.paeta@comaite.com>
---
 src/PVE/Network/SDN.pm                       |  4 +-
 src/PVE/Network/SDN/Controllers.pm           |  2 +
 src/PVE/Network/SDN/Controllers/Makefile     |  2 +-
 src/PVE/Network/SDN/Controllers/OvnPlugin.pm | 86 ++++++++++++++++++++
 src/test/Makefile                            |  5 +-
 src/test/run_test_ovn.pl                     | 28 +++++++
 6 files changed, 124 insertions(+), 3 deletions(-)
 create mode 100644 src/PVE/Network/SDN/Controllers/OvnPlugin.pm
 create mode 100755 src/test/run_test_ovn.pl

diff --git a/src/PVE/Network/SDN.pm b/src/PVE/Network/SDN.pm
index 33a3cf3..aeb9b4c 100644
--- a/src/PVE/Network/SDN.pm
+++ b/src/PVE/Network/SDN.pm
@@ -126,13 +126,15 @@ sub running_config_has_frr {
 
     # all can be empty if the SDN configuration was never applied
     my $controllers = $running_config->{controllers}->{ids} // {};
+    # OVN controllers do not generate any FRR configuration
+    my @frr_controllers = grep { $controllers->{$_}->{type} ne 'ovn' } keys %$controllers;
     my $fabrics = $running_config->{fabrics}->{ids} // {};
     my $route_maps = $running_config->{'route-maps'}->{ids} // {};
     my $prefix_lists = $running_config->{'prefix-lists'}->{ids} // {};
 
     my $local_frr_config = PVE::Network::SDN::Frr::local_frr_config_exists();
 
-    return %$controllers || %$fabrics || %$route_maps || %$prefix_lists || $local_frr_config;
+    return @frr_controllers || %$fabrics || %$route_maps || %$prefix_lists || $local_frr_config;
 }
 
 sub pending_config {
diff --git a/src/PVE/Network/SDN/Controllers.pm b/src/PVE/Network/SDN/Controllers.pm
index b2c2f9d..ac0d70a 100644
--- a/src/PVE/Network/SDN/Controllers.pm
+++ b/src/PVE/Network/SDN/Controllers.pm
@@ -15,11 +15,13 @@ use PVE::Network::SDN::Controllers::EvpnPlugin;
 use PVE::Network::SDN::Controllers::BgpPlugin;
 use PVE::Network::SDN::Controllers::IsisPlugin;
 use PVE::Network::SDN::Controllers::FaucetPlugin;
+use PVE::Network::SDN::Controllers::OvnPlugin;
 use PVE::Network::SDN::Controllers::Plugin;
 PVE::Network::SDN::Controllers::EvpnPlugin->register();
 PVE::Network::SDN::Controllers::BgpPlugin->register();
 PVE::Network::SDN::Controllers::IsisPlugin->register();
 PVE::Network::SDN::Controllers::FaucetPlugin->register();
+PVE::Network::SDN::Controllers::OvnPlugin->register();
 PVE::Network::SDN::Controllers::Plugin->init();
 
 sub sdn_controllers_config {
diff --git a/src/PVE/Network/SDN/Controllers/Makefile b/src/PVE/Network/SDN/Controllers/Makefile
index fd9f881..a1cd14e 100644
--- a/src/PVE/Network/SDN/Controllers/Makefile
+++ b/src/PVE/Network/SDN/Controllers/Makefile
@@ -1,4 +1,4 @@
-SOURCES=Plugin.pm FaucetPlugin.pm EvpnPlugin.pm BgpPlugin.pm IsisPlugin.pm
+SOURCES=Plugin.pm FaucetPlugin.pm EvpnPlugin.pm BgpPlugin.pm IsisPlugin.pm OvnPlugin.pm
 
 
 PERL5DIR=${DESTDIR}/usr/share/perl5
diff --git a/src/PVE/Network/SDN/Controllers/OvnPlugin.pm b/src/PVE/Network/SDN/Controllers/OvnPlugin.pm
new file mode 100644
index 0000000..f7a9b96
--- /dev/null
+++ b/src/PVE/Network/SDN/Controllers/OvnPlugin.pm
@@ -0,0 +1,86 @@
+package PVE::Network::SDN::Controllers::OvnPlugin;
+
+use v5.36;
+
+use PVE::JSONSchema;
+use PVE::Tools;
+
+use PVE::Network::SDN::Controllers::Plugin;
+
+use base('PVE::Network::SDN::Controllers::Plugin');
+
+PVE::JSONSchema::register_format('pve-sdn-ovn-remotes', \&pve_verify_sdn_ovn_remotes);
+
+sub pve_verify_sdn_ovn_remotes {
+    my ($remotes, $noerr) = @_;
+
+    for my $remote (split(/,/, $remotes)) {
+        next if $remote =~ m/^tcp:$PVE::Tools::IPV4RE:\d+$/;
+        next if $remote =~ m/^tcp:\[$PVE::Tools::IPV6RE\]:\d+$/;
+
+        return undef if $noerr;
+        die "invalid OVN database connection '$remote', expected tcp:<ip>:<port>\n";
+    }
+
+    return $remotes;
+}
+
+sub type {
+    return 'ovn';
+}
+
+sub properties {
+    return {
+        'nb-connection' => {
+            description => "Comma separated list of the OVN northbound database servers,"
+                . " for example tcp:10.0.0.1:6641,tcp:10.0.0.2:6641.",
+            type => 'string',
+            format => 'pve-sdn-ovn-remotes',
+        },
+        'sb-connection' => {
+            description => "Comma separated list of the OVN southbound database servers,"
+                . " for example tcp:10.0.0.1:6642,tcp:10.0.0.2:6642.",
+            type => 'string',
+            format => 'pve-sdn-ovn-remotes',
+        },
+        'encap-type' => {
+            description => "Tunnel encapsulation used between the chassis.",
+            type => 'string',
+            enum => ['geneve', 'vxlan'],
+            default => 'geneve',
+        },
+    };
+}
+
+sub options {
+    return {
+        'nb-connection' => { optional => 0 },
+        'sb-connection' => { optional => 0 },
+        'encap-type' => { optional => 1 },
+    };
+}
+
+# OVN does not use FRR
+sub generate_frr_config {
+    my ($class, $plugin_config, $controller_cfg, $id, $uplinks, $config) = @_;
+
+    return;
+}
+
+sub generate_zone_frr_config {
+    my ($class, $plugin_config, $controller, $controller_cfg, $id, $uplinks, $config) = @_;
+
+    return;
+}
+
+sub on_delete_hook {
+    my ($class, $controllerid, $zone_cfg) = @_;
+
+    for my $id (sort keys %{ $zone_cfg->{ids} }) {
+        my $zone = $zone_cfg->{ids}->{$id};
+        die "controller $controllerid is used by $id\n"
+            if defined($zone->{controller}) && $zone->{controller} eq $controllerid;
+    }
+}
+
+1;
diff --git a/src/test/Makefile b/src/test/Makefile
index 5a937a4..b3c5d69 100644
--- a/src/test/Makefile
+++ b/src/test/Makefile
@@ -1,6 +1,6 @@
 all: test
 
-test: test_zones test_ipams test_dns test_subnets test_vnets_blackbox
+test: test_zones test_ipams test_dns test_subnets test_vnets_blackbox test_ovn
 
 test_zones: run_test_zones.pl
 	./run_test_zones.pl
@@ -17,4 +17,7 @@ test_subnets: run_test_subnets.pl
 test_vnets_blackbox: run_test_vnets_blackbox.pl
 	./run_test_vnets_blackbox.pl
 
+test_ovn: run_test_ovn.pl
+	./run_test_ovn.pl
+
 clean:
diff --git a/src/test/run_test_ovn.pl b/src/test/run_test_ovn.pl
new file mode 100755
index 0000000..60e752b
--- /dev/null
+++ b/src/test/run_test_ovn.pl
@@ -0,0 +1,28 @@
+#!/usr/bin/perl
+
+use strict;
+use warnings;
+
+use lib qw(..);
+
+use Test::More;
+
+use PVE::Network::SDN;
+use PVE::Network::SDN::Controllers::OvnPlugin;
+
+# controller schema
+
+ok(
+    PVE::Network::SDN::Controllers::OvnPlugin::pve_verify_sdn_ovn_remotes(
+        'tcp:10.0.0.1:6641,tcp:[fd00::1]:6641', 1,
+    ),
+    'remotes format: valid',
+);
+for my $invalid ('ssl:10.0.0.1:6641', 'tcp:10.0.0.1', 'tcp:ovn.example.com:6641') {
+    ok(
+        !PVE::Network::SDN::Controllers::OvnPlugin::pve_verify_sdn_ovn_remotes($invalid, 1),
+        "remotes format: invalid '$invalid'",
+    );
+}
+
+done_testing();
-- 
2.47.3