From: "Max R. Carrara" <m.carrara@proxmox.com>
To: pve-devel@lists.proxmox.com
Cc: Wolfgang Bumiller <w.bumiller@proxmox.com>
Subject: [PATCH pve-storage v3 22/51] common: test: set up parser testing code, add tests for 'iso' vtype
Date: Tue, 17 Nov 2026 21:38:54 +0100 [thread overview]
Message-ID: <20261117203953.913035-23-m.carrara@proxmox.com> (raw)
In-Reply-To: <20261117203953.913035-1-m.carrara@proxmox.com>
Set up the necessary scaffolding for testing the new parser functions
in `PVE::Storage::Common::Parse` and add tests for the 'iso' vtype.
This also adds `libtest-differences-perl` to `Build-Depends`.
Since the volid parsing functions are built on top of the volname
parsing functions, their tests are built in a similar way; that is,
the volname parser test cases are taken and adapted for the volid
parsers.
This is primarily done to ensure consistency between the two
"families" of parsing functions; for example, the
`parse_abs_path_as_volid_parts()` function should always return the same
hash as the `parse_rel_path_as_volname_parts()` function, except that it
also contains a 'volid' key.
Signed-off-by: Max R. Carrara <m.carrara@proxmox.com>
---
debian/control | 1 +
src/PVE/Makefile | 1 +
src/PVE/Storage/Common/Makefile | 4 +
src/PVE/Storage/Common/test/Makefile | 6 +
src/PVE/Storage/Common/test/parser_tests.pl | 328 ++++++++++++++++++++
src/PVE/Storage/Common/test/run_tests.pl | 25 ++
src/PVE/Storage/Makefile | 4 +
7 files changed, 369 insertions(+)
create mode 100644 src/PVE/Storage/Common/test/Makefile
create mode 100755 src/PVE/Storage/Common/test/parser_tests.pl
create mode 100755 src/PVE/Storage/Common/test/run_tests.pl
diff --git a/debian/control b/debian/control
index f87a052a..44e9e6f1 100644
--- a/debian/control
+++ b/debian/control
@@ -8,10 +8,11 @@ Build-Depends: debhelper-compat (= 13),
libpve-access-control,
libpve-cluster-perl (>= 9.1.9),
libpve-common-perl (>= 9.2.10),
librados2-perl,
libtest-mockmodule-perl,
+ libtest-differences-perl,
libxml-libxml-perl,
lintian,
open-iscsi,
perl,
pve-cluster (>= 5.0-32),
diff --git a/src/PVE/Makefile b/src/PVE/Makefile
index 9e9f6aac..b8fc6325 100644
--- a/src/PVE/Makefile
+++ b/src/PVE/Makefile
@@ -12,8 +12,9 @@ install:
make -C BackupProvider install
make -C CLI install
.PHONY: test
test:
+ $(MAKE) -C Storage test
$(MAKE) -C test test
clean:
diff --git a/src/PVE/Storage/Common/Makefile b/src/PVE/Storage/Common/Makefile
index 0d9b1be1..7a13371d 100644
--- a/src/PVE/Storage/Common/Makefile
+++ b/src/PVE/Storage/Common/Makefile
@@ -3,5 +3,9 @@ SOURCES = \
.PHONY: install
install:
for i in ${SOURCES}; do install -D -m 0644 $$i ${DESTDIR}${PERLDIR}/PVE/Storage/Common/$$i; done
+
+.PHONY: test
+test:
+ make -C test test
diff --git a/src/PVE/Storage/Common/test/Makefile b/src/PVE/Storage/Common/test/Makefile
new file mode 100644
index 00000000..c4b2c0db
--- /dev/null
+++ b/src/PVE/Storage/Common/test/Makefile
@@ -0,0 +1,6 @@
+all: test
+
+.PHONY: test
+test: run_tests.pl
+ ./run_tests.pl
+
diff --git a/src/PVE/Storage/Common/test/parser_tests.pl b/src/PVE/Storage/Common/test/parser_tests.pl
new file mode 100755
index 00000000..ea770bb4
--- /dev/null
+++ b/src/PVE/Storage/Common/test/parser_tests.pl
@@ -0,0 +1,328 @@
+#!/usr/bin/perl
+
+use v5.36;
+
+use lib q(../../../..);
+
+use File::Temp;
+use Storable qw(dclone);
+
+use PVE::Storage::Common qw(
+ plugin_get_vtype_subdir
+);
+use PVE::Storage::Common::Parse qw(
+ parse_rel_path_as_volname_parts
+ parse_rel_path_as_volname
+ parse_volname_as_parts
+
+ parse_abs_path_as_volid_parts
+ parse_abs_path_as_volid
+ parse_volid_as_parts
+);
+
+use Test::More qw(no_plan);
+use Test::Differences;
+
+my $volname_tests = [];
+
+my $volname_cases_iso_valid = [
+ # plain paths
+ {
+ path => 'custom-debian.iso',
+ expected => {
+ file => 'custom-debian.iso',
+ ext => 'iso',
+ 'disk-path' => 'custom-debian.iso',
+ path => 'custom-debian.iso',
+ vtype => 'iso',
+ volname => 'iso/custom-debian.iso',
+ },
+ },
+ {
+ path => 'archlinux.img',
+ expected => {
+ file => 'archlinux.img',
+ ext => 'img',
+ 'disk-path' => 'archlinux.img',
+ path => 'archlinux.img',
+ vtype => 'iso',
+ volname => 'iso/archlinux.img',
+ },
+ },
+
+ # case insensitive file extensions
+ {
+ path => 'Debian 13 Trixie.ISO',
+ expected => {
+ file => 'Debian 13 Trixie.ISO',
+ ext => 'ISO',
+ 'disk-path' => 'Debian 13 Trixie.ISO',
+ path => 'Debian 13 Trixie.ISO',
+ vtype => 'iso',
+ volname => 'iso/Debian 13 Trixie.ISO',
+ },
+ },
+ {
+ path => 'Fedora.Img',
+ expected => {
+ file => 'Fedora.Img',
+ ext => 'Img',
+ 'disk-path' => 'Fedora.Img',
+ path => 'Fedora.Img',
+ vtype => 'iso',
+ volname => 'iso/Fedora.Img',
+ },
+ },
+];
+
+my $volname_cases_iso_invalid = [
+ {
+ description => "Invalid file extension (iso)",
+ args => {
+ path => 'MacOS-kittycat.dmg',
+ vtype => 'iso',
+ },
+ expected => undef,
+ },
+];
+
+my $volname_cases_newline_invalid = [
+ {
+ description => "Trailing newline (iso)",
+ args => {
+ path => "debian.iso\n",
+ vtype => 'iso',
+ },
+ expected => undef,
+ },
+ {
+ description => "Newline in file name (iso)",
+ args => {
+ path => "deb\nian.iso",
+ vtype => 'iso',
+ },
+ expected => undef,
+ },
+ {
+ description => "Newline in directory name (iso)",
+ args => {
+ path => "sub\ndir/debian.iso",
+ vtype => 'iso',
+ },
+ expected => undef,
+ },
+];
+
+my $cases_valid_all = [
+ $volname_cases_iso_valid,
+];
+
+my $cases_invalid_all = [
+ $volname_cases_iso_invalid, $volname_cases_newline_invalid,
+];
+
+{
+ for my $cases_list ($cases_valid_all->@*) {
+ for my $case ($cases_list->@*) {
+ my $path = $case->{path};
+ my $vtype = $case->{expected}->{vtype};
+
+ push(
+ $volname_tests->@*,
+ {
+ description => "Valid path ($vtype) \"$path\"",
+ args => {
+ path => $path,
+ vtype => $vtype,
+ },
+ expected => $case->{expected},
+ },
+ );
+ }
+ }
+
+ for my $cases_list ($cases_invalid_all->@*) {
+ push($volname_tests->@*, $cases_list->@*);
+ }
+}
+
+my sub run_volname_parsing_tests : prototype($) ($volname_tests) {
+ for my $case ($volname_tests->@*) {
+ subtest $case->{description} => sub() {
+ my ($path, $vtype) = $case->{args}->@{qw(path vtype)};
+
+ my $got_volname_parts = parse_rel_path_as_volname_parts($path, $vtype);
+ my $got_volname = parse_rel_path_as_volname($path, $vtype);
+
+ if (defined($case->{expected})) {
+ eq_or_diff(
+ $got_volname_parts,
+ $case->{expected},
+ 'parse_rel_path_as_volname_parts() returns expected hashref',
+ { context => 50000 },
+ );
+
+ is(
+ $got_volname,
+ $case->{expected}->{volname},
+ 'parse_rel_path_as_volname() returns expected volname',
+ );
+
+ my $got_volname_parts_from_volname = parse_volname_as_parts($got_volname);
+
+ eq_or_diff(
+ $got_volname_parts_from_volname,
+ $case->{expected},
+ 'parse_volname_as_parts() returns expected hashref from parsed volname',
+ );
+ } else {
+ is($got_volname_parts, undef,
+ 'parse_rel_path_as_volname_parts() returns undef');
+ is($got_volname, undef, 'parse_rel_path_as_volname() returns undef');
+ }
+
+ };
+ }
+
+ return;
+}
+
+my $DEFAULT_STOREID = 'local';
+my $DEFAULT_STORAGE_PATH = File::Temp->newdir();
+my $DEFAULT_SCFG = {
+ type => 'dir',
+ path => $DEFAULT_STORAGE_PATH,
+ shared => 0,
+ content => {
+ iso => 1,
+ rootdir => 1,
+ vztmpl => 1,
+ images => 1,
+ snippets => 1,
+ backup => 1,
+ import => 1,
+ },
+};
+
+my $ALT_STOREID = 'dir-store';
+my $ALT_STORAGE_PATH = File::Temp->newdir();
+my $ALT_SCFG = {
+ type => 'dir',
+ path => $ALT_STORAGE_PATH,
+ shared => 0,
+ content => { $DEFAULT_SCFG->{content}->%* },
+ 'content-dirs' => {
+ iso => 'pve/volumes/iso',
+ vztmpl => 'pve/dumps/vz',
+ images => 'pve/guest/images',
+ snippets => 'pve/misc/snippets',
+ backup => 'pve/dumps/bak',
+ import => 'archive/import',
+ },
+};
+
+my sub format_volname_case_to_volid_case($storeid, $scfg, $volname_case) {
+ my $volid_case = dclone($volname_case);
+
+ my ($path, $vtype) = $volid_case->{args}->@{qw(path vtype)};
+
+ my $vtype_subdir = plugin_get_vtype_subdir($scfg, $vtype);
+
+ $volid_case->{args}->{path} = $vtype_subdir . '/' . $path;
+ $volid_case->{args}->{storeid} = $storeid;
+ $volid_case->{args}->{scfg} = $scfg;
+
+ if (defined($volid_case->{expected})) {
+ my $volname = $volid_case->{expected}->{volname};
+ $volid_case->{expected}->{volid} = $storeid . ':' . $volname;
+ }
+
+ return $volid_case;
+}
+
+my $volid_tests = [
+ {
+ description => "volid parsers build on volname parsers' behaviors (1)",
+ storeid => $DEFAULT_STOREID,
+ scfg => $DEFAULT_SCFG,
+ cases => [
+ map { format_volname_case_to_volid_case($DEFAULT_STOREID, $DEFAULT_SCFG, $_) }
+ $volname_tests->@*
+ ],
+ },
+ {
+ description => "volid parsers build on volname parsers' behaviors (2)",
+ storeid => $ALT_STOREID,
+ scfg => $ALT_SCFG,
+ cases => [
+ map { format_volname_case_to_volid_case($ALT_STOREID, $ALT_SCFG, $_) }
+ $volname_tests->@*
+ ],
+ },
+];
+
+my sub run_volid_parsing_tests : prototype($) ($volid_tests) {
+ for my $test ($volid_tests->@*) {
+ subtest $test->{description} => sub() {
+ for my $case ($test->{cases}->@*) {
+ my ($storeid, $scfg, $path, $vtype) =
+ $case->{args}->@{qw(storeid scfg path vtype)};
+
+ my $got_volid_parts =
+ parse_abs_path_as_volid_parts($storeid, $scfg, $path, $vtype);
+ my $got_volid = parse_abs_path_as_volid($storeid, $scfg, $path, $vtype);
+
+ note("Running test case based on:");
+ note($case->{description});
+
+ if (defined($case->{expected})) {
+ eq_or_diff(
+ $got_volid_parts,
+ $case->{expected},
+ 'parse_abs_path_as_volid_parts() returns expected hashref',
+ { context => 50000 },
+ );
+
+ is(
+ $got_volid,
+ $case->{expected}->{volid},
+ 'parse_abs_path_as_volid() returns expected volid',
+ );
+
+ my $expected_volid_parts = {
+ volid => $case->{expected}->{volid},
+ storeid => $case->{args}->{storeid},
+ volname => $case->{expected}->{volname},
+ };
+
+ my $got_volid_parts_from_volid = parse_volid_as_parts($got_volid);
+
+ eq_or_diff(
+ $got_volid_parts_from_volid,
+ $expected_volid_parts,
+ 'parse_volid_as_parts() returns expected hashref from parsed volid',
+ );
+ } else {
+ is($got_volid_parts, undef,
+ 'parse_abs_path_as_volid_parts() returns undef');
+ is($got_volid, undef, 'parse_abs_path_as_volid() returns undef');
+ }
+ }
+ };
+ }
+
+ return;
+}
+
+my sub main() {
+ unified_diff();
+
+ run_volname_parsing_tests($volname_tests);
+ run_volid_parsing_tests($volid_tests);
+
+ done_testing();
+
+ return;
+}
+
+main();
diff --git a/src/PVE/Storage/Common/test/run_tests.pl b/src/PVE/Storage/Common/test/run_tests.pl
new file mode 100755
index 00000000..b21668c0
--- /dev/null
+++ b/src/PVE/Storage/Common/test/run_tests.pl
@@ -0,0 +1,25 @@
+#!/usr/bin/perl
+
+use v5.36;
+
+use TAP::Harness;
+
+my $MAX_JOBS = 4;
+
+my $nproc = eval { int(`nproc`) } || $MAX_JOBS;
+
+my $jobs = $nproc > $MAX_JOBS ? $MAX_JOBS : $nproc;
+
+my sub main() {
+ my $harness = TAP::Harness->new({ verbosity => -1, jobs => $jobs });
+
+ my $res = $harness->runtests(
+ "parser_tests.pl",
+ );
+
+ exit -1 if !$res || $res->{failed} || $res->{parse_errors} || $res->{exit};
+
+ return;
+}
+
+main();
diff --git a/src/PVE/Storage/Makefile b/src/PVE/Storage/Makefile
index a67dc25f..1c8d364b 100644
--- a/src/PVE/Storage/Makefile
+++ b/src/PVE/Storage/Makefile
@@ -19,5 +19,9 @@ SOURCES= \
.PHONY: install
install:
make -C Common install
for i in ${SOURCES}; do install -D -m 0644 $$i ${DESTDIR}${PERLDIR}/PVE/Storage/$$i; done
make -C LunCmd install
+
+.PHONY: test
+test:
+ make -C Common test
--
2.47.3
next prev parent reply other threads:[~2026-11-17 20:43 UTC|newest]
Thread overview: 52+ messages / expand[flat|nested] mbox.gz Atom feed top
2026-11-17 20:38 [PATCH manager/storage v3 00/51] Fix #2884: Implement Subdirectory Scanning for Dir-Based Storage Types Max R. Carrara
2026-11-17 20:38 ` [PATCH pve-storage v3 01/51] test: plugin tests: run tests with at most 4 jobs Max R. Carrara
2026-11-17 20:38 ` [PATCH pve-storage v3 02/51] plugin, common: remove superfluous use of =pod command paragraph Max R. Carrara
2026-11-17 20:38 ` [PATCH pve-storage v3 03/51] common: use Exporter module for PVE::Storage::Common Max R. Carrara
2026-11-17 20:38 ` [PATCH pve-storage v3 04/51] plugin: make get_subdir_files a proper subroutine and update style Max R. Carrara
2026-11-17 20:38 ` [PATCH pve-storage v3 05/51] plugin api: replace subdir helper methods with standalone functions Max R. Carrara
2026-11-17 20:38 ` [PATCH pve-storage v3 06/51] common: prevent autovivification in plugin_get_vtype_subdir helper Max R. Carrara
2026-11-17 20:38 ` [PATCH pve-storage v3 07/51] plugin: break up if-elsif chain into separate if-blocks Max R. Carrara
2026-11-17 20:38 ` [PATCH pve-storage v3 08/51] plugin: adapt get_subdir_files helper of list_volumes API method Max R. Carrara
2026-11-17 20:38 ` [PATCH pve-storage v3 09/51] plugin: update code style of list_volumes plugin " Max R. Carrara
2026-11-17 20:38 ` [PATCH pve-storage v3 10/51] plugin: use closure for obtaining raw volume data in list_volumes Max R. Carrara
2026-11-17 20:38 ` [PATCH pve-storage v3 11/51] plugin: use closure for inner loop logic " Max R. Carrara
2026-11-17 20:38 ` [PATCH pve-storage v3 12/51] storage: update code style in function path_to_volume_id Max R. Carrara
2026-11-17 20:38 ` [PATCH pve-storage v3 13/51] storage: break up if-elsif chain in path_to_volume_id Max R. Carrara
2026-11-17 20:38 ` [PATCH pve-storage v3 14/51] storage: heave vtype file path parsing logic inside loop into helper Max R. Carrara
2026-11-17 20:38 ` [PATCH pve-storage v3 15/51] storage: clean up code that was moved into helper in path_to_volume_id Max R. Carrara
2026-11-17 20:38 ` [PATCH pve-storage v3 16/51] api: status: move content type assert for up-/downloads into helper Max R. Carrara
2026-11-17 20:38 ` [PATCH pve-storage v3 17/51] api: status: use get_subdir helper method to get content directory Max R. Carrara
2026-11-17 20:38 ` [PATCH pve-storage v3 18/51] api: status: move up-/download file path parsing code into helper Max R. Carrara
2026-11-17 20:38 ` [PATCH pve-storage v3 19/51] api: status: simplify file content assertion logic for up-/download Max R. Carrara
2026-11-17 20:38 ` [PATCH pve-storage v3 20/51] test: guest import: add tests for PVE::GuestImport Max R. Carrara
2026-11-17 20:38 ` [PATCH pve-storage v3 21/51] tree-wide: introduce parsing module and replace usages of ISO_EXT_RE_0 Max R. Carrara
2026-11-17 20:38 ` Max R. Carrara [this message]
2026-11-17 20:38 ` [PATCH pve-storage v3 23/51] tree-wide: replace usages of VZTMPL_EXT_RE_1 with parsing functions Max R. Carrara
2026-11-17 20:38 ` [PATCH pve-storage v3 24/51] tree-wide: replace usages of BACKUP_EXT_RE_2 " Max R. Carrara
2026-11-17 20:38 ` [PATCH pve-storage v3 25/51] tree-wide: replace usages of inline regexes for snippets with parsers Max R. Carrara
2026-11-17 20:38 ` [PATCH pve-storage v3 26/51] tree-wide: partially replace usages of regexes for 'import' vtype Max R. Carrara
2026-11-17 20:38 ` [PATCH pve-storage v3 27/51] tree-wide: replace remaining " Max R. Carrara
2026-11-17 20:39 ` [PATCH pve-storage v3 28/51] tree-wide: simplify recently refactored parsing logic Max R. Carrara
2026-11-17 20:39 ` [PATCH pve-storage v3 29/51] test: list volumes: reorganize and modernize test running code Max R. Carrara
2026-11-17 20:39 ` [PATCH pve-storage v3 30/51] test: list volumes: fix broken test checking for vmlist modifications Max R. Carrara
2026-11-17 20:39 ` [PATCH pve-storage v3 31/51] test: list volumes: introduce new format for test cases Max R. Carrara
2026-11-17 20:39 ` [PATCH pve-storage v3 32/51] test: list volumes: remove legacy code and migrate cases to new format Max R. Carrara
2026-11-17 20:39 ` [PATCH pve-storage v3 33/51] plugin: do not return volumes of undeclared content types anymore Max R. Carrara
2026-11-17 20:39 ` [PATCH pve-storage v3 34/51] plugin: correct comment in get_subdir_files helper Max R. Carrara
2026-11-17 20:39 ` [PATCH pve-storage v3 35/51] test: parse volname: modernize code Max R. Carrara
2026-11-17 20:39 ` [PATCH pve-storage v3 36/51] test: parse volname: adapt tests regarding 'import' volume type Max R. Carrara
2026-11-17 20:39 ` [PATCH pve-storage v3 37/51] test: parse volname: move VM disk test creation into separate block Max R. Carrara
2026-11-17 20:39 ` [PATCH pve-storage v3 38/51] test: parse volname: move backup file test creation into sep. block Max R. Carrara
2026-11-17 20:39 ` [PATCH pve-storage v3 39/51] test: parse volname: parameterize test case creation for some vtypes Max R. Carrara
2026-11-17 20:39 ` [PATCH pve-storage v3 40/51] test: volume id: modernize code Max R. Carrara
2026-11-17 20:39 ` [PATCH pve-storage v3 41/51] test: volume id: rename 'volname' test case parameter to 'file' Max R. Carrara
2026-11-17 20:39 ` [PATCH pve-storage v3 42/51] test: filesystem path: modernize code Max R. Carrara
2026-11-17 20:39 ` [PATCH pve-storage v3 43/51] plugin: list content directories without globbing Max R. Carrara
2026-11-18 9:12 ` [PATCH pve-storage v3 44/51] fix #2884: implement nested subdir scanning and support 'iso' vtype Max R. Carrara
2026-11-18 9:14 ` [PATCH pve-storage v3 45/51] fix #2884: support nested subdir scanning for 'vztmpl' volume type Max R. Carrara
2026-11-18 9:14 ` [PATCH pve-storage v3 46/51] fix #2884: support nested subdir scanning for 'snippets' vtype Max R. Carrara
2026-11-18 9:14 ` [PATCH pve-storage v3 47/51] test: add more tests for 'import' vtype & guard against nested subdirs Max R. Carrara
2026-11-18 9:14 ` [PATCH pve-storage v3 48/51] test: add tests guarding against subdir scanning for vtypes Max R. Carrara
2026-11-18 9:14 ` [PATCH pve-storage v3 49/51] storage: resolve images in content dir overrides ending with a slash Max R. Carrara
2026-11-18 9:14 ` [PATCH pve-storage v3 50/51] bump the storage plugin API version Max R. Carrara
2026-11-18 9:14 ` [PATCH pve-manager v3 51/51] fix #2884: ui: storage: add field for 'max-scan-depth' property Max R. Carrara
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=20261117203953.913035-23-m.carrara@proxmox.com \
--to=m.carrara@proxmox.com \
--cc=pve-devel@lists.proxmox.com \
--cc=w.bumiller@proxmox.com \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is an external index of several public inboxes,
see mirroring instructions on how to clone and mirror
all data and code used by this external index.