From: Christoph Heiss <c.heiss@proxmox.com>
To: pve-devel@lists.proxmox.com
Subject: [pve-devel] [PATCH installer 1/3] low-level: add zfs module for retrieving importable zpool info
Date: Thu, 16 May 2024 12:28:33 +0200 [thread overview]
Message-ID: <20240516102837.422278-2-c.heiss@proxmox.com> (raw)
In-Reply-To: <20240516102837.422278-1-c.heiss@proxmox.com>
Signed-off-by: Christoph Heiss <c.heiss@proxmox.com>
---
Proxmox/Makefile | 1 +
Proxmox/Sys/ZFS.pm | 43 ++++++++++++++++++++++++++++++++++
test/Makefile | 6 +++++
test/zfs-get-pool-list.pl | 49 +++++++++++++++++++++++++++++++++++++++
4 files changed, 99 insertions(+)
create mode 100644 Proxmox/Sys/ZFS.pm
create mode 100755 test/zfs-get-pool-list.pl
diff --git a/Proxmox/Makefile b/Proxmox/Makefile
index 9561d9b..035626b 100644
--- a/Proxmox/Makefile
+++ b/Proxmox/Makefile
@@ -17,6 +17,7 @@ PERL_MODULES=\
Sys/File.pm \
Sys/Net.pm \
Sys/Udev.pm \
+ Sys/ZFS.pm \
UI.pm \
UI/Base.pm \
UI/Gtk3.pm \
diff --git a/Proxmox/Sys/ZFS.pm b/Proxmox/Sys/ZFS.pm
new file mode 100644
index 0000000..4c732ca
--- /dev/null
+++ b/Proxmox/Sys/ZFS.pm
@@ -0,0 +1,43 @@
+package Proxmox::Sys::ZFS;
+
+use strict;
+use warnings;
+
+use Proxmox::Sys::Command qw(run_command);
+
+use base qw(Exporter);
+our @EXPORT_OK = qw(get_exported_pools);
+
+my sub parse_pool_list {
+ my ($fh) = @_;
+
+ my @pools;
+ my $pool = {}; # last found pool in output
+
+ while (my $line = <$fh>) {
+ if ($line =~ /^\s+pool: (.+)$/) {
+ push @pools, $pool if %$pool;
+ $pool = { name => $1 };
+ next;
+ }
+
+ next if !%$pool;
+
+ if ($line =~ /^\s*(id|state|status|action): (.+)$/) {
+ chomp($pool->{$1} = $2);
+ next;
+ }
+ }
+
+ push @pools, $pool if %$pool;
+ return \@pools;
+}
+
+sub get_exported_pools {
+ my $raw = run_command(['zpool', 'import']);
+ open (my $fh, '<', \$raw) or die 'failed to open in-memory stream';
+
+ return parse_pool_list($fh);
+}
+
+1;
diff --git a/test/Makefile b/test/Makefile
index 99bf14e..2d9decc 100644
--- a/test/Makefile
+++ b/test/Makefile
@@ -2,6 +2,7 @@ all:
export PERLLIB=..
+# test-zfs-get-pool-list is not run by default, due to requiring root access
.PHONY: check
check: test-zfs-arc-max test-run-command test-parse-fqdn test-ui2-stdio
@@ -9,6 +10,7 @@ check: test-zfs-arc-max test-run-command test-parse-fqdn test-ui2-stdio
test-zfs-arc-max:
./zfs-arc-max.pl
+.PHONY: test-run-command
test-run-command:
./run-command.pl
@@ -19,3 +21,7 @@ test-parse-fqdn:
.PHONY: test-ui2-stdio
test-ui2-stdio:
./ui2-stdio.pl
+
+.PHONY: test-zfs-get-pool-list
+test-zfs-get-pool-list:
+ ./zfs-get-pool-list.pl
diff --git a/test/zfs-get-pool-list.pl b/test/zfs-get-pool-list.pl
new file mode 100755
index 0000000..072da2f
--- /dev/null
+++ b/test/zfs-get-pool-list.pl
@@ -0,0 +1,49 @@
+#!/usr/bin/perl
+
+use strict;
+use warnings;
+
+use File::Temp;
+use Test::More tests => 6;
+
+use Proxmox::Sys::Command qw(syscmd run_command);
+use Proxmox::Sys::ZFS;
+use Proxmox::UI;
+
+my $log_file = File::Temp->new();
+Proxmox::Log::init($log_file->filename);
+
+Proxmox::UI::init_stdio();
+
+our $POOL_PREFIX = 'pve-installer';
+my $pools = { 'test-pool1' => {}, 'test-pool2' => {} };
+
+foreach (keys %$pools) {
+ my $f = File::Temp->new();
+ print "$_: $f\n";
+
+ syscmd("truncate -s 1G $f");
+ my $dev = run_command("losetup --find --show $f");
+
+ syscmd("zpool create $POOL_PREFIX-$_ $dev");
+ syscmd("zpool export $POOL_PREFIX-$_");
+
+ $pools->{$_} = {
+ file => $f,
+ dev => $dev,
+ };
+}
+
+my $exported = Proxmox::Sys::ZFS::get_exported_pools();
+while (my ($name, $info) = each %$pools) {
+ my ($p) = grep { $_->{name} eq "$POOL_PREFIX-$name" } @$exported;
+ ok(defined($p), "pool $name was found");
+ is($p->{state}, 'ONLINE', "pool $name is online");
+ is($p->{action}, 'The pool can be imported using its name or numeric identifier.',
+ "pool $name can be imported");
+}
+
+keys %$pools;
+while (my ($name, $info) = each %$pools) {
+ syscmd("losetup --detach $info->{dev}");
+}
--
2.44.0
_______________________________________________
pve-devel mailing list
pve-devel@lists.proxmox.com
https://lists.proxmox.com/cgi-bin/mailman/listinfo/pve-devel
next prev parent reply other threads:[~2024-05-16 10:29 UTC|newest]
Thread overview: 10+ messages / expand[flat|nested] mbox.gz Atom feed top
2024-05-16 10:28 [pve-devel] [PATCH installer 0/3] add check/rename for already-existing ZFS rpool Christoph Heiss
2024-05-16 10:28 ` Christoph Heiss [this message]
2024-07-08 14:24 ` [pve-devel] [PATCH installer 1/3] low-level: add zfs module for retrieving importable zpool info Aaron Lauterer
2024-07-08 15:13 ` Christoph Heiss
2024-05-16 10:28 ` [pve-devel] [PATCH installer 2/3] low-level: install: split out random disk uid generation Christoph Heiss
2024-05-16 10:28 ` [pve-devel] [PATCH installer 3/3] low-level: install: check for already-existing `rpool` on install Christoph Heiss
2024-07-08 14:16 ` Aaron Lauterer
2024-07-08 15:16 ` Christoph Heiss
2024-07-08 11:27 ` [pve-devel] [PATCH installer 0/3] add check/rename for already-existing ZFS rpool Christoph Heiss
2024-07-11 12:00 ` Christoph Heiss
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=20240516102837.422278-2-c.heiss@proxmox.com \
--to=c.heiss@proxmox.com \
--cc=pve-devel@lists.proxmox.com \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox