[pve-devel] [PATCH ha-manager v5 05/14] rules: add global checks between node and resource affinity rules

[Daniel Kral <d.kral@proxmox.com>]

Add checks, which determine infeasible resource affinity rules, because
their resources are already restricted by their node affinity rules in
such a way, that these cannot be satisfied or are reasonable to be
proven to be satisfiable.

Node affinity rules restrict resources to certain nodes by their nature,
but resources in positive resource affinity rule need to have at least
one common node to be feasible and resources in negative resource
affinity rule need to have at least the amount of nodes available that
nodes are restricted to in total.

Since node affinity rules allow nodes to be put in priority groups, but
the information which priority group is relevant depends on the online
nodes, these checks currently prohibit resource affinity rules with
resources, which make use of these kinds of node affinity rules.

Even though node affinity rules are restricted to only allow a resource
to be used in a single node affinity rule, the checks here still go over
all node affinity rules, as this restriction is bound to be changed in
the future.

Signed-off-by: Daniel Kral <d.kral@proxmox.com>
---
 src/PVE/HA/Rules.pm                  | 71 ++++++++++++++++++++++++++++
 src/PVE/HA/Rules/ResourceAffinity.pm |  3 +-
 2 files changed, 73 insertions(+), 1 deletion(-)

diff --git a/src/PVE/HA/Rules.pm b/src/PVE/HA/Rules.pm
index 3121424c..75dbeecf 100644
--- a/src/PVE/HA/Rules.pm
+++ b/src/PVE/HA/Rules.pm
@@ -6,6 +6,7 @@ use warnings;
 use PVE::JSONSchema qw(get_standard_option);
 use PVE::Tools;
 
+use PVE::HA::HashTools qw(set_intersect set_union sets_are_disjoint);
 use PVE::HA::Tools;
 
 use base qw(PVE::SectionConfig);
@@ -476,4 +477,74 @@ sub get_next_ordinal : prototype($) {
     return $current_order + 1;
 }
 
+=head1 INTER-PLUGIN RULE CHECKERS
+
+=cut
+
+=head3 check_single_global_resource_reference($node_affinity_rules, $resource_affinity_rules)
+
+Returns all rules in C<$node_affinity_rules> and C<$resource_affinity_rules> as
+a list of lists, each consisting of the rule id and the resource id, where one
+of the resources is used in both a node affinity rule and resource affinity rule
+at the same time.
+
+If there are none, the returned list is empty.
+
+=cut
+
+sub check_single_global_resource_reference {
+    my ($node_affinity_rules, $resource_affinity_rules) = @_;
+
+    my @conflicts = ();
+    my $resource_ruleids = {};
+
+    while (my ($ruleid, $rule) = each %$node_affinity_rules) {
+        for my $sid (keys $rule->{resources}->%*) {
+            push $resource_ruleids->{$sid}->{node_affinity}->@*, $ruleid;
+        }
+    }
+    while (my ($ruleid, $rule) = each %$resource_affinity_rules) {
+        for my $sid (keys $rule->{resources}->%*) {
+            push $resource_ruleids->{$sid}->{resource_affinity}->@*, $ruleid;
+        }
+    }
+
+    for my $sid (keys %$resource_ruleids) {
+        my $node_affinity_ruleids = $resource_ruleids->{$sid}->{node_affinity} // [];
+        my $resource_affinity_ruleids = $resource_ruleids->{$sid}->{resource_affinity} // [];
+
+        next if @$node_affinity_ruleids > 0 && !@$resource_affinity_ruleids;
+        next if @$resource_affinity_ruleids > 0 && !@$node_affinity_ruleids;
+
+        for my $ruleid (@$node_affinity_ruleids, @$resource_affinity_ruleids) {
+            push @conflicts, [$ruleid, $sid];
+        }
+    }
+
+    @conflicts = sort { $a->[0] cmp $b->[0] || $a->[1] cmp $b->[1] } @conflicts;
+    return \@conflicts;
+}
+
+__PACKAGE__->register_check(
+    sub {
+        my ($args) = @_;
+
+        return check_single_global_resource_reference(
+            $args->{node_affinity_rules},
+            $args->{resource_affinity_rules},
+        );
+    },
+    sub {
+        my ($conflicts, $errors) = @_;
+
+        for my $conflict (@$conflicts) {
+            my ($ruleid, $sid) = @$conflict;
+
+            push $errors->{$ruleid}->{resources}->@*,
+                "resource '$sid' cannot be used in both a node affinity rule"
+                . " and a resource affinity rule at the same time";
+        }
+    },
+);
+
 1;
diff --git a/src/PVE/HA/Rules/ResourceAffinity.pm b/src/PVE/HA/Rules/ResourceAffinity.pm
index 8fc640f4..6415c9d7 100644
--- a/src/PVE/HA/Rules/ResourceAffinity.pm
+++ b/src/PVE/HA/Rules/ResourceAffinity.pm
@@ -167,7 +167,8 @@ __PACKAGE__->register_check(
         my ($args) = @_;
 
         return check_negative_resource_affinity_resources_count(
-            $args->{negative_rules}, $args->{nodes},
+            $args->{negative_rules},
+            $args->{nodes},
         );
     },
     sub {
-- 
2.47.2



_______________________________________________
pve-devel mailing list
pve-devel@lists.proxmox.com
https://lists.proxmox.com/cgi-bin/mailman/listinfo/pve-devel