[pmg-devel] [PATCH pmg-api 1/1] fix #3450: api: add 'filter' parameter to queue DELETE endpoint

[Hannes Laimer <h.laimer@proxmox.com>]

This allows to delete all mails in the queue which have a
sender/recipient that matches the passed filter.

Signed-off-by: Hannes Laimer <h.laimer@proxmox.com>
---
 src/PMG/API2/Postfix.pm | 14 ++++++++++++--
 src/PMG/Postfix.pm      | 40 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 52 insertions(+), 2 deletions(-)

diff --git a/src/PMG/API2/Postfix.pm b/src/PMG/API2/Postfix.pm
index ba0689c..31f7449 100644
--- a/src/PMG/API2/Postfix.pm
+++ b/src/PMG/API2/Postfix.pm
@@ -339,7 +339,7 @@ __PACKAGE__->register_method({
     name => 'delete_queue',
     path => 'queue/{queue}',
     method => 'DELETE',
-    description => "Delete all mails in the queue.",
+    description => "Delete all mails in the queue, or only those matching an optional filter.",
     proxyto => 'node',
     permissions => { check => ['admin'] },
     protected => 1,
@@ -348,13 +348,23 @@ __PACKAGE__->register_method({
         properties => {
             node => get_standard_option('pve-node'),
             queue => $queue_name_option,
+            filter => {
+                description => "Filter string (matches sender and recipients).",
+                type => 'string',
+                maxLength => 64,
+                optional => 1,
+            },
         },
     },
     returns => { type => 'null' },
     code => sub {
         my ($param) = @_;
 
-        PMG::Postfix::delete_queue($param->{queue});
+        if (defined($param->{filter}) && $param->{filter} ne '') {
+            PMG::Postfix::delete_queue_filtered($param->{queue}, $param->{filter});
+        } else {
+            PMG::Postfix::delete_queue($param->{queue});
+        }
 
         return undef;
     },
diff --git a/src/PMG/Postfix.pm b/src/PMG/Postfix.pm
index 966130f..7c7869e 100644
--- a/src/PMG/Postfix.pm
+++ b/src/PMG/Postfix.pm
@@ -221,6 +221,46 @@ sub delete_queue {
     PVE::Tools::run_command($cmd);
 }
 
+# delete mails in a queue matching a sender/recipient filter
+sub delete_queue_filtered {
+    my ($queue, $filter) = @_;
+
+    die "no filter specified\n" if !defined($filter) || $filter eq '';
+
+    open(my $fh, '-|', '/usr/sbin/postqueue', '-j') || die "ERROR: unable to run postqueue - $!\n";
+
+    my %seen;
+    my @queue_ids;
+    my $line;
+    while (defined($line = <$fh>)) {
+        my $rec = decode_json($line);
+        next if $rec->{queue_name} ne $queue;
+
+        my $match = 0;
+        my $sender = $rec->{sender} // '';
+        if ($sender =~ m/$filter/i) {
+            $match = 1;
+        } else {
+            my $recipients = $rec->{recipients} // [];
+            foreach my $entry (@$recipients) {
+                if (($entry->{address} // '') =~ m/$filter/i) { $match = 1; last; }
+            }
+        }
+
+        next if !$match;
+
+        my $qid = $rec->{queue_id};
+        next if !$qid || $seen{$qid}++;
+        push @queue_ids, $qid;
+    }
+
+    return if !@queue_ids;
+
+    my $input = join("\n", @queue_ids) . "\n";
+    my $cmd = ['/usr/sbin/postsuper', '-d', '-', $queue];
+    PVE::Tools::run_command($cmd, input => $input);
+}
+
 sub discard_verify_cache {
     unlink "/var/lib/postfix/verify_cache.db";
 
-- 
2.47.3



_______________________________________________
pmg-devel mailing list
pmg-devel@lists.proxmox.com
https://lists.proxmox.com/cgi-bin/mailman/listinfo/pmg-devel