[PATCH cluster v4 3/8] add functions to determine warning level for high token timeouts

["Michael Köppl" <m.koeppl@proxmox.com>]

High token timeouts can lead to stability problems in clusters. To
inform users about the timeout in their current setup and give
recommendations regarding the token coefficient setting, introduce
functions to calculate the timeout as well as determine the warning
level.

Current token and consensus timeout are parsed from corosync-cmapctl's
output directly to avoid future drift between this implementation and
Corosync's implementation. The values are parsed from the output
assuming the following format:

    runtime.config.totem.consensus (u32) = 3750
    runtime.config.totem.token (u32) = 3125

Signed-off-by: Michael Köppl <m.koeppl@proxmox.com>
---
 src/PVE/Corosync.pm | 59 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)

diff --git a/src/PVE/Corosync.pm b/src/PVE/Corosync.pm
index aef0d31..d379710 100644
--- a/src/PVE/Corosync.pm
+++ b/src/PVE/Corosync.pm
@@ -534,4 +534,63 @@ sub resolve_hostname_like_corosync {
     return $match_ip_and_version->($resolved_ip);
 }
 
+sub read_cmap {
+    my $cmap = {};
+    my $rc = eval {
+        PVE::Tools::run_command(
+            ['corosync-cmapctl'],
+            outfunc => sub {
+                my $line = shift;
+                if ($line =~ /^(\S+)\s+\(\w+\)\s+=\s+(.*)$/) {
+                    $cmap->{$1} = $2;
+                }
+            },
+        );
+        1;
+    };
+    return undef if !$rc;
+    return $cmap;
+}
+
+sub calculate_membership_recovery_timeout {
+    my $cmap = read_cmap();
+    return undef if !$cmap;
+
+    my $token = $cmap->{'runtime.config.totem.token'};
+    my $consensus = $cmap->{'runtime.config.totem.consensus'};
+    return undef if !defined($token) || !defined($consensus);
+
+    return ($token + $consensus) / 1000.0;
+}
+
+sub get_membership_recovery_timeout_warning_level {
+    my ($total_timeout_secs) = @_;
+
+    if ($total_timeout_secs > 45) {
+        return 'critical';
+    } elsif ($total_timeout_secs > 40) {
+        return 'warning';
+    } elsif ($total_timeout_secs > 30) {
+        return 'info';
+    }
+
+    return undef;
+}
+
+sub get_membership_recovery_timeout_warning {
+    my ($total_timeout_secs) = @_;
+
+    my $level = get_membership_recovery_timeout_warning_level($total_timeout_secs);
+    return if !defined($level);
+
+    my $level_msg = {
+        critical => "Lowering the token coefficient is strongly recommended",
+        warning => "Lowering the token coefficient is recommended",
+        info => "The token coefficient can be optimized",
+    }->{$level};
+
+    my $msg = "Sum of Corosync token and consensus timeout is ${total_timeout_secs}s. $level_msg.";
+    return ($level, $msg);
+}
+
 1;
-- 
2.47.3