[PATCH manager 09/21] api: node: add endpoints for listing backups for a node

[Shannon Sterz <s.sterz@proxmox.com>]

GET /nodes/{node}/host-backup now lists backups of a host

Signed-off-by: Shannon Sterz <s.sterz@proxmox.com>
---
 PVE/API2/HostBackup.pm | 140 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 140 insertions(+)

diff --git a/PVE/API2/HostBackup.pm b/PVE/API2/HostBackup.pm
index 9a0b0dc1d..fe1263a85 100644
--- a/PVE/API2/HostBackup.pm
+++ b/PVE/API2/HostBackup.pm
@@ -18,6 +18,7 @@ use PVE::PBSClient;
 use PVE::Storage::PBSPlugin;
 use PVE::Storage;
 use PVE::Systemd;
+use PVE::Tools qw(extract_param);
 use PVE::VZDump;
 use PVE::pvecfg;
 
@@ -316,6 +317,145 @@ sub complete_proxmox_backup_storage(@) {
     return $res;
 }
 
+__PACKAGE__->register_method({
+    name => 'index',
+    path => '',
+    method => 'GET',
+    proxyto => 'node',
+    protected => 1,
+    description => "List backups for specified node.",
+    permissions => {
+        check => [
+            'and',
+            ['perm', '/', ['Sys.Audit']],
+            [
+                'perm',
+                '/storage/{storage}',
+                ['Datastore.Audit', 'Datastore.AllocateSpace'],
+                any => 1,
+            ],
+        ],
+
+    },
+    parameters => {
+        additionalProperties => 0,
+        properties => {
+            node => get_standard_option('pve-node'),
+            storage => get_standard_option(
+                'pve-storage-id',
+                {
+                    description =>
+                        "The Proxmox Backup Server storage to scan for host backups.",
+                    completion => \&complete_proxmox_backup_storage,
+                    optional => 0,
+                },
+            ),
+        },
+    },
+    returns => {
+        type => 'array',
+        items => {
+            type => 'object',
+            properties => {
+                volid => {
+                    description => "Volume identifier.",
+                    type => 'string',
+                },
+                'format' => {
+                    description => "Always 'pbs-host'.",
+                    type => 'string',
+                },
+                size => {
+                    description =>
+                        "Volume size in bytes. 0 if the size couldn't be determined.",
+                    type => 'integer',
+                    renderer => 'bytes',
+                },
+                ctime => {
+                    description => "Creation time (seconds since the UNIX Epoch).",
+                    type => 'integer',
+                    minimum => 0,
+                    optional => 1,
+                },
+                notes => {
+                    description =>
+                        "Optional notes. If they are multiple lines long, only the first line will "
+                        . "be returned.",
+                    type => 'string',
+                    optional => 1,
+                },
+                encrypted => {
+                    description => "Fingerprint of the encrypted backup if it is encrypted.",
+                    type => 'string',
+                    optional => 1,
+                },
+                verification => {
+                    description => "Last backup verification result.",
+                    type => 'object',
+                    properties => {
+                        state => {
+                            description => "Last backup verification state.",
+                            type => 'string',
+                        },
+                        upid => {
+                            description => "Last backup verification UPID.",
+                            type => 'string',
+                        },
+                    },
+                    optional => 1,
+                },
+                protected => {
+                    description => "Protection status.",
+                    type => 'boolean',
+                    optional => 1,
+                },
+            },
+        },
+        links => [{ rel => 'child', href => "{backup-time}" }],
+    },
+    code => sub($param) {
+        my $storeid = extract_param($param, 'storage');
+        my $cfg = PVE::Storage::config();
+        my $scfg = PVE::Storage::storage_check_enabled($cfg, $storeid, undef, 1);
+
+        croak "storage is not enabled or not available on this host\n" if !defined($scfg);
+        croak "currently only proxmox backup server is supported for host backups\n"
+            if $scfg->{type} ne PVE::Storage::PBSPlugin::type();
+
+        my $pbs = PVE::PBSClient->new($scfg, $storeid);
+
+        my $nodename = extract_param($param, 'node');
+        my $snapshots = $pbs->get_snapshots("host/$nodename");
+
+        my $res = [];
+
+        foreach my $item (@$snapshots) {
+            my ($type, $id, $time) = $item->@{qw(backup-type backup-id backup-time)};
+            next if $type ne 'host';
+
+            my @pxar = grep { $_->{filename} eq 'pve-backup.pxar.didx' } @{ $item->{files} };
+            next if (scalar(@pxar) != 1);
+
+            my $info = {
+                volid => PVE::Storage::PBSPlugin::print_volid($storeid, $type, $id, $time),
+                format => "pbs-$type",
+                size => int($item->{size}),
+                content => 'backup',
+                ctime => $time,
+                subtype => 'host',
+            };
+
+            $info->{verification} = $item->{verification} if defined($item->{verification});
+            $info->{notes} = $item->{comment} if defined($item->{comment});
+            $info->{protected} = 1 if $item->{protected};
+
+            push @$res, $info;
+        }
+
+        return $res;
+    },
+});
+
 __PACKAGE__->register_method({
     name => 'create_backup',
     path => '',
-- 
2.47.3