[RFC pve-storage 07/27] iscsi: factor out session device map from device list

[Dietmar Maurer <dietmar@proxmox.com>]

Walking the iSCSI sessions in sysfs to find the attached block
devices and their target is useful on its own, for example to check
whether a local disk belongs to a configured iSCSI storage. Split
that part out of the device list helper into a reusable map of
kernel device names to target and address. No functional change.

Signed-off-by: Dietmar Maurer <dietmar@proxmox.com>
---
 src/PVE/Storage/ISCSIPlugin.pm | 74 +++++++++++++++++++++-------------
 1 file changed, 47 insertions(+), 27 deletions(-)

diff --git a/src/PVE/Storage/ISCSIPlugin.pm b/src/PVE/Storage/ISCSIPlugin.pm
index 801b5d1..c18a4b6 100644
--- a/src/PVE/Storage/ISCSIPlugin.pm
+++ b/src/PVE/Storage/ISCSIPlugin.pm
@@ -251,14 +251,14 @@ sub load_stable_scsi_paths {
     return $stable_paths;
 }
 
-sub iscsi_device_list {
+# Maps kernel block device names (e.g. 'sda') of all disks attached through an
+# iSCSI session to their target IQN and channel/id/lun address.
+sub iscsi_session_device_map {
 
     my $res = {};
 
     my $dirname = '/sys/class/iscsi_session';
 
-    my $stable_paths = load_stable_scsi_paths();
-
     dir_glob_foreach(
         $dirname,
         'session(\d+)',
@@ -290,31 +290,12 @@ sub iscsi_device_list {
                     }
                     return if !$bdev;
 
-                    #check multipath
-                    if (-d "/sys/block/$bdev/holders") {
-                        my $multipathdev =
-                            dir_glob_regex("/sys/block/$bdev/holders", '[A-Za-z]\S*');
-                        $bdev = $multipathdev if $multipathdev;
-                    }
-
-                    my $blockdev = $stable_paths->{$bdev};
-                    return if !$blockdev;
-
-                    my $size = file_read_firstline("/sys/block/$bdev/size");
-                    return if !$size;
-
-                    my $volid = "$channel.$id.$lun.$blockdev";
-
-                    $res->{$target}->{$volid} = {
-                        'format' => 'raw',
-                        'size' => int($size * 512),
-                        'vmid' => 0, # not assigned to any vm
-                        'channel' => int($channel),
-                        'id' => int($id),
-                        'lun' => int($lun),
+                    $res->{$bdev} = {
+                        target => $target,
+                        channel => int($channel),
+                        id => int($id),
+                        lun => int($lun),
                     };
-
-                    #print "TEST: $target $session $host,$bus,$tg,$lun $blockdev\n";
                 },
             );
 
@@ -324,6 +305,45 @@ sub iscsi_device_list {
     return $res;
 }
 
+sub iscsi_device_list {
+
+    my $res = {};
+
+    my $stable_paths = load_stable_scsi_paths();
+
+    my $device_map = iscsi_session_device_map();
+
+    for my $bdev (sort keys %$device_map) {
+        my $info = $device_map->{$bdev};
+        my ($channel, $id, $lun) = $info->@{qw(channel id lun)};
+
+        #check multipath
+        if (-d "/sys/block/$bdev/holders") {
+            my $multipathdev = dir_glob_regex("/sys/block/$bdev/holders", '[A-Za-z]\S*');
+            $bdev = $multipathdev if $multipathdev;
+        }
+
+        my $blockdev = $stable_paths->{$bdev};
+        next if !$blockdev;
+
+        my $size = file_read_firstline("/sys/block/$bdev/size");
+        next if !$size;
+
+        my $volid = "$channel.$id.$lun.$blockdev";
+
+        $res->{ $info->{target} }->{$volid} = {
+            'format' => 'raw',
+            'size' => int($size * 512),
+            'vmid' => 0, # not assigned to any vm
+            'channel' => $channel,
+            'id' => $id,
+            'lun' => $lun,
+        };
+    }
+
+    return $res;
+}
+
 # Configuration
 
 sub type {
-- 
2.47.3