[pve-devel] [PATCH v4 pve-common 03/12] test: add tests for path_is_absolute and path_is_relative of PVE::Path

[Max Carrara <m.carrara@proxmox.com>]

Add cases for both functions, as they're each other's opposite.

Signed-off-by: Max Carrara <m.carrara@proxmox.com>
---
Changes v3 --> v4:
  * None

Changes v2 --> v3:
  * None

Changes v1 --> v2:
  * NEW: Split from patch 02

 test/Path/Makefile                           |   1 +
 test/Path/path_is_absolute_relative_tests.pl | 122 +++++++++++++++++++
 2 files changed, 123 insertions(+)
 create mode 100755 test/Path/path_is_absolute_relative_tests.pl

diff --git a/test/Path/Makefile b/test/Path/Makefile
index d091036..5998c19 100644
--- a/test/Path/Makefile
+++ b/test/Path/Makefile
@@ -1,4 +1,5 @@
 TESTS = \
+	path_is_absolute_relative_tests.pl			\
 
 
 TEST_TARGETS = $(addsuffix .t,$(basename ${TESTS}))
diff --git a/test/Path/path_is_absolute_relative_tests.pl b/test/Path/path_is_absolute_relative_tests.pl
new file mode 100755
index 0000000..ad36c11
--- /dev/null
+++ b/test/Path/path_is_absolute_relative_tests.pl
@@ -0,0 +1,122 @@
+#!/usr/bin/env perl
+
+use lib '../../src';
+
+use strict;
+use warnings;
+
+use Test::More;
+
+use PVE::Path;
+
+my $path_is_absolute_relative_cases = [
+    {
+	name => "empty path",
+	path => "",
+	is_absolute => undef,
+	is_relative => 1,
+    },
+    {
+	name => "root",
+	path => "/",
+	is_absolute => 1,
+	is_relative => undef,
+    },
+    {
+	name => "single component, relative",
+	path => "foo",
+	is_absolute => undef,
+	is_relative => 1,
+    },
+    {
+	name => "single component, absolute",
+	path => "/foo",
+	is_absolute => 1,
+	is_relative => undef,
+    },
+    {
+	name => "path is undef",
+	path => undef,
+	is_absolute => undef,
+	is_relative => undef,
+	should_throw => 1,
+    },
+];
+
+sub test_path_is_absolute : prototype($) {
+    my ($case) = @_;
+
+    my $name = "path_is_absolute: " . $case->{name};
+
+    my $is_absolute = eval { PVE::Path::path_is_absolute($case->{path}); };
+
+    if ($@) {
+	if ($case->{should_throw}) {
+	    pass($name);
+	    return;
+	}
+
+	fail($name);
+	diag("Failed to determine whether path is absolute:\n$@");
+	return;
+    }
+
+    # Note: `!is()` isn't the same as `isnt()` -- we want extra output here
+    # if the check fails; can't do that with `isnt()`
+    if (!is($is_absolute, $case->{is_absolute}, $name)) {
+	diag("path = " . $case->{path});
+    }
+
+    return;
+}
+
+sub test_path_is_relative : prototype($) {
+    my ($case) = @_;
+
+    my $name = "path_is_relative: " . $case->{name};
+
+    my $is_relative = eval { PVE::Path::path_is_relative($case->{path}); };
+
+    if ($@) {
+	if ($case->{should_throw}) {
+	    pass($name);
+	    return;
+	}
+
+	fail($name);
+	diag("Failed to determine whether path is relative:\n$@");
+	return;
+    }
+
+    # Note: `!is()` isn't the same as `isnt()` -- we want extra output here
+    # if the check fails; can't do that with `isnt()`
+    if (!is($is_relative, $case->{is_relative}, $name)) {
+	diag("path = " . $case->{path});
+    }
+
+    return;
+}
+
+sub main : prototype() {
+    my $test_subs = [
+	\&test_path_is_absolute,
+	\&test_path_is_relative,
+    ];
+
+    plan(tests => scalar($path_is_absolute_relative_cases->@*) * scalar($test_subs->@*));
+
+    for my $case ($path_is_absolute_relative_cases->@*) {
+	for my $test_sub ($test_subs->@*) {
+	    eval {
+		# suppress warnings here to make output less noisy for certain tests if necessary
+		# local $SIG{__WARN__} = sub {};
+		$test_sub->($case);
+	    };
+	    warn "$@\n" if $@;
+	}
+    }
+
+    return;
+}
+
+main();
-- 
2.39.5



_______________________________________________
pve-devel mailing list
pve-devel@lists.proxmox.com
https://lists.proxmox.com/cgi-bin/mailman/listinfo/pve-devel