[PATCH pve-network 11/12] tests: cover the ebpf dhcp backend and ipam API mapping pushes

[Hannes Laimer <h.laimer@proxmox.com>]

Signed-off-by: Hannes Laimer <h.laimer@proxmox.com>
---
 src/test/run_test_vnets_blackbox.pl | 147 ++++++++++++++++++++++++++++
 1 file changed, 147 insertions(+)

diff --git a/src/test/run_test_vnets_blackbox.pl b/src/test/run_test_vnets_blackbox.pl
index 9f4c424..fd63fd2 100755
--- a/src/test/run_test_vnets_blackbox.pl
+++ b/src/test/run_test_vnets_blackbox.pl
@@ -46,6 +46,7 @@ sub clear_test_state {
         vnets_config => {},
         macdb => {},
         ipamdb => {},
+        ebpf_calls => [],
         ipam_config => {
             'ids' => {
                 'pve' => {
@@ -103,6 +104,13 @@ my $mocked_pve_sdn;
 $mocked_pve_sdn = Test::MockModule->new('PVE::Network::SDN');
 $mocked_pve_sdn->mock(
     cfs_lock_file => $mocked_cfs_lock_file,
+    running_config => sub {
+        return {
+            zones => $test_state->{zones_config},
+            vnets => $test_state->{vnets_config},
+            subnets => $test_state->{subnets_config},
+        };
+    },
 );
 
 my $mocked_pve_tools = Test::MockModule->new('PVE::Tools');
@@ -224,6 +232,21 @@ $mocked_sdn_dhcp_dnsmasq->mock(
     update_lease => sub { },
 );
 
+my $mocked_sdn_dhcp = Test::MockModule->new('PVE::Network::SDN::Dhcp');
+$mocked_sdn_dhcp->mock(
+    notify_guest_node => sub { },
+);
+
+my $mocked_pve_rs_dhcp = Test::MockModule->new('PVE::RS::SDN::Dhcp');
+$mocked_pve_rs_dhcp->mock(
+    map {
+        my $method = $_;
+        $method => sub {
+            push $test_state->{ebpf_calls}->@*, { method => $method, args => [@_] };
+        };
+    } qw(apply attach remove sync update)
+);
+
 my $mocked_api_zones = Test::MockModule->new('PVE::API2::Network::SDN::Zones');
 $mocked_api_zones->mock(
     create_etc_interfaces_sdn_dir => sub { },
@@ -330,6 +353,22 @@ sub create_ip {
     return PVE::API2::Network::SDN::Ips->ipcreate($param);
 }
 
+sub update_ip {
+    my ($param) = @_;
+    return PVE::API2::Network::SDN::Ips->ipupdate($param);
+}
+
+sub delete_ip {
+    my ($param) = @_;
+    return PVE::API2::Network::SDN::Ips->ipdelete($param);
+}
+
+sub take_ebpf_calls {
+    my $calls = $test_state->{ebpf_calls};
+    $test_state->{ebpf_calls} = [];
+    return $calls;
+}
+
 sub run_test {
     my $test = shift;
     clear_test_state();
@@ -963,4 +1002,112 @@ run_test(
     2,
 );
 
+# -------------- ebpf dhcp backend
+sub test_ebpf_backend {
+    my $test_name = (split(/::/, (caller(0))[3]))[-1];
+    my $zoneid = "TESTZONE";
+    my $vnetid = "testvnet";
+    my $mac = "da:65:8f:18:9b:6f";
+
+    create_zone({
+        type => "simple",
+        dhcp => "ebpf",
+        ipam => "pve",
+        zone => $zoneid,
+    });
+
+    create_vnet({
+        type => "vnet",
+        zone => $zoneid,
+        vnet => $vnetid,
+    });
+
+    create_subnet({
+        type => "subnet",
+        vnet => $vnetid,
+        subnet => "10.0.0.0/24",
+        gateway => "10.0.0.1",
+        'dhcp-range' => ["start-address=10.0.0.100,end-address=10.0.0.200"],
+        'dhcp-lease-time' => 300,
+    });
+
+    take_ebpf_calls();
+
+    # guest start allocates from the range and pushes the record
+    eval { nic_start($vnetid, $mac, "999", "testhostname"); };
+    if ($@) {
+        fail("$test_name: nic_start: $@");
+        return;
+    }
+
+    my $calls = take_ebpf_calls();
+    my $record = sub {
+        my ($ip) = @_;
+        return {
+            mac => $mac,
+            ip => $ip,
+            prefixlen => 24,
+            server_id => "10.0.0.1",
+            lease => 300,
+            router => "10.0.0.1",
+            dns => undef,
+            mtu => 1500,
+        };
+    };
+
+    eq_or_diff(
+        $calls,
+        [{ method => 'update', args => [[$record->("10.0.0.100")]] }],
+        "$test_name: guest start pushes the record",
+    );
+
+    # a mapping edit through the API replaces the record
+    update_ip({
+        zone => $zoneid,
+        vnet => $vnetid,
+        mac => $mac,
+        ip => "10.0.0.150",
+    });
+
+    $calls = take_ebpf_calls();
+    eq_or_diff(
+        $calls,
+        [
+            { method => 'remove', args => [$mac] },
+            { method => 'update', args => [[$record->("10.0.0.150")]] },
+        ],
+        "$test_name: mapping edit replaces the record",
+    );
+
+    # a full regenerate refreshes the responder and translates into one sync
+    PVE::Network::SDN::Dhcp::regenerate_config();
+
+    $calls = take_ebpf_calls();
+    eq_or_diff(
+        $calls,
+        [
+            { method => 'apply', args => [] },
+            { method => 'sync', args => [[$record->("10.0.0.150")]] },
+        ],
+        "$test_name: regenerate refreshes the responder and syncs the full record set",
+    );
+
+    # deleting the mapping drops the record
+    delete_ip({
+        zone => $zoneid,
+        vnet => $vnetid,
+        mac => $mac,
+        ip => "10.0.0.150",
+    });
+
+    $calls = take_ebpf_calls();
+    eq_or_diff(
+        $calls,
+        [{ method => 'remove', args => [$mac] }],
+        "$test_name: mapping delete drops the record",
+    );
+}
+
+run_test(\&test_ebpf_backend);
+
 done_testing();
-- 
2.47.3