[pve-devel] [PATCH pve-gui-tests v3 1/1] pve: add sdn/fabrics screenshots

[Stefan Hanreich <s.hanreich@proxmox.com>]

From: Gabriel Goller <g.goller@proxmox.com>

Add a few screenshots for the sdn->fabrics panel:
 * fabric overview
 * openfabric fabric creation
 * ospf fabric creation
 * openfabric node creation
 * ospf node creation

Signed-off-by: Gabriel Goller <g.goller@proxmox.com>
---
 create_fabrics_screenshots | 198 +++++++++++++++++++++++++++++++++++++
 1 file changed, 198 insertions(+)
 create mode 100755 create_fabrics_screenshots

diff --git a/create_fabrics_screenshots b/create_fabrics_screenshots
new file mode 100755
index 0000000..a83bb22
--- /dev/null
+++ b/create_fabrics_screenshots
@@ -0,0 +1,198 @@
+#!/usr/bin/perl
+
+use strict;
+use warnings;
+use lib '.';
+
+use Carp;
+use Time::HiRes qw(usleep);
+use Data::Dumper;
+use PVE::GUITester;
+use Proxmox::GUITester;
+
+sub prepare_fabrics {
+    my ($conn) = @_;
+    eval {
+        # might not exist, so ignore any errors
+        $conn->delete("/cluster/sdn/fabrics/fabric/test2");
+        $conn->delete("/cluster/sdn/fabrics/fabric/test1");
+    };
+
+    my $openfabric = {
+        id => "test1",
+        ip_prefix => "192.0.2.0/24",
+        hello_interval => "1",
+        protocol => "openfabric",
+    };
+    my $ospf = {
+        id => "test2",
+        area => "0.0.0.0",
+        ip_prefix => "198.51.100.0/24",
+        protocol => "ospf",
+    };
+    $conn->post("/cluster/sdn/fabrics/fabric", $openfabric);
+    $conn->post("/cluster/sdn/fabrics/fabric", $ospf);
+}
+
+sub prepare_nodes {
+    my ($conn) = @_;
+    eval {
+        # might not exist, so ignore any errors
+        $conn->delete("/cluster/sdn/fabrics/node/test2/pve0");
+        $conn->delete("/cluster/sdn/fabrics/node/test2/pve1");
+        $conn->delete("/cluster/sdn/fabrics/node/test2/pve2");
+        $conn->delete("/cluster/sdn/fabrics/node/test1/pve0");
+        $conn->delete("/cluster/sdn/fabrics/node/test1/pve1");
+        $conn->delete("/cluster/sdn/fabrics/node/test1/pve2");
+    };
+
+    my @nodes = ('pve0', 'pve1', 'pve2');
+    
+    for my $i (0 .. $#nodes) {
+        my $node_name = $nodes[$i];
+        my $last_octet = $i + 1;
+        my $ospf_iface = ($i * 2) + 19;
+        my $openfabric_iface = ($i * 2) + 25;
+        
+        my $ospf_node = {
+            node_id => $node_name,
+            ip => "198.51.100.$last_octet",
+            interfaces => [
+                "name=ens$ospf_iface",
+                "name=ens" . ($ospf_iface + 1 . "")
+            ],
+            protocol => "ospf",
+        };
+        my $openfabric_node = {
+            node_id => $node_name,
+            ip => "192.0.2.$last_octet",
+            interfaces => [
+                "name=ens$openfabric_iface",
+                "name=ens" . ($openfabric_iface + 1)
+            ],
+            protocol => "openfabric",
+        };
+        
+        $conn->post("/cluster/sdn/fabrics/node/test1/", $openfabric_node);
+        $conn->post("/cluster/sdn/fabrics/node/test2/", $ospf_node);
+    }
+}
+
+sub open_add_node_panel {
+    my ($self, $protocol) = @_;
+
+    my $driver = $self->{driver};
+
+    my $js = "let panel = Ext.ComponentQuery.query('pveSDNFabricView')[0];" .
+        "panel.controller.openNodeAddWindow({children: [], protocol: '$protocol'});" .
+        "return true";
+
+    my $res;
+
+    $res = Proxmox::GUITester::verify_scalar_result($driver->execute_script($js));
+    croak "unable to open node panel for '$protocol'\n" if !$res;
+}
+
+sub select_interfaces {
+    my ($self, $iface1, $iface2) = @_;
+
+    my $driver = $self->{driver};
+
+    my $js = "let panel = Ext.ComponentQuery.query('pveSDNFabricsInterfacePanel')[0];" .
+        "let store = panel.getStore();" .
+        "let record1 = store.findRecord('name', '$iface1');" .
+        "let record2 = store.findRecord('name', '$iface2');" .
+        "panel.setSelection([record1, record2]);" .
+        "return true";
+
+    my $res;
+
+    $res = Proxmox::GUITester::verify_scalar_result($driver->execute_script($js));
+    croak "unable to select interface '$iface1' or '$iface2'\n" if !$res;
+}
+
+sub create_fabrics_ui_screenshots {
+    my ($gui, $conn) = @_;
+
+    $gui->select_tree_item("root", 10);
+
+    my $panel = $gui->component_query_single('pvePanelConfig');
+    $gui->select_config_item($panel, 'sdnfabrics');
+
+    # get fabric edit window
+    my $menu = $gui->find_button('Add Fabric', $panel)->click();
+    $gui->find_menu_item('OpenFabric')->click();
+
+    my $window = $gui->find_dialog("Create: OpenFabric");
+    $gui->setValue($window, 'id', 'test1');
+    $gui->setValue($window, 'ip_prefix', '192.0.2.0/24');
+    $gui->setValue($window, 'hello_interval', '1');
+
+    $gui->element_screenshot("gui-datacenter-create-fabric-openfabric.png", $window);
+    $gui->window_close($window);
+
+    $menu = $gui->find_button('Add Fabric', $panel)->click();
+    $gui->find_menu_item('OSPF')->click();
+
+    $window = $gui->find_dialog("Create: OSPF");
+    $gui->setValue($window, 'id', 'test2');
+    $gui->setValue($window, 'area', '0');
+    $gui->setValue($window, 'ip_prefix', '198.51.100.0/24');
+
+    $gui->element_screenshot("gui-datacenter-create-fabric-ospf.png", $window);
+    $gui->window_close($window);
+
+    # get node edit window
+    prepare_fabrics($conn);
+    sleep_ms(250);
+
+    open_add_node_panel($gui, "openfabric");
+    sleep_ms(500);
+    
+    $window = $gui->find_dialog("Create: Node");
+    $gui->setValue($window, 'ip', '192.0.2.1');
+    select_interfaces($gui, "ens19", "ens20");
+    $gui->element_screenshot("gui-datacenter-create-node-openfabric.png", $window);
+    $gui->window_close($window);
+
+    open_add_node_panel($gui, "ospf");
+    sleep_ms(500);
+
+    $window = $gui->find_dialog("Create: Node");
+    $gui->setValue($window, 'ip', '198.51.100.1');
+    select_interfaces($gui, "ens19", "ens20");
+    $gui->element_screenshot("gui-datacenter-create-node-ospf.png", $window);
+    $gui->window_close($window);
+
+    # get fabric overview
+    prepare_nodes($conn);
+    sleep_ms(250);
+    $gui->reload();
+
+    $gui->select_tree_item("root", 10);
+
+    $panel = $gui->component_query_single('pvePanelConfig');
+    $gui->select_config_item($panel, 'sdnfabrics');
+    $gui->element_screenshot("gui-datacenter-fabrics-overview.png", $panel);
+}
+
+my $gui;
+
+eval {
+
+    local $SIG{TERM} = $SIG{QUIT} = $SIG{INT} = sub { die "got interrupt"; };
+
+    $gui = PVE::GUITester->new(login => 1);
+
+    my $conn = $gui->apiclient();
+
+    create_fabrics_ui_screenshots($gui, $conn);
+};
+my $err = $@;
+
+$gui->quit() if $gui;
+
+die $err if $err;
+
+exit(0);
+
-- 
2.39.5


_______________________________________________
pve-devel mailing list
pve-devel@lists.proxmox.com
https://lists.proxmox.com/cgi-bin/mailman/listinfo/pve-devel