[pve-devel] [PATCH container v6 29/37] add LXC::Namespaces module

[Fiona Ebner <f.ebner@proxmox.com>]

The module includes a run_in_userns() helper to run a Perl subroutine
in a user namespace.

The first use case is running the container backup subroutine for
external providers inside a user namespace. That allows them to see
the filesystem to back-up from the containers perspective and also
improves security because of isolation.

Heavily adapted from code by Wolfgang from the pve-buildpkg
repository.

Originally-by: Wolfgang Bumiller <w.bumiller@proxmox.com>
[FE: add $idmap parameter, drop $aux_groups parameter
     use different fork helper
     use newuidmap and newgidmap binaries]
Signed-off-by: Fiona Ebner <f.ebner@proxmox.com>
---

Changes in v6:
* import constants from PVE::Tools instead of redefining.

 src/PVE/LXC/Makefile      |  1 +
 src/PVE/LXC/Namespaces.pm | 57 +++++++++++++++++++++++++++++++++++++++
 2 files changed, 58 insertions(+)
 create mode 100644 src/PVE/LXC/Namespaces.pm

diff --git a/src/PVE/LXC/Makefile b/src/PVE/LXC/Makefile
index a190260..4b05e98 100644
--- a/src/PVE/LXC/Makefile
+++ b/src/PVE/LXC/Makefile
@@ -5,6 +5,7 @@ SOURCES= \
 	Create.pm \
 	Migrate.pm \
 	Monitor.pm \
+	Namespaces.pm \
 	Setup.pm \
 	Tools.pm
 
diff --git a/src/PVE/LXC/Namespaces.pm b/src/PVE/LXC/Namespaces.pm
new file mode 100644
index 0000000..bd39c07
--- /dev/null
+++ b/src/PVE/LXC/Namespaces.pm
@@ -0,0 +1,57 @@
+package PVE::LXC::Namespaces;
+
+use strict;
+use warnings;
+
+use Fcntl qw(O_WRONLY);
+use Socket;
+
+use PVE::Tools qw(CLONE_NEWNS CLONE_NEWUSER);
+
+my sub set_id_map($$) {
+    my ($pid, $id_map) = @_;
+
+    my @gid_args = ();
+    my @uid_args = ();
+
+    for my $map ($id_map->@*) {
+	my ($type, $ct, $host, $length) = $map->@*;
+
+	push @gid_args, $ct, $host, $length if $type eq 'g';
+	push @uid_args, $ct, $host, $length if $type eq 'u';
+    }
+
+    PVE::Tools::run_command(['newgidmap', $pid, @gid_args]) if scalar(@gid_args);
+    PVE::Tools::run_command(['newuidmap', $pid, @uid_args]) if scalar(@uid_args);
+}
+
+sub run_in_userns(&;$) {
+    my ($code, $id_map) = @_;
+    socketpair(my $sp, my $sc, AF_UNIX, SOCK_STREAM, PF_UNSPEC)
+	or die "socketpair: $!\n";
+    my $child = sub {
+	close($sp);
+	PVE::Tools::unshare(CLONE_NEWUSER|CLONE_NEWNS) or die "unshare(NEWUSER|NEWNS): $!\n";
+	syswrite($sc, "1\n") == 2 or die "write: $!\n";
+	shutdown($sc, 1);
+	my $two = <$sc>;
+	die "failed to sync with parent process\n" if $two ne "2\n";
+	close($sc);
+	$! = undef;
+	($(, $)) = (0, 0); die "$!\n" if $!;
+	($<, $>) = (0, 0); die "$!\n" if $!;
+	return $code->();
+    };
+    my $parent = sub {
+	my ($pid) = @_;
+	close($sc);
+	my $one = <$sp>;
+	die "failed to sync with userprocess\n" if $one ne "1\n";
+	set_id_map($pid, $id_map);
+	syswrite($sp, "2\n") == 2 or die "write: $!\n";
+	close($sp);
+    };
+    PVE::Tools::run_fork($child, { afterfork => $parent });
+}
+
+1;
-- 
2.39.5



_______________________________________________
pve-devel mailing list
pve-devel@lists.proxmox.com
https://lists.proxmox.com/cgi-bin/mailman/listinfo/pve-devel