From: Thomas Lamprecht <t.lamprecht@proxmox.com>
To: pve-devel@lists.proxmox.com
Subject: [PATCH container v2 20/36] fix #7846: config: add a guest identity to the 'meta' property
Date: Tue, 17 Nov 2026 23:34:30 +0100 [thread overview]
Message-ID: <20261117223945.862914-21-t.lamprecht@proxmox.com> (raw)
In-Reply-To: <20261117223945.862914-1-t.lamprecht@proxmox.com>
Give containers a guest identity in the 'meta' property: a random
identifier, 'uid', and the time the container was registered in the
cluster, 'rtime'.
With identities enabled for the config class, every config write keeps
the identity a container already has, or assigns one if it has none,
whatever the written config carries. So create and clone get a new
identity when the VMID is reserved, while config changes, pending
changes applied by the post-stop hook, snapshot rollback and a restore
over an existing container keep it. A container without identity gets
one with its first config write by an upgraded node.
The post-stop hook writes the config it loaded before, without the
guest lock. As the write reads the existing identity under the
per-VMID identity lock, an identity that another writer assigned in the
meantime is kept and not replaced by a second one.
Signed-off-by: Thomas Lamprecht <t.lamprecht@proxmox.com>
---
changes v1 -> v2:
* rebase, adapt the tests
src/PVE/LXC/Config.pm | 8 ++
src/test/lifecycle_tests.pl | 242 +++++++++++++++++++++++++++++++++++-
2 files changed, 248 insertions(+), 2 deletions(-)
diff --git a/src/PVE/LXC/Config.pm b/src/PVE/LXC/Config.pm
index 2d5536a..d9e3931 100644
--- a/src/PVE/LXC/Config.pm
+++ b/src/PVE/LXC/Config.pm
@@ -9,6 +9,7 @@ use PVE::AbstractConfig;
use PVE::Cluster qw(cfs_register_file);
use PVE::DataCenterConfig;
use PVE::GuestHelpers;
+use PVE::GuestIdentity;
use PVE::INotify;
use PVE::JSONSchema qw(get_standard_option);
use PVE::Network::SDN::Vnets;
@@ -60,6 +61,12 @@ sub cfs_config_path {
return "nodes/$node/lxc/$vmid.conf";
}
+sub __identity_enabled {
+ my ($class) = @_;
+
+ return 1;
+}
+
sub mountpoint_backup_enabled {
my ($class, $mp_key, $mountpoint) = @_;
@@ -512,6 +519,7 @@ my $meta_info_fmt = {
minimum => 0,
optional => 1,
},
+ PVE::GuestIdentity::meta_format_properties()->%*,
};
my $confdesc = {
diff --git a/src/test/lifecycle_tests.pl b/src/test/lifecycle_tests.pl
index bc6cbf1..2387c6d 100755
--- a/src/test/lifecycle_tests.pl
+++ b/src/test/lifecycle_tests.pl
@@ -7,10 +7,12 @@ use v5.36;
use lib qw(..);
-# The API modules load modules of pve-ha-manager, which is not a build dependency, so stub them. Tests
-# that call into them mock the functions they need.
+# The API modules load modules of pve-ha-manager and the backup plugin PVE::VZDump of pve-manager,
+# which are not build dependencies, so stub them. Tests that call into them mock the functions they
+# need.
BEGIN {
$INC{'PVE/HA/Config.pm'} = $INC{'PVE/HA/Env/PVE2.pm'} = __FILE__;
+ $INC{'PVE/VZDump.pm'} = __FILE__;
}
use File::Path qw(make_path remove_tree);
@@ -135,6 +137,26 @@ $config_module->mock(
},
);
+# Guest identities are generated deterministically, the local identity lock is taken in the working
+# directory.
+
+$PVE::GuestHelpers::lockdir = "$WORKDIR/lock";
+
+my $random_counter = 0;
+my $now_ms = 1_700_000_000_000;
+
+my $identity_module = Test::MockModule->new('PVE::GuestIdentity');
+$identity_module->mock(
+ __random_bytes => sub {
+ my ($len) = @_;
+ die "unexpected length $len\n" if $len != 20;
+ # one byte per uid character, the last three hold 5 bits of the counter each
+ my $n = ++$random_counter;
+ return ("\0" x 17) . pack('C3', map { ($n >> $_) & 31 } (10, 5, 0));
+ },
+ __time_ms => sub { return $now_ms },
+);
+
my $repl_config_module = Test::MockModule->new('PVE::ReplicationConfig');
$repl_config_module->mock(
new => sub { return bless {}, 'PVE::ReplicationConfig' },
@@ -179,6 +201,7 @@ $restenv_module->mock(
chomp($msg);
$task_log .= "WARN: $msg\n";
},
+ setup_default_cli_env => sub { },
);
# Runs $code like a task, with its output going to the task log. Returns the error, if any.
@@ -218,6 +241,8 @@ $storage_module->mock(
},
storage_has_feature => sub { return 0 },
get_bandwidth_limit => sub { return undef },
+ volume_rollback_is_possible => sub { return 1 },
+ volume_snapshot_rollback => sub { },
);
my $lxc_module = Test::MockModule->new('PVE::LXC');
@@ -249,6 +274,10 @@ $lxc_module->mock(
return $rootdir;
},
umount_all => sub { },
+ copy_volume => sub {
+ my ($mp, $newid) = @_;
+ return "local:$newid/vm-$newid-disk-0.raw";
+ },
create_ifaces_ipams_ips => sub { },
delete_ifaces_ipams_ips => sub { },
update_lxc_config => sub { },
@@ -286,6 +315,7 @@ package PVE::LXC::Test::Setup {
my $firewall_module = Test::MockModule->new('PVE::Firewall');
$firewall_module->mock(
+ clone_vmfw_conf => sub { },
remove_vmfw_conf => sub {
my ($vmid) = @_;
$vmfw_removed_reserved->{$vmid}++ if defined(read_raw_config($vmid));
@@ -327,6 +357,17 @@ my sub update_ct($vmid, $param) {
});
}
+my sub clone_ct($vmid, $newid, $param = undef) {
+ return run_task(sub {
+ PVE::API2::LXC->clone_vm({
+ node => $NODENAME,
+ vmid => $vmid,
+ newid => $newid,
+ ($param // {})->%*,
+ });
+ });
+}
+
# Runs the migration tunnel for $vmid with the commands @commands, which are sent at once, and
# returns the error of the task, if any, and the replies.
my sub run_mtunnel($vmid, @commands) {
@@ -400,6 +441,10 @@ my sub meta_of($vmid) {
return { map { split(/=/, $_, 2) } split(/,/, $conf->{meta} // '') };
}
+my sub identity_of($vmid) {
+ return PVE::LXC::Config->get_identity(PVE::LXC::Config->load_config($vmid));
+}
+
# Tests
subtest 'meta cannot be changed through the API' => sub {
@@ -544,6 +589,199 @@ subtest 'remote migration keeps the meta information of the source' => sub {
is($conf->{lock}, 'migrate', 'config is locked for the migration');
};
+subtest 'create assigns a new guest identity' => sub {
+ reset_configs();
+ $now_ms = 1_700_000_000_000;
+
+ my $err = create_ct(201);
+ is($err, '', 'create succeeds');
+
+ my $meta = meta_of(201);
+ like($meta->{uid}, qr/^[a-z2-7]{20}$/, 'uid is assigned');
+ is($meta->{rtime}, 1_700_000_000_000, 'rtime is the time of the create');
+ ok(defined($meta->{ctime}), 'ctime is kept next to the identity');
+ ok(!defined(PVE::LXC::Config->load_config(201)->{lock}), 'create lock is removed');
+
+ $err = create_ct(202);
+ isnt(identity_of(202)->{uid}, $meta->{uid}, 'another container gets another uid');
+};
+
+subtest 'config changes keep the guest identity' => sub {
+ reset_configs();
+ my $meta = 'ctime=1500000000,rtime=1500000000000,uid=existingexistingexis';
+ write_raw_config(200, existing_config($meta));
+ $now_ms = 1_700_000_000_000;
+
+ my $err = update_ct(200, { hostname => 'changed', memory => 1024 });
+ is($err, '', 'update succeeds');
+ my $conf = PVE::LXC::Config->load_config(200);
+ is($conf->{hostname}, 'changed', 'change is applied');
+ is($conf->{meta}, $meta, 'meta is unchanged');
+
+ write_raw_config(200, existing_config('ctime=1500000000'));
+ $err = update_ct(200, { hostname => 'first-write' });
+ is($err, '', 'update of a container without identity succeeds');
+ my $identity = identity_of(200);
+ like($identity->{uid}, qr/^[a-z2-7]{20}$/, 'first write assigns a uid');
+ is($identity->{rtime}, 1_700_000_000_000, 'first write sets rtime');
+ is(meta_of(200)->{ctime}, 1500000000, 'ctime is kept');
+
+ $now_ms += 1000;
+ $err = update_ct(200, { hostname => 'second-write' });
+ is_deeply(identity_of(200), $identity, 'later writes keep the identity');
+};
+
+subtest 'clone assigns a new guest identity' => sub {
+ reset_configs();
+ write_raw_config(
+ 200,
+ existing_config('ctime=1500000000,rtime=1500000000000,uid=existingexistingexis'),
+ );
+ $now_ms = 1_700_000_000_000;
+
+ my $err = clone_ct(200, 201, { hostname => 'clone' });
+ is($err, '', 'clone succeeds') or diag($task_log);
+
+ my $meta = meta_of(201);
+ like($meta->{uid}, qr/^[a-z2-7]{20}$/, 'clone has a uid');
+ isnt($meta->{uid}, 'existingexistingexis', 'clone does not get the uid of the source');
+ is($meta->{rtime}, 1_700_000_000_000, 'rtime is the time of the clone');
+ is($meta->{ctime}, 1500000000, 'ctime of the source is kept');
+ is(identity_of(200)->{uid}, 'existingexistingexis', 'source keeps its uid');
+};
+
+subtest 'snapshot rollback keeps the current guest identity' => sub {
+ reset_configs();
+ write_raw_config(200, <<~'EOF');
+ arch: amd64
+ hostname: existing
+ memory: 512
+ meta: ctime=1500000000,rtime=1600000000000,uid=existingexistingexis
+ ostype: debian
+ parent: snap
+ rootfs: local:200/vm-200-disk-0.raw,size=4G
+ unprivileged: 1
+
+ [snap]
+ arch: amd64
+ hostname: snapshot
+ memory: 512
+ meta: ctime=1500000000,rtime=1500000000000,uid=snapshotsnapshotsnap
+ ostype: debian
+ rootfs: local:200/vm-200-disk-0.raw,size=4G
+ snaptime: 1500000000
+ unprivileged: 1
+ EOF
+
+ my $err = run_task(sub { PVE::LXC::Config->snapshot_rollback(200, 'snap') });
+ is($err, '', 'rollback succeeds') or diag($task_log);
+
+ my $conf = PVE::LXC::Config->load_config(200);
+ is($conf->{hostname}, 'snapshot', 'config of the snapshot is restored');
+ is_deeply(
+ identity_of(200),
+ { uid => 'existingexistingexis', rtime => 1600000000000 },
+ 'current identity is kept',
+ );
+};
+
+subtest 'in-place restore keeps the guest identity of the target' => sub {
+ reset_configs();
+ my $meta = 'ctime=1500000000,rtime=1500000000000,uid=existingexistingexis';
+ write_raw_config(200, existing_config($meta));
+
+ for my $backup_meta (
+ undef, 'ctime=1400000000,rtime=1400000000000,uid=existingexistingexis',
+ ) {
+ $backup_raw_config = backup_config($backup_meta);
+ my $err = restore_ct(200, { force => 1 });
+ is($err, '', 'restore succeeds') or diag($task_log);
+ is_deeply(
+ identity_of(200),
+ { uid => 'existingexistingexis', rtime => 1500000000000 },
+ 'identity is kept',
+ );
+ is(PVE::LXC::Config->load_config(200)->{hostname}, 'backup', 'backup is restored');
+ }
+};
+
+subtest 'backup assigns the guest identity and includes it' => sub {
+ reset_configs();
+ write_raw_config(987, existing_config('ctime=1500000000'));
+ $now_ms = 1_700_000_000_000;
+
+ require PVE::VZDump::LXC;
+ my $plugin = bless { vzdump => { opts => { pbs => 1 } } }, 'PVE::VZDump::LXC';
+
+ $plugin->lock_vm(987);
+ my $identity = identity_of(987);
+ like($identity->{uid}, qr/^[a-z2-7]{20}$/, 'backup lock assigns a uid');
+ is($identity->{rtime}, $now_ms, 'backup lock sets rtime');
+
+ $plugin->assemble({ tmpdir => "$WORKDIR/backup" }, 987);
+ my $raw = file_get_contents("$WORKDIR/backup/etc/vzdump/pct.conf");
+ my $backup_conf = PVE::LXC::Config::parse_pct_config('/lxc/987.conf', $raw);
+ is_deeply(
+ PVE::LXC::Config->get_identity($backup_conf),
+ $identity,
+ 'backup has the identity',
+ );
+
+ $now_ms += 1000;
+ $plugin->unlock_vm(987);
+ is_deeply(identity_of(987), $identity, 'removing the backup lock keeps the identity');
+};
+
+subtest 'post-stop hook keeps an identity stored while it ran' => sub {
+ reset_configs();
+ write_raw_config(200, existing_config('ctime=1500000000'));
+ $now_ms = 1_700_000_000_000;
+
+ my $stored;
+ $lxc_module->mock(
+ get_staging_tempfs => sub { return "$WORKDIR/staging" },
+ vm_stop_cleanup => sub {
+ # another writer assigns the identity after the hook loaded the config
+ PVE::LXC::Config->lock_config(
+ 200,
+ sub {
+ my $conf = PVE::LXC::Config->load_config(200);
+ $conf->{description} = 'written while the hook ran';
+ PVE::LXC::Config->write_config(200, $conf);
+ },
+ );
+ $stored = identity_of(200);
+ $now_ms += 1000;
+ },
+ );
+ my $tools_module = Test::MockModule->new('PVE::Tools');
+ $tools_module->mock(run_command => sub { });
+ my $guest_helpers_module = Test::MockModule->new('PVE::GuestHelpers');
+ $guest_helpers_module->mock(exec_hookscript => sub { });
+
+ local $ENV{LXC_HOOK_VERSION} = '1';
+ local $ENV{LXC_NAME} = '200';
+ local $ENV{LXC_HOOK_SECTION} = 'lxc';
+ local $ENV{LXC_HOOK_TYPE} = 'post-stop';
+ local $ENV{LXC_ROOTFS_MOUNT} = "$WORKDIR/rootfs/200";
+ local $ENV{LXC_ROOTFS_PATH} = "$WORKDIR/rootfs/200";
+ local $ENV{LXC_CONFIG_FILE} = "$WORKDIR/lxc-200.config";
+ delete local $ENV{LXC_TARGET};
+
+ my $err = run_task(sub {
+ do '../lxc-pve-poststop-hook';
+ die $@ if $@;
+ });
+ is($err, '', 'hook succeeds') or diag($task_log);
+ unlike($task_log, qr/WARN/, 'hook does not warn') or diag($task_log);
+
+ like($stored->{uid}, qr/^[a-z2-7]{20}$/, 'other writer assigned a uid');
+ ok(!defined(PVE::LXC::Config->load_config(200)->{description}), 'hook wrote its config');
+ is_deeply(identity_of(200), $stored, 'hook keeps the identity');
+
+ $lxc_module->unmock('get_staging_tempfs', 'vm_stop_cleanup');
+};
+
remove_tree($WORKDIR);
done_testing();
--
2.47.3
next prev parent reply other threads:[~2026-11-17 22:42 UTC|newest]
Thread overview: 38+ messages / expand[flat|nested] mbox.gz Atom feed top
2026-11-17 22:34 [PATCH cluster/guest-common/qemu-server/container/manager/docs v2 00/36] fix #7846: guest identity (uid) and cluster ID Thomas Lamprecht
2026-11-17 22:34 ` [PATCH cluster v2 01/36] pmxcfs: reject changes to the cluster ID file from user space Thomas Lamprecht
2026-11-17 22:34 ` [PATCH cluster v2 02/36] pmxcfs: generate a cluster ID on standalone nodes Thomas Lamprecht
2026-11-17 22:34 ` [PATCH cluster v2 03/36] pmxcfs: dfsm: add a callback that runs once all members are in sync Thomas Lamprecht
2026-11-17 22:34 ` [PATCH cluster v2 04/36] pmxcfs: quorum: pass the corosync membership to an optional listener Thomas Lamprecht
2026-11-17 22:34 ` [PATCH cluster v2 05/36] pmxcfs: dcdb: generate the cluster ID once the cluster is in sync Thomas Lamprecht
2026-11-17 22:34 ` [PATCH cluster v2 06/36] cluster: add helper to read the cluster ID Thomas Lamprecht
2026-11-17 22:34 ` [PATCH cluster v2 07/36] pmxcfs: allow removing the cluster ID file in forced local mode Thomas Lamprecht
2026-11-17 22:34 ` [PATCH guest-common v2 08/36] guest identity: add helpers for the guest uid and registration time Thomas Lamprecht
2026-11-17 22:34 ` [PATCH guest-common v2 09/36] abstract config: assign a guest identity and keep it on config writes Thomas Lamprecht
2026-11-17 22:34 ` [PATCH guest-common v2 10/36] abstract config: let the VMID reservation return the previous state Thomas Lamprecht
2026-11-17 22:34 ` [PATCH guest-common v2 11/36] guest identity: allow taking over a uid that is unused in the cluster Thomas Lamprecht
2026-11-17 22:34 ` [PATCH qemu-server v2 12/36] api: restore: release the VMID if a restore to an unused VMID fails Thomas Lamprecht
2026-11-17 22:34 ` [PATCH qemu-server v2 13/36] api: migrate, clone: refuse targets that would drop the guest identity Thomas Lamprecht
2026-11-17 22:34 ` [PATCH qemu-server v2 14/36] fix #7846: config: add a guest identity to the 'meta' property Thomas Lamprecht
2026-11-17 22:34 ` [PATCH qemu-server v2 15/36] restore: take over the guest uid from the backup where possible Thomas Lamprecht
2026-11-17 22:34 ` [PATCH qemu-server v2 16/36] api: remote migration: take over the guest uid from the source Thomas Lamprecht
2026-11-17 22:34 ` [PATCH qemu-server v2 17/36] api: status: return the guest uid Thomas Lamprecht
2026-11-17 22:34 ` [PATCH qemu-server v2 18/36] tests: remote migration: check a failed command and an early tunnel end Thomas Lamprecht
2026-11-17 22:34 ` [PATCH container v2 19/36] config: add read-only meta property with the creation time Thomas Lamprecht
2026-11-17 22:34 ` Thomas Lamprecht [this message]
2026-11-17 22:34 ` [PATCH container v2 21/36] api: migrate, clone: refuse targets that would drop the guest identity Thomas Lamprecht
2026-11-17 22:34 ` [PATCH container v2 22/36] restore: take over the guest uid from the backup where possible Thomas Lamprecht
2026-11-17 22:34 ` [PATCH container v2 23/36] restore: refuse overwriting a container with another guest's backup Thomas Lamprecht
2026-11-17 22:34 ` [PATCH container v2 24/36] test: remote migration: check the cleanup of the target after failures Thomas Lamprecht
2026-11-17 22:34 ` [PATCH container v2 25/36] api: remote migration: take over the guest uid from the source Thomas Lamprecht
2026-11-17 22:34 ` [PATCH container v2 26/36] api: status: return the guest uid Thomas Lamprecht
2026-11-17 22:34 ` [PATCH manager v2 27/36] api: cluster resources: add guest uid and registration time Thomas Lamprecht
2026-11-17 22:34 ` [PATCH manager v2 28/36] api: cluster status: add cluster ID Thomas Lamprecht
2026-11-17 22:34 ` [PATCH manager v2 29/36] ui: restore: allow overwriting a guest with a backup of another guest Thomas Lamprecht
2026-11-17 22:34 ` [PATCH manager v2 30/36] ui: migrate: refuse target nodes that would drop the guest identity Thomas Lamprecht
2026-11-17 22:34 ` [PATCH manager v2 31/36] ui: guest summary: show " Thomas Lamprecht
2026-11-17 22:34 ` [PATCH manager v2 32/36] api: migrate all: refuse targets that would drop " Thomas Lamprecht
2026-11-17 22:34 ` [PATCH docs v2 33/36] vzdump: describe the guest identity of VMs and containers Thomas Lamprecht
2026-11-17 22:34 ` [PATCH docs v2 34/36] pvecm: document the cluster ID and how to get a new one Thomas Lamprecht
2026-11-17 22:34 ` [PATCH docs v2 35/36] qm: configuration: describe the read-only meta property Thomas Lamprecht
2026-11-17 22:34 ` [PATCH docs v2 36/36] pct: " Thomas Lamprecht
2026-11-18 5:57 ` superseded: [PATCH cluster/guest-common/qemu-server/container/manager/docs v2 00/36] fix #7846: guest identity (uid) and cluster ID Thomas Lamprecht
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=20261117223945.862914-21-t.lamprecht@proxmox.com \
--to=t.lamprecht@proxmox.com \
--cc=pve-devel@lists.proxmox.com \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is an external index of several public inboxes,
see mirroring instructions on how to clone and mirror
all data and code used by this external index.