[pve-devel] [RFC qemu-server 2/9] cfg2cmd: improve error message for invalid volume storage content type

[Daniel Kral <d.kral@proxmox.com>]

Improve the error message when a VM start fails due to a volume storage
not supporting the volume's required content type by prefixing it with
the disk handle (e.g. scsi0).

This moves and splits the subroutine for checking the volume storage's
content type to increase its reusability.

Signed-off-by: Daniel Kral <d.kral@proxmox.com>
---
This introduces the check_storage_content_type and
check_volume_content_type subroutines, which are later used throughout
the refactoring of the other locations with similar checks.

 PVE/QemuServer.pm                             | 16 +------
 PVE/QemuServer/Helpers.pm                     | 45 +++++++++++++++++++
 .../unsupported-storage-content-type.conf     |  2 +-
 3 files changed, 48 insertions(+), 15 deletions(-)

diff --git a/PVE/QemuServer.pm b/PVE/QemuServer.pm
index b26da505..e24c741c 100644
--- a/PVE/QemuServer.pm
+++ b/PVE/QemuServer.pm
@@ -3961,7 +3961,8 @@ sub config_to_command {
 	my ($ds, $drive) = @_;
 
 	if (PVE::Storage::parse_volume_id($drive->{file}, 1)) {
-	    check_volume_storage_type($storecfg, $drive->{file});
+	    eval { PVE::QemuServer::Helpers::check_volume_content_type($storecfg, $drive->{file}) };
+	    die "$ds: $@" if $@;
 	    push @$vollist, $drive->{file};
 	}
 
@@ -8794,19 +8795,6 @@ sub vm_is_paused {
     );
 }
 
-sub check_volume_storage_type {
-    my ($storecfg, $vol) = @_;
-
-    my ($storeid, $volname) = PVE::Storage::parse_volume_id($vol);
-    my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
-    my ($vtype) = PVE::Storage::parse_volname($storecfg, $vol);
-
-    die "storage '$storeid' does not support content-type '$vtype'\n"
-	if !$scfg->{content}->{$vtype};
-
-    return 1;
-}
-
 sub add_nets_bridge_fdb {
     my ($conf, $vmid) = @_;
 
diff --git a/PVE/QemuServer/Helpers.pm b/PVE/QemuServer/Helpers.pm
index 0afb6317..9d0f24aa 100644
--- a/PVE/QemuServer/Helpers.pm
+++ b/PVE/QemuServer/Helpers.pm
@@ -106,6 +106,51 @@ sub vm_running_locally {
     return;
 }
 
+=head3 check_storage_content_type($storecfg, $storeid [, $content_type])
+
+Checks whether the storage with the identifier C<$storeid>, that is defined in C<$storecfg>,
+supports the content type C<$content_type>. If the C<$content_type> is undefined, it will default
+to the value C<"images">.
+
+If the check fails, the subroutine will C<die> with an error message containing the storage and
+content type that is not supported.
+
+Returns C<1> if the check is successful.
+
+=cut
+
+sub check_storage_content_type : prototype($$;$) {
+    my ($storecfg, $storeid, $content_type) = @_;
+
+    $content_type = "images" if !defined($content_type);
+    my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
+    die "storage '$storeid' does not support content type '$content_type'\n"
+	if !$scfg->{content}->{$content_type};
+
+    return 1;
+}
+
+=head3 check_volume_content_type($storecfg, $volid)
+
+Checks whether the volume with the identifier C<$volid>, that is defined in C<$storecfg>, supports
+the content type, which is determined by L<PVE::Storage::parse_volname>.
+
+If the check fails, the subroutine will C<die> with an error message containing the storage and
+content type that is not supported.
+
+Returns C<1> if the check is successful.
+
+=cut
+
+sub check_volume_content_type : prototype($$) {
+    my ($storecfg, $volid) = @_;
+
+    my ($storeid) = PVE::Storage::parse_volume_id($volid);
+    my ($vtype) = PVE::Storage::parse_volname($storecfg, $volid);
+
+    return check_storage_content_type($storecfg, $storeid, $vtype);
+}
+
 sub min_version {
     my ($verstr, $major, $minor, $pve) = @_;
 
diff --git a/test/cfg2cmd/unsupported-storage-content-type.conf b/test/cfg2cmd/unsupported-storage-content-type.conf
index 35e789b2..7e7952aa 100644
--- a/test/cfg2cmd/unsupported-storage-content-type.conf
+++ b/test/cfg2cmd/unsupported-storage-content-type.conf
@@ -1,3 +1,3 @@
 # TEST: Unsupported storage content type in a volume disk
-# EXPECT_ERROR: storage 'no-images' does not support content-type 'images'
+# EXPECT_ERROR: scsi0: storage 'no-images' does not support content type 'images'
 scsi0: no-images:8006/vm-8006-disk-0.raw,iothread=1,size=32G
-- 
2.39.5



_______________________________________________
pve-devel mailing list
pve-devel@lists.proxmox.com
https://lists.proxmox.com/cgi-bin/mailman/listinfo/pve-devel