[PATCH proxmox-acme 3/3] tests: rewrite check-missing-functions to catch calls in substitutions

[Mathias Bartmann <mathias.bartmann@gmail.com>]

The check did not notice the missing _json_decode, _mktemp and
_url_replace helpers, for two reasons:

- it only matched a _name followed by a space, so calls at the end of
  a command substitution or pipe like "$(_mktemp)" or "| _json_decode)"
  were never seen
- it filtered whole lines, so any line that also contains an
  assignment, like "_tmp_file=$(_mktemp)", was dropped

Rewrite it in Perl to extract each _name in command position (line
start, after ( ` | ; & ! or a shell keyword, not followed by '='),
skipping arithmetic like "$((_cnt - 1))", and report the ones defined
neither in proxmox-acme nor in the calling plugin. Checked against the
tree before the respective fixes, this reports dns_active24.sh:
_json_decode, dns_oci.sh and dns_transip.sh: _mktemp, and dns_yc.sh:
_url_replace.

The false positives of the old check are gone, so the expected list
shrinks to dns_aws.sh calling _error, which upstream acme.sh does not
define either.

Signed-off-by: Mathias Bartmann <mathias.bartmann@gmail.com>
---
 src/test/check-missing-functions    | 59 ++++++++++++++++++++++++-----
 src/test/missing-functions.expected |  8 +---
 2 files changed, 50 insertions(+), 17 deletions(-)

diff --git a/src/test/check-missing-functions b/src/test/check-missing-functions
index dfc32d3..adb93cd 100755
--- a/src/test/check-missing-functions
+++ b/src/test/check-missing-functions
@@ -1,14 +1,53 @@
-#!/bin/sh
+#!/usr/bin/perl
 
-set -e
+use strict;
+use warnings;
 
-# functions already in src/proxmox-acme
-PRESENT=$(awk 'BEGIN{ORS="\\W|";} /^_/{ gsub(/\(\) {/, ""); print $0}' \
-	../proxmox-acme | sed -r 's/\|$//')
+# Print every _helper a dnsapi plugin calls that is defined neither in
+# src/proxmox-acme nor in the plugin itself.
 
-# functions defined in all plugins
-LOCAL=$(awk 'BEGIN{ORS="\\W|";} /^_/{ gsub(/\(\) {/, ""); print $0}' \
-	../acme.sh/dnsapi/dns*.sh | sed -r 's/\|$//')
+my $shim_path = '../proxmox-acme';
+my $dnsapi_path = '../acme.sh/dnsapi';
 
-grep -P '(?<!["$])\b_[a-zA-Z0-9_-]+ ' ../acme.sh/dnsapi/dns_*sh | \
-	grep -Ev "$PRESENT|$LOCAL|\b_[a-zA-Z0-9_-]+=|^../acme.sh/dnsapi/.*sh: *#"
+die "cannot find '$shim_path'!\n" if !-f $shim_path;
+die "cannot find dnsapi path '$dnsapi_path'!\n" if !-d $dnsapi_path;
+
+sub defined_functions {
+    my ($path) = @_;
+
+    open(my $fh, '<', $path) or die "cannot open '$path' - $!\n";
+    my $functions = {};
+    while (my $line = <$fh>) {
+        $functions->{$1} = 1 if $line =~ /^\s*(_[A-Za-z0-9_]+)\s*\(\)/;
+    }
+    close($fh);
+
+    return $functions;
+}
+
+# a _word in command position: at line start, after ( ` | ; & ! or a shell
+# keyword, and not followed by '=' (an assignment) - this also covers calls
+# inside command substitutions like "$(_mktemp)" and pipes like "| _dbase64",
+# but not variables in arithmetic like "$((_cnt - 1))"
+my $call_re = qr/
+    (?: ^ | (?<!\()\((?!\() | [`|;&!] | \b(?:if|then|else|elif|do|while|until)\s )
+    \s* (_[A-Za-z0-9_]+) (?= [\s)`|;&] | $ )
+/x;
+
+my $shim_functions = defined_functions($shim_path);
+
+for my $plugin (sort glob("$dnsapi_path/dns_*.sh")) {
+    my $plugin_functions = defined_functions($plugin);
+
+    open(my $fh, '<', $plugin) or die "cannot open '$plugin' - $!\n";
+    my $reported = {};
+    while (my $line = <$fh>) {
+        next if $line =~ /^\s*#/;
+        while ($line =~ /$call_re/g) {
+            my $function = $1;
+            next if $shim_functions->{$function} || $plugin_functions->{$function};
+            print "$plugin: $function\n" if !$reported->{$function}++;
+        }
+    }
+    close($fh);
+}
diff --git a/src/test/missing-functions.expected b/src/test/missing-functions.expected
index b338a58..c8f8240 100644
--- a/src/test/missing-functions.expected
+++ b/src/test/missing-functions.expected
@@ -1,7 +1 @@
-../acme.sh/dnsapi/dns_artfiles.sh:  response="$(printf -- '%s' "$response" | sed '/_acme-challenge "'"$txtValue"'"/d')"
-../acme.sh/dnsapi/dns_aws.sh:      _error "invalid domain"
-../acme.sh/dnsapi/dns_cpanel.sh:  for _domain in $_domains; do
-../acme.sh/dnsapi/dns_cyon.sh:  printf "%s" "${_dns_entries}" | while read -r _hash _identifier; do
-../acme.sh/dnsapi/dns_mythic_beasts.sh:  export _H1 _H2
-../acme.sh/dnsapi/dns_openstack.sh:    for _rec in $_records; do
-../acme.sh/dnsapi/dns_selectel.sh:    for _one_id in $_record_id; do
+../acme.sh/dnsapi/dns_aws.sh: _error
-- 
2.55.0