Re: [pve-devel] [PATCH qemu-server v3 2/6] fix #4225: qemuserver: introduce sub eject_nonrequired_isos

[Fiona Ebner <f.ebner@proxmox.com>]

Am 30.01.25 um 12:31 schrieb Daniel Herzig:
> The function `eject_nonrequired_isos` checks on whether a cdrom drive is
> marked as required for booting the VM  or not. If the parameter `essential` is not
> defined, it will assume `essential` to be true and keep the current
> behaviour.
> 
> If `required` is set to 0, the function 'ejects' the ISO file by
> setting the drive's file value to 'none', if the underlying storage is
> unavailable or if the defined file is unavailable for another reason.
> 
> The function is meant to be called from `config_to_command` while it
> iterates over all volumes to allow for early storage activation and
> early exit in the case of missing required files or unavailable
> network storages.
> 
> This commit also adds a small helper sub `file_exists` to facilitate
> mocking of file existence, which is needed for testing
> `eject_nonrequired_isos` once in place.
> ---
>  PVE/QemuServer.pm | 35 +++++++++++++++++++++++++++++++++++
>  1 file changed, 35 insertions(+)
> 
> diff --git a/PVE/QemuServer.pm b/PVE/QemuServer.pm
> index 808c0e1c..d151c322 100644
> --- a/PVE/QemuServer.pm
> +++ b/PVE/QemuServer.pm
> @@ -8797,4 +8797,39 @@ sub delete_ifaces_ipams_ips {
>      }
>  }
>  
> +sub eject_nonrequired_isos {
> +    my ($ds, $drive, $vmid, $storecfg, $conf) = @_;
> +
> +    # exclude cloudinit drives from processing (parameter '1')
> +    return if ( !drive_is_cdrom($drive, 1) ||
> +		$drive->{file} eq 'none' ||
> +		$drive->{file} eq 'cdrom' );

Style nit: post-ifs should not be multiline, post-ifs don't use
additional parentheses:
https://pve.proxmox.com/wiki/Perl_Style_Guide#Wrapping_Post-If

> +
> +    $drive->{essential} = 1 if !defined($drive->{essential});

This should rather be done when parsing the drive.

> +    my $iso_volid = $drive->{file};

Nit: variable could be moved up so that the previous check can already
use it

> +    my $iso_path = PVE::QemuServer::Drive::get_iso_path($storecfg, $vmid, $iso_volid);
> +    my $store_err;
> +    if ($iso_volid !~ m|^/|) {
> +	my $iso_storage  = PVE::Storage::parse_volume_id($iso_volid, 1);
> +	eval { PVE::Storage::activate_storage($storecfg, $iso_storage); };
> +	$store_err = $@;

I'd issue a warning here if there was a failure to activate.

> +    }
> +
> +    return if ( !$store_err &&
> +		file_exists($iso_path) );
> +
> +    if ($drive->{essential}) {
> +	die "'${ds}: ${iso_volid}': storage unavailable or file does not exist\n";
> +    } else {
> +	log_warn("eject '${ds}: ${iso_volid}': storage unavailable or file does not exist");

Technically, this does not eject anything, just changes the configuration.

> +	$drive->{file} = 'none';
> +	$conf->{$ds} = print_drive($drive);

Should we also make sure to write out the modified config? Especially
for live-migration it's important to stay in-sync and so the migration
target should not suddenly have a CD-ROM again if it became accessible
again. Writing the config can also be done by the caller of course if it
better fits there.

> +    }
> +}
> +
> +sub file_exists {
> +    my $file_path = shift;
> +    return -e $file_path

This will only work for file-based storages. The PVE::Storage::path()
function can also return a protocol-based path like "glusterfs://xyz"
which will not work for "-e" checks. (Our glusterfs plugin does so only
for content type "images", but nothing requires a "media=cdrom" drive to
be of content type "iso" right now, and I'm making a general point here,
there are third-party plugins too). So to cleanly solve this, it will be
required to either use e.g. "qemu-img info" as a proxy for existence
checking, which is often done in our code via volume_size_info() (or
alternatively to add a dedicated storage+plugin API function to check
for the existence of an image).

> +}
> +
>  1;



_______________________________________________
pve-devel mailing list
pve-devel@lists.proxmox.com
https://lists.proxmox.com/cgi-bin/mailman/listinfo/pve-devel