From: Aaron Lauterer <a.lauterer@proxmox.com>
To: pve-devel@pve.proxmox.com
Subject: [pve-devel] [PATCH v4 manager 1/5] api: backup: add endpoint to list included guests and volumes
Date: Tue, 7 Jul 2020 11:48:58 +0200 [thread overview]
Message-ID: <20200707094902.24712-2-a.lauterer@proxmox.com> (raw)
In-Reply-To: <20200707094902.24712-1-a.lauterer@proxmox.com>
This patch adds a new API endpoint that returns a list of included
guests, their volumes and whether they are included in a backup.
The output is formatted to be used with the extJS tree panel.
Signed-off-by: Aaron Lauterer <a.lauterer@proxmox.com>
---
The return types are `qemu`, `lxc` and `unknown`. The latter is there on
purpose because it is possible that a deleted but not purged VM is still
configured on a backup job. While the backup job itself will fail, I
think it is good to show it in the job detail view so users can react to
it.
v3 -> v4:
* remove the "not all permissions" field as we never show such
notifications anywhere else. This makes the returned data simpler
* define objects to be pushed in the return data directly in the push
operation and not way ahead in the code.
v2 -> v3 (hopefully I got them all):
* incorporate feedback from thomas
* changed double negative for permissions `not_all_permissions` to
`permissions_for_all`
* adapted to latest changes to return values from `get_included_guests`
* define $guest only once
* return VMID as int
* renamed some vars to be more descriptive
v1 -> v2:
* simplified the code
* refactored according to feedback
PVE/API2/Backup.pm | 174 +++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 174 insertions(+)
diff --git a/PVE/API2/Backup.pm b/PVE/API2/Backup.pm
index 86377c0a..6fbe2106 100644
--- a/PVE/API2/<F2>Backup.pm
+++ b/PVE/API2/Backup.pm
@@ -324,4 +324,178 @@ __PACKAGE__->register_method({
die "$@" if ($@);
}});
+__PACKAGE__->register_method({
+ name => 'get_volume_backup_included',
+ path => '{id}/included_volumes',
+ method => 'GET',
+ protected => 1,
+ description => "Returns included guests and the backup status of their disks. Optimized to be used in ExtJS tree views.",
+ permissions => {
+ check => ['perm', '/', ['Sys.Audit']],
+ },
+ parameters => {
+ additionalProperties => 0,
+ properties => {
+ id => $vzdump_job_id_prop
+ },
+ },
+ returns => {
+ type => 'object',
+ description => 'Root node of the tree object. Children represent guests, grandchildren represent volumes of that guest.',
+ properties => {
+ children => {
+ type => 'array',
+ items => {
+ type => 'object',
+ properties => {
+ id => {
+ type => 'integer',
+ description => 'VMID of the guest.',
+ },
+ name => {
+ type => 'string',
+ description => 'Name of the guest',
+ optional => 1,
+ },
+ type => {
+ type => 'string',
+ description => 'Type of the guest, VM, CT or unknown for removed but not purged guests.',
+ enum => ['qemu', 'lxc', 'unknown'],
+ },
+ children => {
+ type => 'array',
+ optional => 1,
+ description => 'The volumes of the guest with the information if they will be included in backups.',
+ items => {
+ type => 'object',
+ properties => {
+ id => {
+ type => 'string',
+ description => 'Configuration key of the volume.',
+ },
+ name => {
+ type => 'string',
+ description => 'Name of the volume.',
+ },
+ included => {
+ type => 'boolean',
+ description => 'Whether the volume is included in the backup or not.',
+ },
+ reason => {
+ type => 'string',
+ description => 'The reason why the volume is included (or excluded).',
+ },
+ },
+ },
+ },
+ },
+ },
+ },
+ },
+ },
+ code => sub {
+ my ($param) = @_;
+
+ my $rpcenv = PVE::RPCEnvironment::get();
+
+ my $user = $rpcenv->get_user();
+
+ my $vzconf = cfs_read_file('vzdump.cron');
+ my $all_jobs = $vzconf->{jobs} || [];
+ my $job;
+ my $rrd = PVE::Cluster::rrd_dump();
+
+ for my $j (@$all_jobs) {
+ if ($j->{id} eq $param->{id}) {
+ $job = $j;
+ last;
+ }
+ }
+ raise_param_exc({ id => "No such job '$param->{id}'" }) if !$job;
+
+ my $vmlist = PVE::Cluster::get_vmlist();
+
+ my @job_vmids;
+
+ my $included_guests = PVE::VZDump::get_included_guests($job);
+
+ for my $node (keys %{$included_guests}) {
+ my $node_vmids = $included_guests->{$node};
+ push(@job_vmids, @{$node_vmids});
+ }
+
+ # remove VMIDs to which the user has no permission to not leak infos
+ # like the guest name
+ my @allowed_vmids = grep {
+ $rpcenv->check($user, "/vms/$_", [ 'VM.Audit' ], 1);
+ } @job_vmids;
+
+ my $result = {
+ children => [],
+ };
+
+ for my $vmid (@allowed_vmids) {
+
+ my $children = [];
+
+ # It's possible that a job has VMIDs configured that are not in
+ # vmlist. This could be because a guest was removed but not purged.
+ # Since there is no more data available we can only deliver the VMID
+ # and no volumes.
+ if (!defined $vmlist->{ids}->{$vmid}) {
+ push(@{$result->{children}}, {
+ id => int($vmid),
+ type => 'unknown',
+ leaf => 1,
+ });
+ next;
+ }
+
+ my $type = $vmlist->{ids}->{$vmid}->{type};
+ my $node = $vmlist->{ids}->{$vmid}->{node};
+
+ my $conf;
+ my $volumes;
+ my $name = "";
+
+ if ($type eq 'qemu') {
+ $conf = PVE::QemuConfig->load_config($vmid, $node);
+ $volumes = PVE::QemuConfig->get_backup_volumes($conf);
+ $name = $conf->{name};
+ } elsif ($type eq 'lxc') {
+ $conf = PVE::LXC::Config->load_config($vmid, $node);
+ $volumes = PVE::LXC::Config->get_backup_volumes($conf);
+ $name = $conf->{hostname};
+ } else {
+ die "VMID $vmid is neither Qemu nor LXC guest\n";
+ }
+
+ foreach my $volume (@$volumes) {
+ my $disk = {
+ # id field must be unique for ExtJS tree view
+ id => "$vmid:$volume->{key}",
+ name => $volume->{volume_config}->{file} // $volume->{volume_config}->{volume},
+ included=> $volume->{included},
+ reason => $volume->{reason},
+ leaf => 1,
+ };
+ push(@{$children}, $disk);
+ }
+
+ my $leaf = 0;
+ # it's possible for a guest to have no volumes configured
+ $leaf = 1 if !@{$children};
+
+ push(@{$result->{children}}, {
+ id => int($vmid),
+ type => $type,
+ name => $name,
+ children => $children,
+ leaf => $leaf,
+ });
+ }
+
+ return $result;
+ }});
+
1;
--
2.20.1
next prev parent reply other threads:[~2020-07-07 9:56 UTC|newest]
Thread overview: 9+ messages / expand[flat|nested] mbox.gz Atom feed top
2020-07-07 9:48 [pve-devel] [PATCH v4 manager 0/5] add backup detail and not backed up view Aaron Lauterer
2020-07-07 9:48 ` Aaron Lauterer [this message]
2020-07-08 7:11 ` [pve-devel] [PATCH v4 manager 1/5] api: backup: add endpoint to list included guests and volumes Thomas Lamprecht
2020-07-08 7:21 ` Aaron Lauterer
2020-07-07 9:48 ` [pve-devel] [PATCH v4 manager 2/5] gui: dc/backup: move renderers to Utils.js Aaron Lauterer
2020-07-07 9:49 ` [pve-devel] [PATCH v4 manager 3/5] gui: dc/backup: add new backup job detail view Aaron Lauterer
2020-07-07 9:49 ` [pve-devel] [PATCH v4 manager 4/5] fix #2609 api: backupinfo: add non job specific endpoint Aaron Lauterer
2020-07-07 9:49 ` [pve-devel] [PATCH v4 manager 5/5] fix #2609 gui: backup: add window for not backed guests Aaron Lauterer
2020-07-09 18:06 ` [pve-devel] applied-series: Re: [PATCH v4 manager 0/5] add backup detail and not backed up view Thomas Lamprecht
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=20200707094902.24712-2-a.lauterer@proxmox.com \
--to=a.lauterer@proxmox.com \
--cc=pve-devel@pve.proxmox.com \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox