[PATCH access-control/network v2 0/2] fix #7520: sdn: clean up dangling ACLs on resource deletion

[PATCH access-control/network v2 0/2] fix #7520: sdn: clean up dangling ACLs on resource deletion

[David Riley]

Add pruning mechanism to clean up orphaned SDN ACL entries by
comparing the current `running-config` with the newly compiled state
during `commit_config`.

This ensures state consistency for manual applies via the UI/API
as well as during the automatic configuration reload on system boot.
Covers resources tracked in the `running-config`:
* Zones
* VNets
* Fabrics
* Controllers
* Route Maps
* Prefix Lists

Does not cover IPAMs and DNS as these are not staged.

Difference to v1: 
* Add: Route Maps and Prefix Lists

Thanks, Stefan Hanreich for the suggestion.


pve-access-control:

David Riley (1):
  fix #7520: access-control: add SDN ACL cleanup helper

 src/PVE/AccessControl.pm | 40 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)


pve-network:

David Riley (1):
  fix #7520: sdn: clean up dangling ACLs on resource deletion

 src/PVE/Network/SDN.pm | 76 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 76 insertions(+)


Summary over all repositories:
  2 files changed, 116 insertions(+), 0 deletions(-)

-- 
Generated by murpp 0.11.0

[PATCH pve-access-control v2 1/2] fix #7520: access-control: add SDN ACL cleanup helper

[David Riley]

Add a helper to prune ACL nodes under the `/sdn/` path.
Traverse the internal tree to delete target nodes.

Signed-off-by: David Riley <d.riley@proxmox.com>
---
 src/PVE/AccessControl.pm | 40 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)

diff --git a/src/PVE/AccessControl.pm b/src/PVE/AccessControl.pm
index 0d632b3..c83e807 100644
--- a/src/PVE/AccessControl.pm
+++ b/src/PVE/AccessControl.pm
@@ -1895,6 +1895,46 @@ sub roles {
     return $roles;
 }
 
+sub remove_sdn_resource_access {
+    # $paths is e.g. [ ['zones', '<zone>'], ['zones', '<zone>', '<vnet>'] ]
+    my ($paths) = @_;
+
+    my $delSDNResourceFn = sub {
+        my $usercfg = cfs_read_file("user.cfg");
+        my $modified = 0;
+
+        foreach my $segments (@$paths) {
+            my @full_path = ('sdn', @$segments);
+            my $current = $usercfg->{acl_root};
+            my $parent = undef;
+            my $last_key = undef;
+            my $found = 1;
+
+            foreach my $step (@full_path) {
+                if ($current->{children} && $current->{children}->{$step}) {
+                    $parent = $current;
+                    $last_key = $step;
+                    $current = $current->{children}->{$step};
+                } else {
+                    $found = 0;
+                    last;
+                }
+            }
+
+            if ($found && $parent && $last_key) {
+                delete $parent->{children}->{$last_key};
+                $modified = 1;
+            }
+        }
+
+        if ($modified) {
+            cfs_write_file("user.cfg", $usercfg);
+        }
+    };
+
+    lock_user_config($delSDNResourceFn, "SDN ACL cleanup failed");
+}
+
 sub remove_vm_access {
     my ($vmid) = @_;
     my $delVMaccessFn = sub {
-- 
2.47.3

[PATCH pve-network v2 2/2] fix #7520: sdn: clean up dangling ACLs on resource deletion

[David Riley]

Add pruning mechanism to clean up orphaned SDN ACL entries by
comparing the current `running-config` with the newly compiled state
during `commit_config`.

This ensures state consistency for manual applies via the UI/API
as well as during the automatic configuration reload on system boot.
Covers resources tracked in the `running-config`:
* Zones
* VNets
* Fabrics
* Controllers
* Route Maps
* Prefix Lists

Suggested-by: Stefan Hanreich <s.hanreich@proxmox.com>
Signed-off-by: David Riley <d.riley@proxmox.com>
---
 src/PVE/Network/SDN.pm | 76 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 76 insertions(+)

diff --git a/src/PVE/Network/SDN.pm b/src/PVE/Network/SDN.pm
index 33a3cf3..7bb2fca 100644
--- a/src/PVE/Network/SDN.pm
+++ b/src/PVE/Network/SDN.pm
@@ -12,6 +12,7 @@ use UUID;
 
 use PVE::Cluster qw(cfs_read_file cfs_write_file cfs_lock_file);
 use PVE::INotify;
+use PVE::AccessControl;
 use PVE::RESTEnvironment qw(log_warn);
 use PVE::RPCEnvironment;
 use PVE::Tools qw(file_get_contents file_set_contents extract_param dir_glob_regex run_command);
@@ -238,11 +239,86 @@ sub compile_running_cfg {
 }
 
 sub commit_config {
+    my $old_cfg = cfs_read_file($RUNNING_CFG_FILENAME);
     my $cfg = compile_running_cfg();
 
+    cleanup_sdn_acls($old_cfg, $cfg);
+
     cfs_write_file($RUNNING_CFG_FILENAME, $cfg);
 }
 
+sub cleanup_sdn_acls {
+    my ($old_cfg, $new_cfg) = @_;
+    return if !$old_cfg || !$new_cfg;
+
+    my @paths_to_delete;
+
+    my @types = qw(zones controllers fabrics prefix-lists);
+    foreach my $type (@types) {
+        next if !$old_cfg->{$type} || !$old_cfg->{$type}->{ids};
+
+        my $old_ids = $old_cfg->{$type}->{ids};
+        my $new_ids = {};
+        if (my $type_block = $new_cfg->{$type}) {
+            $new_ids = $type_block->{ids} // {};
+        }
+
+        foreach my $id (keys %$old_ids) {
+            next if $new_ids->{$id};
+            push @paths_to_delete, [$type, $id];
+        }
+    }
+
+    if ($old_cfg->{'route-maps'} && $old_cfg->{'route-maps'}->{ids}) {
+        my $old_route_maps = $old_cfg->{'route-maps'}->{ids};
+        my $route_map_suffix = qr/_\d+$/;
+
+        my %active_route_maps;
+        if ($new_cfg->{'route-maps'} && $new_cfg->{'route-maps'}->{ids}) {
+            foreach my $id (keys %{ $new_cfg->{'route-maps'}->{ids} }) {
+                (my $base_name = $id) =~ s/$route_map_suffix//;
+                $active_route_maps{$base_name} = 1;
+            }
+        }
+
+        my %queued_route_maps;
+        foreach my $id (keys %$old_route_maps) {
+            next if $new_cfg->{'route-maps'}->{ids}->{$id};
+
+            (my $base_name = $id) =~ s/$route_map_suffix//;
+            next if $active_route_maps{$base_name};
+            next if $queued_route_maps{$base_name};
+
+            push @paths_to_delete, ['route-maps', $base_name];
+            $queued_route_maps{$base_name} = 1;
+        }
+    }
+
+    if ($old_cfg->{vnets} && $old_cfg->{vnets}->{ids}) {
+        my $old_vnets = $old_cfg->{vnets}->{ids};
+        my $new_vnets = {};
+
+        if (my $type_block = $new_cfg->{vnets}) {
+            $new_vnets = $type_block->{ids} // {};
+        }
+
+        foreach my $vnetid (keys %$old_vnets) {
+            next if $new_vnets->{$vnetid};
+
+            if (my $zoneid = $old_vnets->{$vnetid}->{zone}) {
+                push @paths_to_delete, ['zones', $zoneid, $vnetid];
+                next;
+            }
+
+            log_warn("SDN Cleanup: Could not find zone for VNet $vnetid, skipping ACL cleanup");
+        }
+    }
+
+    if (@paths_to_delete) {
+        PVE::AccessControl::remove_sdn_resource_access(\@paths_to_delete);
+    }
+}
+
 sub has_pending_changes {
     my $running_cfg = PVE::Network::SDN::running_config();
 
-- 
2.47.3