[PATCH qemu-server 7/8] agent: fsfreeze: harmonize checks for guest fs freeze

[Fiona Ebner <f.ebner@proxmox.com>]

Puts the logic inside the agent module, rather than duplicating it in
three different places.

Signed-off-by: Fiona Ebner <f.ebner@proxmox.com>
---
 src/PVE/QemuConfig.pm          | 14 ++++-------
 src/PVE/QemuServer/Agent.pm    | 45 ++++++++++++++++++++++++++++++++++
 src/PVE/QemuServer/BlockJob.pm | 13 ++--------
 src/PVE/VZDump/QemuServer.pm   | 21 ++++------------
 4 files changed, 57 insertions(+), 36 deletions(-)

diff --git a/src/PVE/QemuConfig.pm b/src/PVE/QemuConfig.pm
index 7656134b..240b8bfd 100644
--- a/src/PVE/QemuConfig.pm
+++ b/src/PVE/QemuConfig.pm
@@ -292,18 +292,14 @@ sub __snapshot_check_running {
 sub __snapshot_check_freeze_needed {
     my ($class, $vmid, $config, $save_vmstate) = @_;
 
+    my $freeze_needed = 0;
     my $running = $class->__snapshot_check_running($vmid);
+
     if (!$save_vmstate) {
-        return (
-            $running,
-            $running
-                && PVE::QemuServer::Agent::get_qga_key($config->{agent}, 'enabled')
-                && PVE::QemuServer::Agent::qga_check_running($vmid)
-                && (PVE::QemuServer::Agent::get_qga_key($config->{agent}, 'guest-fsfreeze') // 1),
-        );
-    } else {
-        return ($running, 0);
+        $freeze_needed = PVE::QemuServer::Agent::guest_fsfreeze_applicable($config->{agent}, $vmid);
     }
+
+    return ($running, $freeze_needed);
 }
 
 sub __snapshot_freeze {
diff --git a/src/PVE/QemuServer/Agent.pm b/src/PVE/QemuServer/Agent.pm
index 2c1f580d..12f9f9d5 100644
--- a/src/PVE/QemuServer/Agent.pm
+++ b/src/PVE/QemuServer/Agent.pm
@@ -289,4 +289,49 @@ sub guest_fsthaw {
     return;
 }
 
+=head3 guest_fsfreeze_applicable
+
+    if (guest_fsfreeze_applicable($agent_str, $vmid, $logfunc, $is_backup)) {
+        guest_fsfreeze($vmid);
+    }
+
+Check if the file systems of the guest C<$vmid> should be frozen according to the guest agent
+property string C<$agent_str> and if freezing is actionable in practice, i.e. guest agent running.
+Logs a message if skipped. Using a custom log function via C<$logfunc> is supported. Otherwise,
+C<print()> and C<warn()> will be used. In the context of backup tasks, C<$is_backup> must be
+specified.
+
+=cut
+
+sub guest_fsfreeze_applicable {
+    my ($agent_str, $vmid, $logfunc, $is_backup) = @_;
+
+    $logfunc //= sub {
+        my ($level, $msg) = @_;
+        chomp($msg);
+        $level eq 'info' ? print("$msg\n") : warn("$msg\n");
+    };
+
+    if (!get_qga_key($agent_str, 'enabled')) {
+        $logfunc->('info', "skipping guest filesystem freeze - agent not configured in VM options");
+        return;
+    }
+
+    if (!qga_check_running($vmid, 1)) {
+        $logfunc->('info', "skipping guest filesystem freeze - agent configured but not running?");
+        return;
+    }
+
+    my $freeze = get_qga_key($agent_str, 'guest-fsfreeze');
+    $freeze //= get_qga_key($agent_str, 'freeze-fs-on-backup') if $is_backup;
+    $freeze //= 1;
+
+    if (!$freeze) {
+        $logfunc->('info', "skipping guest filesystem freeze - disabled in VM options");
+        return;
+    }
+
+    return 1;
+}
+
 1;
diff --git a/src/PVE/QemuServer/BlockJob.pm b/src/PVE/QemuServer/BlockJob.pm
index dc5804a6..35ebbd0e 100644
--- a/src/PVE/QemuServer/BlockJob.pm
+++ b/src/PVE/QemuServer/BlockJob.pm
@@ -162,22 +162,13 @@ sub monitor {
                 last if $completion eq 'skip' || $completion eq 'auto';
 
                 if ($vmiddst && $vmiddst != $vmid) {
-                    my $freeze_enabled =
-                        PVE::QemuServer::Agent::get_qga_key($qga, 'enabled') &&
-                        (PVE::QemuServer::Agent::get_qga_key($qga, 'guest-fsfreeze') // 1);
-                    my $should_fsfreeze = $freeze_enabled && qga_check_running($vmid);
+                    my $should_fsfreeze =
+                        PVE::QemuServer::Agent::guest_fsfreeze_applicable($qga, $vmid);
                     if ($should_fsfreeze) {
                         print "issuing guest agent 'guest-fsfreeze-freeze' command\n";
                         eval { PVE::QemuServer::Agent::guest_fsfreeze($vmid); };
                         warn $@ if $@;
                     } else {
-                        if (!$freeze_enabled) {
-                            print "skipping guest-agent 'guest-fsfreeze-freeze', disabled in VM"
-                                . " options\n";
-                        } else {
-                            print "skipping guest agent 'guest-fsfreeze-freeze' command: the"
-                                . " agent is not running inside of the guest\n";
-                        }
                         print "suspend vm\n";
                         eval { PVE::QemuServer::RunState::vm_suspend($vmid, 1); };
                         warn $@ if $@;
diff --git a/src/PVE/VZDump/QemuServer.pm b/src/PVE/VZDump/QemuServer.pm
index ed63e3c2..99b31dd9 100644
--- a/src/PVE/VZDump/QemuServer.pm
+++ b/src/PVE/VZDump/QemuServer.pm
@@ -1098,22 +1098,11 @@ sub qga_fs_freeze {
 
     my $agent_str = $self->{vmlist}->{$vmid}->{agent};
 
-    if (!PVE::QemuServer::Agent::get_qga_key($agent_str, 'enabled')) {
-        $self->loginfo("skipping guest-agent 'fs-freeze', agent not configured in VM options");
-        return;
-    }
-
-    if (!PVE::QemuServer::Agent::qga_check_running($vmid, 1)) {
-        $self->loginfo("skipping guest-agent 'fs-freeze', agent configured but not running?");
-        return;
-    }
-
-    my $freeze = PVE::QemuServer::Agent::get_qga_key($agent_str, 'guest-fsfreeze');
-    $freeze //= PVE::QemuServer::Agent::get_qga_key($agent_str, 'freeze-fs-on-backup');
-    $freeze //= 1;
-
-    if (!$freeze) {
-        $self->loginfo("skipping guest-agent 'fs-freeze', disabled in VM options");
+    my $logfunc = sub {
+        my ($level, $msg) = @_;
+        $self->log($level, $msg);
+    };
+    if (!PVE::QemuServer::Agent::guest_fsfreeze_applicable($agent_str, $vmid, $logfunc, 1)) {
         return;
     }
 
-- 
2.47.3